msp430dmachannelp.nc

tinyos2.0版本驱动

/*
 * Copyright (c) 2005-2006 Arch Rock Corporation
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Arch Rock Corporation nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
 * ARCHED ROCK OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE
 */

/*
 * "Copyright (c) 2000-2005 The Regents of the University of California.  
 * All rights reserved.
 *
 * Permission to use, copy, modify, and distribute this software and its
 * documentation for any purpose, without fee, and without written agreement
 * is hereby granted, provided that the above copyright notice, the following
 * two paragraphs and the author appear in all copies of this software.
 * 
 * IN NO EVENT SHALL THE UNIVERSITY OF CALIFORNIA BE LIABLE TO ANY PARTY FOR
 * DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES ARISING OUT
 * OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN IF THE UNIVERSITY
 * OF CALIFORNIA HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 * 
 * THE UNIVERSITY OF CALIFORNIA SPECIFICALLY DISCLAIMS ANY WARRANTIES,
 * INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY
 * AND FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
 * ON AN "AS IS" BASIS, AND THE UNIVERSITY OF CALIFORNIA HAS NO OBLIGATION TO
 * PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS."
 */

/**
 * @author Ben Greenstein <[e-mail]>
 * @author Jonathan Hui <[e-mail]>
 * @author Joe Polastre <[e-mail]>
 * @version $Revision: 1.4 $ $Date: 2006/12/12 18:23:10 $
 */

#include "Msp430Dma.h"

generic module Msp430DmaChannelP() {

  provides interface Msp430DmaChannel as Channel;
  uses interface HplMsp430DmaChannel as HplChannel;

}

implementation {

  norace dma_channel_state_t gChannelState;
  norace dma_channel_trigger_t gChannelTrigger;
  
  async command void Channel.setupTransferRaw( uint16_t s, uint16_t t, 
					       void* src, void* dest, 
					       int size ) {
    call HplChannel.setStateRaw( s, t, src, dest, size );
  }
  
  async command error_t Channel.setupTransfer( dma_transfer_mode_t transfer_mode, 
					   dma_trigger_t trigger, 
					   dma_level_t level,
					   void *src_addr, 
					   void *dst_addr, 
					   uint16_t size,
					   dma_byte_t src_byte, 
					   dma_byte_t dst_byte,
					   dma_incr_t src_incr, 
					   dma_incr_t dst_incr ) {
    
    gChannelState.request = 0;
    gChannelState.abort = 0;
    gChannelState.interruptEnable = 1;
    gChannelState.interruptFlag = 0;
    gChannelState.enable = 0;          /* don't start an xfer */
    gChannelState.level = level;
    gChannelState.srcByte = src_byte;
    gChannelState.dstByte = dst_byte;
    gChannelState.srcIncrement = src_incr;
    gChannelState.dstIncrement = dst_incr;
    gChannelState.transferMode = transfer_mode;
    
    gChannelTrigger.trigger = trigger;
    
    call HplChannel.setState( gChannelState, gChannelTrigger,
			      src_addr, dst_addr, size );
    
    return SUCCESS;
    
  }
  
  async command error_t Channel.startTransfer() {
    call HplChannel.enableDMA();
    return SUCCESS;
  }
  
  async command error_t Channel.repeatTransfer( void *src_addr, 
						void *dst_addr, 
						uint16_t size ) {
    call HplChannel.setSrc( src_addr );
    call HplChannel.setDst(dst_addr);
    call HplChannel.setSize(size);
    call HplChannel.enableDMA();
    return SUCCESS;
  }
  
  async command error_t Channel.softwareTrigger() {
    if (gChannelTrigger.trigger != DMA_TRIGGER_DMAREQ) 
      return FAIL;
    call HplChannel.triggerDMA();
    return SUCCESS;
  }
  
  async command error_t Channel.stopTransfer() {
    if ( gChannelState.transferMode != DMA_BURST_BLOCK_TRANSFER ||
	 gChannelState.transferMode != DMA_REPEATED_BURST_BLOCK_TRANSFER)
      return FAIL;
    call HplChannel.disableDMA();
    return SUCCESS;
    
  }
  
  async event void HplChannel.transferDone( error_t error ) {
    signal Channel.transferDone( error );
  }

  default async event void Channel.transferDone( error_t error ) {}

}