referencecounterp.nc

tinyos2.0版本驱动

/*
 * Copyright (c) 2008 Stanford University.
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * - Redistributions of source code must retain the above copyright
 *   notice, this list of conditions and the following disclaimer.
 * - Redistributions in binary form must reproduce the above copyright
 *   notice, this list of conditions and the following disclaimer in the
 *   documentation and/or other materials provided with the
 *   distribution.
 * - Neither the name of the Stanford University nor the names of
 *   its contributors may be used to endorse or promote products derived
 *   from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
 * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL STANFORD
 * UNIVERSITY OR ITS CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
 * SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
 * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED
 * OF THE POSSIBILITY OF SUCH DAMAGE.
 */
 
/**
 * @author Kevin Klues <[e-mail]>
 */

module ReferenceCounterP {
  provides {
    interface ReferenceCounter;
  }
  uses {
    interface ThreadScheduler;
    interface ThreadQueue;
    interface Leds;
  }
}

implementation {
  void signalWaiters(refcounter_t* r) {
    thread_t* t;
    while((t = call ThreadQueue.dequeue(&(r->thread_queue))) != NULL)
      call ThreadScheduler.wakeupThread(t->id); 
  }

  async command void ReferenceCounter.init(refcounter_t* r) {
    atomic {
      r->count = 0;
      call ThreadQueue.init(&(r->thread_queue));  
    }
  }
  async command void ReferenceCounter.increment(refcounter_t* r) {
    atomic {
      if( r->count != 255 ) {
        r->count++;
        signalWaiters(r);
      }
    }
  }
  async command void ReferenceCounter.decrement(refcounter_t* r) {
    atomic {
      if( r->count > 0 ) {
        r->count--;
        signalWaiters(r);
      }
    }
  }
  async command void ReferenceCounter.waitOnValue(refcounter_t* r, uint8_t val) {
    atomic {
      while(r->count != val) {
        call ThreadQueue.enqueue(&(r->thread_queue), call ThreadScheduler.currentThreadInfo());
        call ThreadScheduler.suspendCurrentThread(); 
      }
    }
  }
  async command uint8_t ReferenceCounter.count(refcounter_t* r) {
    atomic return r->count;
  }
}