lowtextfield.as

Papervision3d的源码

/**
 * Paperskated3d - simple skateboard simulator in Papervision3d
 * 
 * @author Bartek Drozdz 
 * @version 1.0
 * 
 * Released under Creative Commons Attribution-Non-Commercial-Share Alike 3.0 License.
 */
package com.paperskate3d.gui {
	
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	import flash.text.Font;
	import flash.display.StageQuality;

	public class LowTextField extends Sprite {

		[Embed(source='../../../../../../assets/contest/font/impact.ttf', fontName = 'Impact')]
		public var EmbeddedFont:Class;
		
		public var field:TextField;
		private var image:BitmapData;
		private var imageHolder:Bitmap;
		
		public function LowTextField() {
			Font.registerFont(EmbeddedFont);
			
			field = new TextField();
			field.autoSize = TextFieldAutoSize.LEFT;
			field.embedFonts = true;
			
			var style:TextFormat = new TextFormat();
			style.size = 20;
			style.color = 0xffffff;
			style.font = "Impact";
			field.defaultTextFormat = style;
		}
		
		public function set text(nt:String):void {
			if (nt == field.text) return;
			
			if (imageHolder != null && contains(imageHolder)) removeChild(imageHolder);
			
			field.text = nt;
			image = new BitmapData(field.textWidth+4, field.textHeight+4, true, 0x00000000);
			
			stage.quality = StageQuality.HIGH;
			image.draw(field);
			stage.quality = StageQuality.LOW;
			
			imageHolder = new Bitmap(image);
			addChild(imageHolder);
		}
	}
	
}