updatesql.pas

odac for oralce 8i,10g,11g easy to connect to oralce from delphi

unit UpdateSQL;

interface

uses
{$IFNDEF LINUX}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, Buttons,
  OdacVcl,
{$ELSE}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QDBCtrls,
  QExtCtrls, QGrids, QDBGrids, QStdCtrls, QComCtrls, QButtons, OdacClx,
{$ENDIF}
  Db, DBAccess, Ora, MemDS, OdacDemoFrame, OdacDemoForm;

type
  TUpdateSQLFrame = class(TOdacDemoFrame)
    OraQuery: TOraQuery;
    DBGrid: TDBGrid;
    DataSource: TDataSource;
    ToolBar: TPanel;
    meSQL: TMemo;
    OraUpdateSQL: TOraUpdateSQL;
    btOpen: TSpeedButton;
    btClose: TSpeedButton;
    btPrepare: TSpeedButton;
    btUnPrepare: TSpeedButton;
    btExecute: TSpeedButton;
    btBreak: TSpeedButton;
    cbNonBlocking: TCheckBox;
    Panel3: TPanel;
    Panel1: TPanel;
    btRefreshRecord: TSpeedButton;
    DBNavigator1: TDBNavigator;
    Splitter1: TSplitter;
    Panel6: TPanel;
    Panel2: TPanel;
    cbDeleteObject: TCheckBox;
    cbInsertObject: TCheckBox;
    cbModifyObject: TCheckBox;
    cbRefreshObject: TCheckBox;
    Panel4: TPanel;
    DeleteSQL: TOraSQL;
    InsertSQL: TOraSQL;
    RefreshQuery: TOraQuery;
    ModifyQuery: TOraQuery;
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
    procedure btPrepareClick(Sender: TObject);
    procedure btUnPrepareClick(Sender: TObject);
    procedure btExecuteClick(Sender: TObject);
    procedure meSQLExit(Sender: TObject);
    procedure btBreakClick(Sender: TObject);
    procedure btRefreshRecordClick(Sender: TObject);
    procedure cbNonBlockingClick(Sender: TObject);
    procedure cbObjectClick(Sender: TObject);
  private
    { Private declarations }
    procedure ShowState;
  public
    procedure Initialize; override;
    procedure SetDebug(Value: boolean); override;
  end;

implementation

{$IFDEF CLR}
{$R *.nfm}
{$ENDIF}
{$IFDEF WIN32}
{$R *.dfm}
{$ENDIF}
{$IFDEF LINUX}
{$R *.xfm}
{$ENDIF}

procedure TUpdateSQLFrame.ShowState;
var
  St:string;

  procedure AddSt(S:string);
  begin
    if St <> '' then
      St:= St + ', ';
    St:= St + S;
  end;

begin
  St:= '';

  if OraQuery.Prepared then begin
    AddSt('Prepared');

    if OraQuery.IsQuery then
      AddSt('IsQuery');

    if OraQuery.IsPLSQL then
      AddSt('IsPLSQL');
  end;

  if OraQuery.Active then
    AddSt('Active')
  else
    AddSt('Inactive');

  if OraQuery.Executing then
    AddSt('Executing');

  if OraQuery.Fetching then
    AddSt('Fetching');

  OdacForm.StatusBar.Panels[1].Text:= St;
end;

procedure TUpdateSQLFrame.meSQLExit(Sender: TObject);
begin
  if Trim(OraQuery.SQL.Text) <> Trim(meSQL.Lines.Text) then
    OraQuery.SQL.Text:= meSQL.Lines.Text;
  ShowState;
end;

procedure TUpdateSQLFrame.btOpenClick(Sender: TObject);
begin
  OraQuery.SQL.Assign(meSQL.Lines);
  try
    OraQuery.Open;
  finally
    ShowState;
  end;
end;

procedure TUpdateSQLFrame.btCloseClick(Sender: TObject);
begin
  OraQuery.Close;
  ShowState;
end;

procedure TUpdateSQLFrame.btPrepareClick(Sender: TObject);
begin
  OraQuery.SQL.Assign(meSQL.Lines);
  try
    OraQuery.Prepare;
  finally
    ShowState;
  end;
end;

procedure TUpdateSQLFrame.btUnPrepareClick(Sender: TObject);
begin
  OraQuery.UnPrepare;
  ShowState;
end;

procedure TUpdateSQLFrame.btExecuteClick(Sender: TObject);
begin
  OraQuery.SQL.Assign(meSQL.Lines);
  try
    OraQuery.Execute;
  finally
    ShowState;
  end;
end;

procedure TUpdateSQLFrame.Initialize;
begin
  inherited;

  OraQuery.Connection := Connection;
  DeleteSQL.Connection := Connection;
  InsertSQL.Connection := Connection;
  ModifyQuery.Connection := Connection;
  RefreshQuery.Connection := Connection;

  meSQL.Lines.Assign(OraQuery.SQL);
  ShowState;

  cbNonBlocking.Checked := OraQuery.NonBlocking;
end;

procedure TUpdateSQLFrame.btBreakClick(Sender: TObject);
begin
  try
    OraQuery.BreakExec;
  finally
    ShowState;
  end;
end;

procedure TUpdateSQLFrame.btRefreshRecordClick(Sender: TObject);
begin
  OraQuery.RefreshRecord;
end;

procedure TUpdateSQLFrame.SetDebug(Value: boolean);
begin
  OraQuery.Debug := Value;
end;

procedure TUpdateSQLFrame.cbNonBlockingClick(Sender: TObject);
begin
  OraQuery.NonBlocking := cbNonBlocking.Checked;
end;

procedure TUpdateSQLFrame.cbObjectClick(Sender: TObject);
  function GetComponent(cbObject: TCheckBox; Component: TComponent): TComponent;
  begin
    if cbObject.Checked then
      Result := Component
    else
      Result := nil;
  end;
begin
  OraUpdateSQL.DeleteObject := GetComponent(cbDeleteObject, DeleteSQL);
  OraUpdateSQL.InsertObject := GetComponent(cbInsertObject, InsertSQL);
  OraUpdateSQL.ModifyObject := GetComponent(cbModifyObject, ModifyQuery);
  OraUpdateSQL.RefreshObject := GetComponent(cbRefreshObject, RefreshQuery);
end;

end.