truck.as

Papervision3d的源码

/**
 * Paperskated3d - simple skateboard simulator in Papervision3d
 * 
 * @author Bartek Drozdz 
 * @version 1.0
 * 
 * Released under Creative Commons Attribution-Non-Commercial-Share Alike 3.0 License.
 */
package com.paperskate3d.skate {
	
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import org.papervision3d.core.proto.MaterialObject3D;
	import org.papervision3d.materials.BitmapMaterial;
	import org.papervision3d.materials.ColorMaterial;
	import org.papervision3d.materials.utils.MaterialsList;
	import org.papervision3d.materials.WireframeMaterial;
	import org.papervision3d.objects.DisplayObject3D;
	import org.papervision3d.objects.primitives.Cube;
	import org.papervision3d.objects.primitives.Plane;

	public class Truck extends DisplayObject3D {
		
		[Embed(source = '../../../../assets/truck.png')]
		private var TruckTexture:Class;
		private var truckTexture:BitmapData;
		private var truckMaterial:MaterialObject3D;
		
		private var outerWidth:Number = 90;
		private var innerWidth:Number = 20;
		
		private var truck:Cube;
		private var base:Cube;

		public function Truck() {
			truckTexture = (new TruckTexture() as Bitmap).bitmapData;
			truckMaterial = new BitmapMaterial(truckTexture);
			
			var truckList:MaterialsList = new MaterialsList();
			truckList.addMaterial(truckMaterial, "front");
			truckList.addMaterial(truckMaterial, "back");
			truckList.addMaterial(truckMaterial, "top");
			truckList.addMaterial(truckMaterial, "bottom");
			truck = new Cube(truckList, outerWidth, 8, 8);
			addChild(truck);
			
			var baseList:MaterialsList = new MaterialsList();
			baseList.addMaterial(truckMaterial, "right");
			baseList.addMaterial(truckMaterial, "left");
			baseList.addMaterial(truckMaterial, "top");
			baseList.addMaterial(truckMaterial, "bottom");
			base = new Cube(baseList, innerWidth, 36, 8);
			base.z = -14;
			addChild(base);
			
			base.geometry.vertices[0].y -= 10;
			base.geometry.vertices[6].y -= 10;
		}
		
		public function set hiquality(v:Boolean):void {
			truckMaterial.smooth = v;
		}
	}
}