testamc.nc

tinyos2.0版本驱动

// $Id: TestAMC.nc,v 1.4 2006/12/12 18:22:49 vlahan Exp $

/*									tab:4
 * "Copyright (c) 2000-2005 The Regents of the University  of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement is
 * hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY OF
 * CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 *
 * Copyright (c) 2002-2003 Intel Corporation
 * All rights reserved.
 *
 * This file is distributed under the terms in the attached INTEL-LICENSE     
 * file. If you do not find these files, copies can be found by writing to
 * Intel Research Berkeley, 2150 Shattuck Avenue, Suite 1300, Berkeley, CA, 
 * 94704.  Attention:  Intel License Inquiry.
 */
 
#include "Timer.h"

/**
 * Implementation of the TestAM application.  TestAM sends active message 
 * broadcasts at 1Hz and blinks LED 0 whenever it has sucessfully sent a 
 * broadcast. Whenever it receives one of these broadcasts from another 
 * node, it blinks LED 1.  It uses the radio HIL component <tt>ActiveMessageC</tt>, 
 * and its packets are AM type 240.  This application is useful for testing 
 * AM communication and the ActiveMessageC component.
 *
 * @author Philip Levis
 * @date   May 16 2005
 */

module TestAMC {
  uses {
    interface Leds;
    interface Boot;
    interface Receive;
    interface AMSend;
    interface Timer<TMilli> as MilliTimer;
    interface SplitControl;
  }
}
implementation {

  message_t packet;

  bool locked;
  uint8_t counter = 0;
  
  event void Boot.booted() {
    call SplitControl.start();
  }
  
  event void MilliTimer.fired() {
    counter++;
    if (locked) {
      return;
     }
    else if (call AMSend.send(AM_BROADCAST_ADDR, &packet, 0) == SUCCESS) {
      call Leds.led0On();
      locked = TRUE;
    }
  }

  event message_t* Receive.receive(message_t* bufPtr, 
				   void* payload, uint8_t len) {
    call Leds.led1Toggle();
    return bufPtr;
  }

  event void AMSend.sendDone(message_t* bufPtr, error_t error) {
    if (&packet == bufPtr && error == SUCCESS) {
      locked = FALSE;
      call Leds.led0Off();
    }
  }

  event void SplitControl.startDone(error_t err) {
    call MilliTimer.startPeriodic(1000);
  }

  event void SplitControl.stopDone(error_t err) {
  }

}