13-2.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE,SIMPLE HALF WAVE RECTIFIER WITH IDEAL DIODE  ! 定义工作标题
/FILNAME,HALF WAVE RECTIFIER,1            ! 定义工作文件名
KEYW,MAGELC,1                             ! 指定电路分析

/PREP7
PI = 4*ATAN(1)                 ! 设置π参数
R,1,,135,1,                    ! 定义正弦电压源实常数
N,1,-0.85,0.4,0                ! 创建节点
N,2,-0.85,0.25,0   
RMOD,1,15,0,1                  ! 修改实常数组1
ET,1,CIRCU124,4,1              ! 定义独立电压源单元
TYPE,1                         ! 设置默认属性
REAL,1  
!*  
N,3,-0.85,0.325,0              ! 创建节点
E,1,2,3                        ! 创建正弦电压源单元
R,2,2500,                      ! 定义电阻实常数为2500 OHM
N,4,-0.75,0.4,0                ! 创建节点
N,5,-0.75,0.25,0   
RMOD,2,15,0,2                  ! 修改实常数组2
ET,2,CIRCU124,0,0              ! 定义电阻单元
TYPE,2                         ! 设置默认属性
REAL,2  
E,4,5                          ! 创建电阻单元，阻值为2500 OHM
!
! 下面的命令用来创建二极管单元
!
ET,3,CIRCU125,
R,3 
TYPE,3  
REAL,3     
E,1,4
!
! 为电路施加接地边界条件
!  
D,2,VOLT,0
D,5,VOLT,0     
ALLSEL
EPLOT
FINISH
!
! 在时间T=0～1.5范围内进行非线性电路求解
!  
/SOLU   
ANTYPE,TRANS                       ! 瞬态分析
OUTRES,ALL,ALL,
TIME,1.5
AUTOTS,1                           ! 自动时间步长 
DELTIM,0.01,0.01,0.04              ! 时间步长范围为0.01～0.04s 
CNVTOL,VOLT                        ! 收敛标准
SOLVE   
FINISH

/POST26 
NSOL,2,4,VOLT,,                    ! 定义时间历程变量
PRVAR,2,                           ! 列出时间历程变量结果
/AXLAB,Y,OUTPUT POTENTIAL (VOLT)   ! 修改Y轴坐标标签
PLVAR,2,                           ! 绘出时间历程变量