kickflip.as

来自「Papervision3d的源码」· AS 代码 · 共 63 行

/**
 * Paperskated3d - simple skateboard simulator in Papervision3d
 * 
 * @author Bartek Drozdz 
 * @version 1.0
 * 
 * Released under Creative Commons Attribution-Non-Commercial-Share Alike 3.0 License.
 */
package com.paperskate3d.tricks {
	
	import com.paperskate3d.skate.SkateBoard;
	import caurina.transitions.Tweener;
	import com.carlcalderon.arthropod.Debug;

	public class KickFlip extends BasicTrick {
		
		private var destination:Number = 360;
		private var noOllie:Boolean;
		
		public function KickFlip(heelFlip:Boolean=false, noOllie:Boolean=false) {
			if (heelFlip) destination = -360;
			this.noOllie = noOllie;
		}
		
		override public function get name():String { return "kickflip" };
		
		override protected function prepareTrick():void {
			var kd:Number = (noOllie) ? TRICK_TIME * .1 : TRICK_TIME * .2;
			var kt:Number = (noOllie) ? TRICK_TIME * .4 : TRICK_TIME * .5;
			//if (olliePhase == Ollie.LEVEL) kd = 0;
			
			Tweener.addTween(this, { 
				flipAmount:destination, 
				delay:kd,
				time:kt, 
				transition:"easeInOutSine", 
				onComplete:end 
			} );
		}
		
		public function get flipAmount():Number {
			return skateboard.internalRotationY;
		}
		
		public function set flipAmount(a:Number):void {
			skateboard.internalRotationY = a;
		}

		override protected function finalizeTrick():void {
			skateboard.internalRotationY = 0;
		}
	}
}