mysql.m4

有关MYSQL的开源码

# =========================================================================
# AM_PATH_MYSQL : MySQL library

dnl AM_PATH_MYSQL([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
dnl Test for MySQL, and define MYSQL_CFLAGS and MYSQL_LIBS
dnl
AC_DEFUN([AM_PATH_MYSQL],
[dnl
dnl Get the cflags and libraries from the mysql_config script
dnl
AC_ARG_WITH(mysql,[  --with-mysql=PREFIX     prefix where MySQL is installed (optional)],
            mysql_prefix="$withval", mysql_prefix="")
AC_ARG_WITH(mysql-config,[  --with-mysql-config=FILE location of mysql_config file (optional)],
            mysql_config_file="$withval", mysql_config_file="")

  if test x$mysql_config_file != x ; then
     if test x${MYSQL_CONFIG+set} != xset ; then
        MYSQL_CONFIG=$mysql_config_file
     fi
  fi
  if test x$mysql_prefix != x ; then
     if test x${MYSQL_CONFIG+set} != xset ; then
       if test -x $mysql_prefix/bin/mysql_config ; then
         MYSQL_CONFIG=$mysql_prefix/bin/mysql_config
       elif test -x $mysql_prefix/mysql/bin/mysql_config ; then
         MYSQL_CONFIG=$mysql_prefix/mysql/bin/mysql_config
       fi
     fi
  fi

dnl TODO - maybe only run AC_PATH_PROG if mysql_prefix not given ?
dnl do not want to find mysql_config in path if not found at specified prefix
dnl user could be trying to specify location which has no mysql_config

  dnl AC_REQUIRE([AC_CANONICAL_TARGET])
  AC_PATH_PROG(MYSQL_CONFIG, mysql_config, no)
  AC_MSG_CHECKING(for MySQL headers and libraries)
  no_mysql=""
  if test "$MYSQL_CONFIG" = "no" ; then
    dnl try to find files using $mysql_prefix
    if test x$mysql_prefix = x ; then
      mysql_prefix='/usr /usr/local'
    fi
    for prefix_dir in $mysql_prefix ; do
      for suffix_dir in '' /mysql 64 64/mysql ; do
        if test -f $prefix_dir/include$suffix_dir/mysql.h ; then
          MYSQL_CFLAGS="-I$prefix_dir/include$suffix_dir"
        fi
        if test -f $prefix_dir/lib$suffix_dir/libmysqlclient.so ; then
          MYSQL_LIBS="-L$prefix_dir/lib$suffix_dir -lmysqlclient"
        fi
      done
    done
    if test "x$MYSQL_CFLAGS" = x ; then
      no_mysql='set'
    elif test "x$MYSQL_LIBS" = x ; then
      no_mysql='set'
    fi
  else
    MYSQL_CFLAGS=`$MYSQL_CONFIG $mysqlconf_args --cflags | sed -e "s/-I'/-I/g" | sed -e "s/\/mysql'//g"`
    MYSQL_LIBS=`$MYSQL_CONFIG $mysqlconf_args --libs | sed -e "s/'//g"`
    AC_MSG_RESULT(yes)
    ifelse([$1], , :, [$1])
  fi

  if test x$no_mysql != x ; then
    MYSQL_CFLAGS=""
    MYSQL_LIBS=""
    AC_MSG_RESULT(no)
    ifelse([$2], , :, [$2])
  fi

  AC_SUBST(MYSQL_CFLAGS)
  AC_SUBST(MYSQL_LIBS)
])