5-1.txt

ANSYS电磁分析的命令流文件

!/BACH,LIST
/TITLE,3-D STATIC FORCE PROBLEM - TETRAHEDRAL       ! 定义工作标题
/FILNAME,EMAGE_3D,1                        ! 定义工作文件名
KEYW,MAGNOD,1                                 ! 指定磁场分析

/PREP7
! 定义分析参数
N=500                                        ! 线圈匝数
I=6                                          ! 每匝通过的电流
! 定义单元类型
ET,1,96
!给空气和衔铁定义材料属性
MP,MURX,1,1
TB,BH,2,,40
TBPT,,355,0.7
,,405,0.8
,,470,0.9
,,555,1.0
,,673,1.1
,,836,1.2
,,1065,1.3
,,1220,1.35
,,1420,1.4
,,1720,1.45
,,2130,1.5
,,2670,1.55
,,3480,1.6
,,4500,1.65
,,5950,1.7
,,7650,1.75
,,10100,1.8
,,13000,1.85
,,15900,1.9
,,21100,1.95
,,26300,2.0
,,32900,2.05
,,42700,2.1
,,61700,2.15
,,84300,2.2
,,110000,2.25
,,135000,2.3
,,200000,2.41
,,400000,2.69
,,800000,3.22
TBCOPY,BH,2,3
!
!创建电极体
!
/PNUM,VOLU,1
BLOCK,0,63.5,0,25/2,0,25
/VIEW,1,1,1,1
/REPLOT
BLOCK,38.5,63.5,0,25/2,25,125
BLOCK,13.5,63.5,0,25/2,125,150
VGLUE,ALL
!
!创建衔铁、空气体并压缩编号
!
BLOCK,0,12.5,0,5,26.5,125                   ! 衔铁体
BLOCK,0,13,0,5.5,26,125.5                   ! 空气体
VOVLAP,1,2
NUMCMP,VOLU
CYL4,,,0,0,100,90,175
VOVLAP,ALL
NUMCMP,VOLU
!
!设置几何体的属性
!
VSEL,S,VOLU,,1
VATT,3,1,1                                  ! 设置衔铁属性
VSEL,S,VOLU,,3,5
VATT,2,1,1                                  ! 设置电极属性
!
!给模型划分网格
!
ALLSEL,ALL
SMRT,8            ! 定义网格智能划分等级为8，实际工程问题可选6
MSHAPE,1,3D
MSHKEY,0
VMESH,ALL
/PNUM,MAT,1
/NUMBER,1
EPLOT
!
!把衔铁定义成一个组件并施加力标志
!
ESEL,S,MAT,,3                        ! 选择衔铁材料单元
CM,ARM,ELEM
FMAGBC,'ARM'
!
!转换模型单位制为米
!
ALLSEL,ALL
VLSCALE,ALL,,,0.001,0.001,0.001,,0,1
!
!创建线圈
!
LOCAL,12,0,0,0,75/1000
WPCSYS,-1,12
RACE,0.0285,0.0285,0.014,N*I,0.018,0.0966,,,'COIL1'
/ESHAPE,1
EPLOT
SAVE
FINISH
!
!施加边界条件
!
/SOLU
D,2,MAG,0
!
!SOLVE
!
ALLSEL,ALL
MAGSOLV,3,,,,,1
FINISH
!
!对衔铁受力求和
!
/POST1
FMAGSUM,'ARM'
FINISH
SAVE
!
!计算线圈电感矩阵
!
/SOLU
*DIM,CUR,ARRAY,1
CUR(1)=I
LMATRIX,1,'COIL','CUR'
FINISH