gethits.asp

来自「一本关于大学的书」· ASP 代码 · 共 49 行

<%@language=vbscript codepage=936 %>
<%
Option Explicit
'强制浏览器重新访问服务器下载页面，而不是从缓存读取页面
Response.Buffer = True
Response.Expires = -1
Response.ExpiresAbsolute = Now() - 1
Response.Expires = 0
Response.CacheControl = "no-cache"

Dim ProductID, Action, sql, rs, Hits
Const ChannelID=1000
ProductID = Trim(request("ProductID"))
Action = Trim(request("Action"))
%>
<!--#include file="../conn.asp"-->
<%
If Action = "Count" Then
    sql = "select sum(Hits) from PE_Product where ChannelID=" & ChannelID
    Set rs = conn.execute(sql)
    If IsNull(rs(0)) Then
        Hits = 0
    Else
        Hits = rs(0)
    End If
    rs.Close
    Set rs = Nothing
Else
    If ProductID = "" Then
        Hits = 0
    Else
        ProductID = CLng(ProductID)
        sql = "select Hits from PE_Product where ProductID=" & ProductID
        Set rs = server.CreateObject("ADODB.recordset")
        rs.open sql, conn, 1, 3
        If rs.bof And rs.EOF Then
            Hits = 0
        Else
            Hits = rs(0) + 1
            rs(0) = Hits
            rs.Update
        End If
        rs.Close
        Set rs = Nothing
    End If
End If
Response.Write "document.write('" & Hits & "');"
Call CloseConn
%>