📄 user_logout.asp

📁 一本关于大学的书
💻 ASP
字号:
<%@language=vbscript codepage=936 %>
<!--#include file="../Conn.asp"-->
<!--#include file="../inc/function.asp"-->
<!--#include file="../inc/Md5.asp"-->
<!--#include file="../API/API_Config.asp"-->
<%

Action = Trim(Request("action"))
Dim MemberName, APISysKey
MemberName = Request.Cookies(Site_Sn)("UserName")
APISysKey = LCase(MD5(MemberName&API_Key,16))

If Action <> "xml" Then
    Dim strTempMsg
    If API_Enable Then
        Dim iIndex, strLogoutParams
        strLogoutParams = "?syskey=" & APISysKey & "&username=" & MemberName
        For iIndex = 0 To UBound(arrUrlsSP2)
            strTempMsg = strTempMsg & "<script type=""text/javascript"" language=""JavaScript"" src=""" & arrUrlsSP2(iIndex) & strLogoutParams & """ charset=""gb2312""></script>"
        Next
    End If
    strTempMsg = "您已成功注销，期待您的再次光临!" & strTempMsg
    Call WriteSuccessMsg(strTempMsg, InstallDir & "Index.asp")
Else
    Response.Clear
    Response.ContentType = "text/xml; charset=gb2312"
    Response.Write "<?xml version=""1.0"" encoding=""gb2312""?>"
    Response.Write "<body>"
    Response.Write "<user>" & MemberName & "</user>"
    Response.Write "<checkstat>err</checkstat>"
    Response.Write "<errsource/>"
    Response.Write "<checkcode>0</checkcode>"
    If API_Enable And MemberName <> "" Then
        Response.Write "<syskey>" & APISysKey & "</syskey>"
        Dim intIndex
        For intIndex = 0 To UBound(arrUrlsSP2)
            Response.Write "<apiurl><![CDATA[" & arrUrlsSP2(intIndex) & "]]></apiurl>"
        Next
    Else
        Response.Write "<syskey/><apiurl/>"
    End If
    Response.Write "<savecookie/>"
    Response.Write "</body>"
End If
Dim iSubDomainIndex, strSite_Sn
If Enable_SubDomain Then
    For iSubDomainIndex = 0 To UBound(arrSubDomains)
        strSite_Sn = LCase(arrSubDomains(iSubDomainIndex) & Replace(Replace(DomainRoot & InstallDir, "/", ""), ".", ""))
        Response.Cookies(strSite_Sn).Domain = DomainRoot
        Response.Cookies(strSite_Sn)("UserName") = ""
        Response.Cookies(strSite_Sn)("UserPassword") = ""
        Response.Cookies(strSite_Sn)("LastPassword") = ""
    Next
Else
    Response.Cookies(Site_Sn)("UserName") = ""
    Response.Cookies(Site_Sn)("UserPassword") = ""
    Response.Cookies(Site_Sn)("LastPassword") = ""
End If
Call CloseConn
%>
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -