programs.ac

关于Berkelay数据库的共享源码

# $Id: programs.ac,v 12.2 2006/07/06 14:00:28 bostic Exp $

# Check for programs used in building/installation.
AC_DEFUN(AM_PROGRAMS_SET, [

AC_CHECK_TOOL(AR, ar, none)
test "$AR" = "none" && AC_MSG_ERROR([No ar utility found.])

AC_CHECK_TOOL(CHMOD, chmod, none)
test "$CHMOD" = "none" && AC_MSG_ERROR([No chmod utility found.])

AC_CHECK_TOOL(CP, cp, none)
test "$CP" = "none" && AC_MSG_ERROR([No cp utility found.])

# The Tcl test suite requires a kill utility.
if test "$db_cv_test" = "yes"; then
	AC_CHECK_TOOL(KILL, kill, none)
	test "$KILL" = "none" && AC_MSG_ERROR([No kill utility found.])
fi

AC_CHECK_TOOL(LN, ln, none)
test "$LN" = "none" && AC_MSG_ERROR([No ln utility found.])

AC_CHECK_TOOL(MKDIR, mkdir, none)
test "$MKDIR" = "none" && AC_MSG_ERROR([No mkdir utility found.])

# Ranlib doesn't exist on some architectures because the ar utility
# packages the library itself.
AC_CHECK_TOOL(RANLIB, ranlib, none)

AC_CHECK_TOOL(RM, rm, none)
test "$RM" = "none" && AC_MSG_ERROR([No rm utility found.])

if test "$db_cv_rpc" = "yes"; then
	AC_CHECK_TOOL(RPCGEN, rpcgen, none)
	test "$RPCGEN" = "none" && AC_MSG_ERROR([No rpcgen utility found.])
fi

# We need a complete path for sh, because some make utility implementations get
# upset if SHELL is set to just the command name.  Don't use the SHELL variable
# here because the user likely has the SHELL variable set to something other
# than the Bourne shell, which is what Make wants.
AC_PATH_TOOL(db_cv_path_sh, sh, none)
test "$db_cv_path_sh" = "none" && AC_MSG_ERROR([No sh utility found.])

# Don't strip the binaries if --enable-debug was specified.
if test "$db_cv_debug" = yes; then
	STRIP="none"
else
	AC_CHECK_TOOL(STRIP, strip, none)
	test "$STRIP" = "none" && AC_MSG_WARN([No strip utility found.])
fi])