nb_kernel212_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,827 行 · 第 1/5 页

##
## $Id: nb_kernel212_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel212_ia32_sse2
.globl _nb_kernel212_ia32_sse2
nb_kernel212_ia32_sse2: 
_nb_kernel212_ia32_sse2:        
.set nb212_p_nri, 8
.set nb212_iinr, 12
.set nb212_jindex, 16
.set nb212_jjnr, 20
.set nb212_shift, 24
.set nb212_shiftvec, 28
.set nb212_fshift, 32
.set nb212_gid, 36
.set nb212_pos, 40
.set nb212_faction, 44
.set nb212_charge, 48
.set nb212_p_facel, 52
.set nb212_argkrf, 56
.set nb212_argcrf, 60
.set nb212_Vc, 64
.set nb212_type, 68
.set nb212_p_ntype, 72
.set nb212_vdwparam, 76
.set nb212_Vvdw, 80
.set nb212_p_tabscale, 84
.set nb212_VFtab, 88
.set nb212_invsqrta, 92
.set nb212_dvda, 96
.set nb212_p_gbtabscale, 100
.set nb212_GBtab, 104
.set nb212_p_nthreads, 108
.set nb212_count, 112
.set nb212_mtx, 116
.set nb212_outeriter, 120
.set nb212_inneriter, 124
.set nb212_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb212_ixO, 0
.set nb212_iyO, 16
.set nb212_izO, 32
.set nb212_ixH1, 48
.set nb212_iyH1, 64
.set nb212_izH1, 80
.set nb212_ixH2, 96
.set nb212_iyH2, 112
.set nb212_izH2, 128
.set nb212_jxO, 144
.set nb212_jyO, 160
.set nb212_jzO, 176
.set nb212_jxH1, 192
.set nb212_jyH1, 208
.set nb212_jzH1, 224
.set nb212_jxH2, 240
.set nb212_jyH2, 256
.set nb212_jzH2, 272
.set nb212_dxOO, 288
.set nb212_dyOO, 304
.set nb212_dzOO, 320
.set nb212_dxOH1, 336
.set nb212_dyOH1, 352
.set nb212_dzOH1, 368
.set nb212_dxOH2, 384
.set nb212_dyOH2, 400
.set nb212_dzOH2, 416
.set nb212_dxH1O, 432
.set nb212_dyH1O, 448
.set nb212_dzH1O, 464
.set nb212_dxH1H1, 480
.set nb212_dyH1H1, 496
.set nb212_dzH1H1, 512
.set nb212_dxH1H2, 528
.set nb212_dyH1H2, 544
.set nb212_dzH1H2, 560
.set nb212_dxH2O, 576
.set nb212_dyH2O, 592
.set nb212_dzH2O, 608
.set nb212_dxH2H1, 624
.set nb212_dyH2H1, 640
.set nb212_dzH2H1, 656
.set nb212_dxH2H2, 672
.set nb212_dyH2H2, 688
.set nb212_dzH2H2, 704
.set nb212_qqOO, 720
.set nb212_qqOH, 736
.set nb212_qqHH, 752
.set nb212_c6, 768
.set nb212_c12, 784
.set nb212_six, 800
.set nb212_twelve, 816
.set nb212_vctot, 832
.set nb212_Vvdwtot, 848
.set nb212_fixO, 864
.set nb212_fiyO, 880
.set nb212_fizO, 896
.set nb212_fixH1, 912
.set nb212_fiyH1, 928
.set nb212_fizH1, 944
.set nb212_fixH2, 960
.set nb212_fiyH2, 976
.set nb212_fizH2, 992
.set nb212_fjxO, 1008
.set nb212_fjyO, 1024
.set nb212_fjzO, 1040
.set nb212_fjxH1, 1056
.set nb212_fjyH1, 1072
.set nb212_fjzH1, 1088
.set nb212_fjxH2, 1104
.set nb212_fjyH2, 1120
.set nb212_fjzH2, 1136
.set nb212_half, 1152
.set nb212_three, 1168
.set nb212_rsqOO, 1184
.set nb212_rsqOH1, 1200
.set nb212_rsqOH2, 1216
.set nb212_rsqH1O, 1232
.set nb212_rsqH1H1, 1248
.set nb212_rsqH1H2, 1264
.set nb212_rsqH2O, 1280
.set nb212_rsqH2H1, 1296
.set nb212_rsqH2H2, 1312
.set nb212_rinvOO, 1328
.set nb212_rinvOH1, 1344
.set nb212_rinvOH2, 1360
.set nb212_rinvH1O, 1376
.set nb212_rinvH1H1, 1392
.set nb212_rinvH1H2, 1408
.set nb212_rinvH2O, 1424
.set nb212_rinvH2H1, 1440
.set nb212_rinvH2H2, 1456
.set nb212_two, 1472
.set nb212_krf, 1488
.set nb212_crf, 1504
.set nb212_is3, 1520
.set nb212_ii3, 1524
.set nb212_innerjjnr, 1528
.set nb212_innerk, 1532
.set nb212_n, 1536
.set nb212_nn1, 1540
.set nb212_nri, 1544
.set nb212_nouter, 1548
.set nb212_ninner, 1552
.set nb212_salign, 1556
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $1560,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb212_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb212_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb212_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb212_nouter(%esp)
        movl %eax,nb212_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb212_half(%esp)
        movl %ebx,nb212_half+4(%esp)
        movsd nb212_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## 6.0
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## 12.0
        movapd %xmm1,nb212_half(%esp)
        movapd %xmm2,nb212_two(%esp)
        movapd %xmm3,nb212_three(%esp)
        movapd %xmm4,nb212_six(%esp)
        movapd %xmm5,nb212_twelve(%esp)

        movl nb212_argkrf(%ebp),%esi
        movl nb212_argcrf(%ebp),%edi
        movsd (%esi),%xmm5
        movsd (%edi),%xmm6
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        movapd %xmm5,nb212_krf(%esp)
        movapd %xmm6,nb212_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb212_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb212_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb212_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb212_qqOO(%esp)
        movapd %xmm4,nb212_qqOH(%esp)
        movapd %xmm5,nb212_qqHH(%esp)

        xorpd %xmm0,%xmm0
        movl  nb212_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb212_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb212_vdwparam(%ebp),%eax
        movlpd (%eax,%edx,8),%xmm0
        movhpd 8(%eax,%edx,8),%xmm0
        movhlps %xmm0,%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb212_c6(%esp)
        movapd %xmm1,nb212_c12(%esp)

_nb_kernel212_ia32_sse2.nb212_threadloop: 
        movl  nb212_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel212_ia32_sse2.nb212_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel212_ia32_sse2.nb212_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb212_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb212_n(%esp)
        movl %ebx,nb212_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel212_ia32_sse2.nb212_outerstart
        jmp _nb_kernel212_ia32_sse2.nb212_end

_nb_kernel212_ia32_sse2.nb212_outerstart: 
        ## ebx contains number of outer iterations
        addl nb212_nouter(%esp),%ebx
        movl %ebx,nb212_nouter(%esp)

_nb_kernel212_ia32_sse2.nb212_outer: 
        movl  nb212_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb212_is3(%esp)      ## store is3 

        movl  nb212_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movlpd (%eax,%ebx,8),%xmm0
        movlpd 8(%eax,%ebx,8),%xmm1
        movlpd 16(%eax,%ebx,8),%xmm2

        movl  nb212_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb212_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb212_ii3(%esp)

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        addsd (%eax,%ebx,8),%xmm3
        addsd 8(%eax,%ebx,8),%xmm4
        addsd 16(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb212_ixO(%esp)
        movapd %xmm4,nb212_iyO(%esp)
        movapd %xmm5,nb212_izO(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm0
        addsd 32(%eax,%ebx,8),%xmm1
        addsd 40(%eax,%ebx,8),%xmm2
        addsd 48(%eax,%ebx,8),%xmm3
        addsd 56(%eax,%ebx,8),%xmm4
        addsd 64(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb212_ixH1(%esp)
        movapd %xmm1,nb212_iyH1(%esp)
        movapd %xmm2,nb212_izH1(%esp)
        movapd %xmm3,nb212_ixH2(%esp)
        movapd %xmm4,nb212_iyH2(%esp)
        movapd %xmm5,nb212_izH2(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb212_vctot(%esp)
        movapd %xmm4,nb212_Vvdwtot(%esp)
        movapd %xmm4,nb212_fixO(%esp)
        movapd %xmm4,nb212_fiyO(%esp)
        movapd %xmm4,nb212_fizO(%esp)
        movapd %xmm4,nb212_fixH1(%esp)
        movapd %xmm4,nb212_fiyH1(%esp)
        movapd %xmm4,nb212_fizH1(%esp)
        movapd %xmm4,nb212_fixH2(%esp)
        movapd %xmm4,nb212_fiyH2(%esp)
        movapd %xmm4,nb212_fizH2(%esp)

        movl  nb212_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms