configure.in

Firestorm NIDS是一个性能非常高的网络入侵检测系统 (NIDS)。目前

dnl Process this file with autoconf to produce a configure script.

AC_INIT(src/sensor.c)
AM_INIT_AUTOMAKE(firestorm, 0.5.2)
AM_CONFIG_HEADER(include/config.h)

AC_PREFIX_DEFAULT(/usr)

dnl Check for programs
AC_PROG_AWK
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

dnl libtool stuff
AM_DISABLE_STATIC
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL
AM_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

dnl Set our cflags if we are using gcc
if test -n "$GCC"; then
	CFLAGS="${CFLAGS} -Wall -pipe"
fi

dnl Check for headers
AC_HEADER_TIME
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_CHECK_HEADERS([arpa/inet.h errno.h fcntl.h netinet/in.h])
AC_CHECK_HEADERS([stdlib.h string.h sys/socket.h sys/time.h unistd.h])
AC_CHECK_HEADERS([sys/uio.h])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_UID_T
AC_C_INLINE
AC_STRUCT_TM

dnl Check for library functions
AC_CHECK_FUNCS([tzset sigaction])

dnl Check for memory mapped IO support
havemm="no"
AC_FUNC_MMAP(havemm="yes")
if test "x%havemm" == "xno"; then
	echo "ERROR: firestorm needs mmap()/munmap() to compile."
	echo "ERROR: get a real OS."
	exit 1
fi

dnl we actually need writev() now
havewv="no"
AC_CHECK_FUNC(writev, havewv="yes", havewv="no")
if test "x$havewv" == "xno"; then
	echo "ERROR: firestorm needs writev() to compile."
	echo "ERROR: get a real OS."
	exit 1
fi

dnl Check for libpcap -- shamelessly stolen from snort
AC_ARG_WITH(libpcap_includes,
	[  --with-libpcap-includes=DIR  libcap include directory],
	[with_libpcap_includes="$withval"],[with_libpcap_includes=no])

AC_ARG_WITH(libpcap_libraries,
	[  --with-libpcap-libraries=DIR  libcap library directory],
	[with_libpcap_libraries="$withval"],[with_libpcap_libraries=no])

if test "$with_libpcap_includes" != "no"; then
	CPPFLAGS="${CPPFLAGS} -I${with_libpcap_includes}"
fi

if test "$with_libpcap_libraries" != "no"; then
	LDFLAGS="${LDFLAGS}  -L${with_libpcap_libraries}"
fi

AC_CHECK_LIB(pcap,pcap_datalink,have_libpcap="yes",have_libpcap="no")
if test "$have_libpcap" != "no"; then
	pcap_la="capdev_pcap.la"
	pcapfile_la="capdev_pcapfile.la"
	pcap_ldflags="-lpcap"
else
	pcap_la=""
	pcapfile_la=""
	pcap_ldflags=""
fi
AC_SUBST(pcap_la)
AC_SUBST(pcapfile_la)
AC_SUBST(pcap_ldflags)

dnl Check for libprelude
AC_PATH_GENERIC(libprelude,0.4.1,have_libprelude=yes,have_libprelude=no)
AC_SUBST(have_libprelude)

dnl Check for Linux mmap() packet socket 
have_packet_socket=no
AC_MSG_CHECKING(for Linux mmap packet socket)
AC_TRY_COMPILE([
#include <linux/if_packet.h>
int x=PACKET_RX_RING;
],[
],[
have_packet_socket=yes
])
AC_MSG_RESULT($have_packet_socket)
AC_SUBST(have_packet_socket)

dnl Dynamic linker interface for plugin loading
AC_CHECK_LIB(dl, dlopen)
AC_CHECK_HEADERS(dlfcn.h)

dnl Make our Makefiles
AC_OUTPUT([
Makefile
src/Makefile
doc/Makefile
capdev_plugins/Makefile
decode_plugins/Makefile
parser_plugins/Makefile
target_plugins/Makefile
preproc_plugins/Makefile
matcher_plugins/Makefile
snort-rules/Makefile
])