11-1.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE, MICROSTRIP TRANSMISSION LINE ANALYSIS  ! 定义工作标题
/FILNAME,STRIP,1                          ! 定义工作文件名
KEYW,MAGELC,1                             ! 指定电场分析

/PREP7
ET,1,PLANE121                        ! 定义二维8节点静电单元PLANE121
V1=1.5                               ! 定义微带电势
V0=0.5                               ! 定义地电势
/PNUM,AREA,1                         ! 打开面区域编号
MP,PERX,1,1                          ! 自由空间相对介电常数
MP,PERX,2,10                         ! 基片相对介电常数
RECTNG,0,0.5,0,1                     ! 创建几何模型
RECTNG,0.5,5,0,1
RECTNG,0,0.5,1,10
RECTNG,0.5,5,1,10
AGLUE,ALL                           ! 布尔粘接操作
NUMCMP,AREA
ASEL,S,AREA,,1,2
AATT,2            
ASEL,ALL                            ! 设置空气区域材料属性
LSEL,S,LOC,Y,1
LSEL,R,LOC,X,0.25
LESIZE,ALL,,,8
LSEL,ALL
SMRTSIZE,3
MSHAPE,1                            ! 三角形网格划分
AMESH,ALL
NSEL,S,LOC,Y,1                     ! 选择微带上的节点
NSEL,R,LOC,X,0,0.5 
D,ALL,VOLT,V1                      ! 给微带施加电压
NSEL,S,LOC,Y,0                     ! 选择地节点
NSEL,A,LOC,Y,10 
NSEL,A,LOC,X,5
D,ALL,VOLT,V0                      ! 给地节点施加电压
NSEL,ALL
ARSCALE,ALL,,,0.01,0.01,0,,0,1     ! 对面进行缩放
FINISH
/SOLUTION    
SOLVE
FINISH
/POST1
ETABLE,SENE,SENE                   ! 存储静电能
ETABLE,EFX,EF,X                    ! 存储电场力
ETABLE,EFY,EF,Y
/NUMBER,1
PLNSOL,VOLT                        ! 显示电位等值云图
PLVECT,EFX,EFY                     ! 显示自定义矢量图
SSUM                               ! 单元表求和
*GET,W,SSUM,,ITEM,SENE             ! 获取总静电能并赋予参数W
C=(W*2)/((V1-V0)**2)               ! 计算电容(F/M)
C=((C*2)*1E12)                     ! 全部几何体的电容(PF/M)
*STATUS,C                          ! 显示电容
FINISH