agrimonitorappc.nc

tinyos2.0版本驱动

#include "Datastructure.h"
configuration AgriMonitorAppC { }
implementation
{
  components AgriMonitorC, ActiveMessageC, MainC, LedsC,
    new TimerMilliC() as SensorDataTimer, new TimerMilliC() as TopologyDataTimer, new TimerMilliC() as StateDataTimer;
    
  AgriMonitorC.Boot -> MainC.Boot;
  AgriMonitorC.SensorData_Interval -> SensorDataTimer;
  AgriMonitorC.TopologyData_Interval -> TopologyDataTimer;
  AgriMonitorC.StateData_Interval -> StateDataTimer;
  AgriMonitorC.RadioControl -> ActiveMessageC;
  AgriMonitorC.Leds -> LedsC;

  components new VoltageC() ;
  AgriMonitorC.voltageRead -> VoltageC;

  components DisseminationC;
  AgriMonitorC.DisseminationControl -> DisseminationC;

  components new DisseminatorC(rootDissemination_t, DISEMINATION_KEY);
  AgriMonitorC.SettingsValue -> DisseminatorC;

  components CollectionC, new CollectionSenderC(COL_AM_SENSOR) as SensorC , 
  new CollectionSenderC(COL_AM_TOPOLOGY) as TopologyC,
  new CollectionSenderC(COL_AM_STATE) as StateC;

  AgriMonitorC.SensorDataSend -> SensorC;
  AgriMonitorC.TopologyDataSend -> TopologyC;
  AgriMonitorC.StateDataSend -> StateC;
  AgriMonitorC.CollectionControl -> CollectionC;
  AgriMonitorC.CtpInfo -> CollectionC;

  components RandomC;
  AgriMonitorC.Random -> RandomC;
  
  components new BcastC(BCAST_AM);
  AgriMonitorC.BcastReceive -> BcastC;
  /*
  components CC1000CsmaRadioC as LplRadio;
  DemoC.LowPowerListening -> LplRadio;
  */
}