hilow.as

Papervision3d的源码

/**
 * Paperskated3d - simple skateboard simulator in Papervision3d
 * 
 * @author Bartek Drozdz 
 * @version 1.0
 * 
 * Released under Creative Commons Attribution-Non-Commercial-Share Alike 3.0 License.
 */
package com.paperskate3d.gui {
	
	import flash.display.Bitmap;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	import com.paperskate3d.gui.PSUIEvent;
	import com.paperskate3d.util.Button;

	public class HiLow extends Sprite {
		
		[Embed(source = '../../../../assets/ui/footer/hi.png')]
		private var HiText:Class;
		private var hiBtn:Button;
		
		[Embed(source = '../../../../assets/ui/footer/lo.png')]
		private var LoText:Class;
		private var loBtn:Button;
		
		[Embed(source = '../../../../assets/ui/footer/div.png')]
		private var Divider:Class;
		private var div:Bitmap;
		
		[Embed(source = '../../../../assets/ui/footer/hiu.png')]
		private var HiUnderline:Class;
		private var hiu:Bitmap;
		
		[Embed(source='../../../../assets/ui/footer/lou.png')]
		private var LoUnderline:Class;
		private var lou:Bitmap;
		
		public function HiLow() {
			
			hiBtn = new Button(new HiText());
			addChild(hiBtn);
			
			loBtn = new Button(new LoText());
			addChild(loBtn);
			loBtn.x = 50;
			
			div = new Divider();
			addChild(div);
			div.y = -1;
			div.x = 39;
			
			hiu = new HiUnderline();
			addChild(hiu);
			hiu.visible = false;
			hiu.y = 15;
			
			lou = new LoUnderline();
			addChild(lou);
			lou.x = 50;
			lou.y = 15;
			
			alpha = .2;
			hiBtn.buttonMode = false;
			loBtn.buttonMode = false;
		}
		
		public function activate():void {
			alpha = 1;
			hiBtn.buttonMode = true;
			loBtn.buttonMode = true;
			hiBtn.addEventListener(MouseEvent.CLICK, onClick);
			loBtn.addEventListener(MouseEvent.CLICK, onClick);
		}
		
		public function deactivate():void {
			alpha = .2;
			hiBtn.buttonMode = false;
			loBtn.buttonMode = false;
			hiBtn.removeEventListener(MouseEvent.CLICK, onClick);
			loBtn.removeEventListener(MouseEvent.CLICK, onClick);
		}
		
		private function onClick(me:MouseEvent):void {
			var psu:PSUIEvent = new PSUIEvent(PSUIEvent.QUALITY_CHANGE);
			if (me.target == loBtn) {
				hiu.visible = false;
				lou.visible = true;
				psu.isHigh = false;
			} else {
				hiu.visible = true;
				lou.visible = false;
				psu.isHigh = true;
			}
			dispatchEvent(psu);
		}
	}
}