toya2_romram.ld

epson usb2.0 控制芯片 S1R72V05 固件程序。

/*
 *  @(#) $Id: toya2_ROMRAM.ld,v 1.2 2006/07/21 09:50:18 9564907 Exp $
 */

OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm","elf32-littlearm") 
OUTPUT_ARCH(arm)

PROVIDE(hardware_init_hook = 0);
PROVIDE(software_init_hook = 0);
PROVIDE(software_term_hook = 0);

SECTIONS
{

	/* FlashROM偵僟僂儞儘乕僪偡傞僙僋僔儑儞 */
/* /E: Download section in Flash ROM */
	.flash  0xC8000000 : AT(0xC8000000){
		*(.vector)
		*(.init)
	}

	. = ALIGN(16);

	/* RO(Code, Const)椞堟偺暔棟僟僂儞儘乕僪傾僪儗僗傪愝掕 */
	/* /E: Set the physical download address of the RO(Code, Const)area */
	__rocode_start = LOADADDR(.flash) + SIZEOF(.flash);
	__ro_start = __rocode_start;
	.rocode  0xC0000000 : AT(__rocode_start)
	{
		__text = .;
		*(.text)
		*(.text.*)
		*(.gnu.linkonce.t.*)
	}
	/* RO椞堟偺廔抂傾僪儗僗傪巜掕丅*/
	/* /E: Specify the end address of the RO area */
	__rocode_end = __rocode_start + SIZEOF(.rocode);
    _etext = .;
    PROVIDE (etext = .);

	. = ALIGN(16);

	/* RO(Code, Const)椞堟偺暔棟僟僂儞儘乕僪傾僪儗僗傪愝掕 */
	/* /E: Set the physical download address of the RO(Code, Const)area */
	__rodata_start = 0xC80B0000;
	.rodata  0xC00B0000 : AT(__rodata_start)
	{
		__rodata = .;
		*(.rodata)
		*(.rodata.*)
		*(.gnu.linkonce.r.*)
	}
	/* RO椞堟偺廔抂傾僪儗僗傪巜掕丅*/
	/* /E: Specify the end address of the RO area */
	__rodata_end = __rodata_start + SIZEOF(.rodata);
	__ro_end = __rodata_end;
	. = ALIGN(16);


	/* 弶婜抣晅偒僨乕僞椞堟偺暔棟僟僂儞儘乕僪傾僪儗僗傪愝掕 */
	/* /E: Set the physical download address of the initial value data area */
/*    __idata_start = __rodata_end;*/
    __idata_start = 0xC8100000;
	.rw1 0xC1000000 : AT(__idata_start)
	{
		__data_start = .;
		*(.data)
		*(.data.*)
		*(.gnu.linkonce.d.*)
	}

	/* 弶婜抣晅偒僨乕僞椞堟偺廔抂傾僪儗僗傪巜掕丅*/
	/* /E: Specify the end address of the initial value data area */
    __idata_end = __idata_start + SIZEOF(.rw1);
    _edata  =  . ;
    PROVIDE (edata = .);
    . = ALIGN(4);
	

	/* ZI乮Zero Initialize乯僨乕僞椞堟偺巜掕 */
	/* /E: Specification of the ZI(Zero Initialize)data area */
	.zi 0xC1001000 : {
		__bss_start = .;
		*(.bss)
		*(.bss.*)
		*(.gnu.linkonce.b.*)
		*(COMMON)
    }
	. = ALIGN(16);
	_end = .;
	__bss_end = .;
    PROVIDE (end = .)	;


    .comment 0 : { *(.comment) }	

  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to 
     the beginning of the section so we begin them at 0.  */

  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }

  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }

  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }

  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }

  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }
}