nb_kernel303_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,228 行 · 第 1/5 页

.equiv          nb303nf_jindex,         16
.equiv          nb303nf_jjnr,           20
.equiv          nb303nf_shift,          24
.equiv          nb303nf_shiftvec,       28
.equiv          nb303nf_fshift,         32
.equiv          nb303nf_gid,            36
.equiv          nb303nf_pos,            40
.equiv          nb303nf_faction,        44
.equiv          nb303nf_charge,         48
.equiv          nb303nf_p_facel,        52
.equiv          nb303nf_argkrf,         56
.equiv          nb303nf_argcrf,         60
.equiv          nb303nf_Vc,             64
.equiv          nb303nf_type,           68
.equiv          nb303nf_p_ntype,        72
.equiv          nb303nf_vdwparam,       76
.equiv          nb303nf_Vvdw,           80
.equiv          nb303nf_p_tabscale,     84
.equiv          nb303nf_VFtab,          88
.equiv          nb303nf_invsqrta,       92
.equiv          nb303nf_dvda,           96
.equiv          nb303nf_p_gbtabscale,   100
.equiv          nb303nf_GBtab,          104
.equiv          nb303nf_p_nthreads,     108
.equiv          nb303nf_count,          112
.equiv          nb303nf_mtx,            116
.equiv          nb303nf_outeriter,      120
.equiv          nb303nf_inneriter,      124
.equiv          nb303nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb303nf_ixM,            0
.equiv          nb303nf_iyM,            16
.equiv          nb303nf_izM,            32
.equiv          nb303nf_ixH1,           48
.equiv          nb303nf_iyH1,           64
.equiv          nb303nf_izH1,           80
.equiv          nb303nf_ixH2,           96
.equiv          nb303nf_iyH2,           112
.equiv          nb303nf_izH2,           128
.equiv          nb303nf_iqM,            144
.equiv          nb303nf_iqH,            160
.equiv          nb303nf_qqM,            176
.equiv          nb303nf_qqH,            192
.equiv          nb303nf_rinvM,          208
.equiv          nb303nf_rinvH1,         224
.equiv          nb303nf_rinvH2,         240
.equiv          nb303nf_rM,             256
.equiv          nb303nf_rH1,            272
.equiv          nb303nf_rH2,            288
.equiv          nb303nf_tsc,            304
.equiv          nb303nf_vctot,          320
.equiv          nb303nf_half,           336
.equiv          nb303nf_three,          352
.equiv          nb303nf_is3,            368
.equiv          nb303nf_ii3,            372
.equiv          nb303nf_innerjjnr,      376
.equiv          nb303nf_innerk,         380
.equiv          nb303nf_n,              384
.equiv          nb303nf_nn1,            388
.equiv          nb303nf_nri,            392
.equiv          nb303nf_nouter,         396
.equiv          nb303nf_ninner,         400
.equiv          nb303nf_salign,         404
	push ebp
	mov ebp,esp	
    push eax
    push ebx
    push ecx
    push edx
	push esi
	push edi
	sub esp, 408		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb303nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb303nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb303nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb303nf_nouter], eax
	mov [esp + nb303nf_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb303nf_half], eax
	mov [esp + nb303nf_half+4], ebx
	movsd xmm1, [esp + nb303nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb303nf_half], xmm1
	movapd [esp + nb303nf_three], xmm3

	mov eax, [ebp + nb303nf_p_tabscale]
	movsd xmm3, [eax]
	shufpd xmm3, xmm3, 0 
	movapd [esp + nb303nf_tsc], xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb303nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb303nf_charge]
	movsd xmm3, [edx + ebx*8 + 8]	
	movsd xmm4, [edx + ebx*8 + 24]	
	mov esi, [ebp + nb303nf_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb303nf_iqH], xmm3
	movapd [esp + nb303nf_iqM], xmm4
	
.nb303nf_threadloop:
        mov   esi, [ebp + nb303nf_count]        ;# pointer to sync counter
        mov   eax, [esi]
.nb303nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           	;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb303nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb303nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb303nf_n], eax
        mov [esp + nb303nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb303nf_outerstart
        jmp .nb303nf_end

.nb303nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb303nf_nouter]
	mov [esp + nb303nf_nouter], ebx

.nb303nf_outer:
	mov   eax, [ebp + nb303nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 

	mov   eax, [ebp + nb303nf_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb303nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb303nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb303nf_ii3], ebx

	addsd xmm3, [eax + ebx*8 + 24]
	addsd xmm4, [eax + ebx*8 + 32]
	addsd xmm5, [eax + ebx*8 + 40]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb303nf_ixH1], xmm3
	movapd [esp + nb303nf_iyH1], xmm4
	movapd [esp + nb303nf_izH1], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 48]
	addsd xmm1, [eax + ebx*8 + 56]
	addsd xmm2, [eax + ebx*8 + 64]		
	addsd xmm3, [eax + ebx*8 + 72]
	addsd xmm4, [eax + ebx*8 + 80]
	addsd xmm5, [eax + ebx*8 + 88]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb303nf_ixH2], xmm0
	movapd [esp + nb303nf_iyH2], xmm1
	movapd [esp + nb303nf_izH2], xmm2
	movapd [esp + nb303nf_ixM], xmm3
	movapd [esp + nb303nf_iyM], xmm4
	movapd [esp + nb303nf_izM], xmm5
	
	;# clear vctot 
	xorpd xmm4, xmm4
	movapd [esp + nb303nf_vctot], xmm4
	
	mov   eax, [ebp + nb303nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb303nf_pos]
	mov   eax, [ebp + nb303nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb303nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb303nf_ninner]
	mov   [esp + nb303nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb303nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb303nf_unroll_loop
	jmp   .nb303nf_checksingle
.nb303nf_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb303nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb303nf_innerjjnr],  8	;# advance pointer (unrolled 2) 
	mov esi, [ebp + nb303nf_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3	     
	mulpd  xmm3, [esp + nb303nf_iqM]
	mulpd  xmm4, [esp + nb303nf_iqH]

	movapd  [esp + nb303nf_qqM], xmm3
	movapd  [esp + nb303nf_qqH], xmm4	

	mov esi, [ebp + nb303nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 	
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		

	;# move ixM-izM to xmm4-xmm6 
	movapd xmm4, [esp + nb303nf_ixM]
	movapd xmm5, [esp + nb303nf_iyM]
	movapd xmm6, [esp + nb303nf_izM]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqM in xmm7 

	;# move ixH1-izH1 to xmm4-xmm6 
	movapd xmm4, [esp + nb303nf_ixH1]
	movapd xmm5, [esp + nb303nf_iyH1]
	movapd xmm6, [esp + nb303nf_izH1]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm6, xmm5
	addpd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movapd xmm3, [esp + nb303nf_ixH2]
	movapd xmm4, [esp + nb303nf_iyH2]
	movapd xmm5, [esp + nb303nf_izH2]

	;# calc dr 
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2

	;# square it 
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	addpd xmm5, xmm4
	addpd xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqM in xmm7 

	;# start with rsqM - put seed in xmm2 
	cvtpd2ps xmm2, xmm7	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb303nf_three]
	mulpd   xmm2, xmm7	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb303nf_half] ;# iter1 ( new lu) 

	movapd xmm2, xmm7
	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm2, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb303nf_three]
	subpd xmm4, xmm2	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb303nf_half] ;# rinv 
	movapd  [esp + nb303nf_rinvM], xmm4	;# rinvM in xmm4 
	mulpd   xmm7, xmm4
	movapd  [esp + nb303nf_rM], xmm7	;# r in xmm7 
	
	;# rsqH1 - seed in xmm2 
	cvtpd2ps xmm2, xmm6	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb303nf_three]
	mulpd   xmm2, xmm6	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb303nf_half] ;# iter1 ( new lu) 

	movapd xmm2, xmm6
	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm2, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb303nf_three]
	subpd xmm4, xmm2	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb303nf_half] ;# rinv 
	movapd [esp + nb303nf_rinvH1], xmm4	;# rinvH1 
	mulpd  xmm6, xmm4
	movapd [esp + nb303nf_rH1], xmm6	;# rH1 
	
	;# rsqH2 - seed in xmm2 
	cvtpd2ps xmm2, xmm5	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb303nf_three]
	mulpd   xmm2, xmm5	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb303nf_half] ;# iter1 ( new lu) 

	movapd xmm2, xmm5
	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm2, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb303nf_three]
	subpd xmm4, xmm2	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb303nf_half] ;# rinv 
	movapd [esp + nb303nf_rinvH2], xmm4 ;# rinv 
	mulpd xmm5, xmm4
	movapd [esp + nb303nf_rH2], xmm5 ;# r 

	;# do M interactions 
	;# rM is still in xmm7 
	mulpd xmm7, [esp + nb303nf_tsc]
	cvttpd2pi mm6, xmm7	;# mm6 = lu idx 
	cvtpi2pd xmm6, mm6
	subpd xmm7, xmm6
	movapd xmm1, xmm7	;# xmm1=eps 
	movapd xmm2, xmm1	
	mulpd  xmm2, xmm2	;# xmm2=eps2 
	
	pslld mm6, 2		;# idx *= 4 
	mov  esi, [ebp + nb303nf_VFtab]
	movd eax, mm6
	psrlq mm6, 32
	movd ebx, mm6		;# indices in eax/ebx 

	movlpd xmm4, [esi + eax*8]	;# Y1	
	movlpd xmm3, [esi + ebx*8]	;# Y2
	movhpd xmm4, [esi + eax*8 + 8]	;# Y1 F1 	
	movhpd xmm3, [esi + ebx*8 + 8]	;# Y2 F2 

	movapd xmm5, xmm4
	unpcklpd xmm4, xmm3	;# Y1 Y2 
	unpckhpd xmm5, xmm3	;# F1 F2 

	movlpd xmm6, [esi + eax*8 + 16]	;# G1
	movlpd xmm3, [esi + ebx*8 + 16]	;# G2
	movhpd xmm6, [esi + eax*8 + 24]	;# G1 H1 	
	movhpd xmm3, [esi + ebx*8 + 24]	;# G2 H2 

	movapd xmm7, xmm6
	unpcklpd xmm6, xmm3	;# G1 G2 
	unpckhpd xmm7, xmm3	;# H1 H2 
	;# coulomb table ready, in xmm4-xmm7  		
	mulpd  xmm6, xmm1	;# xmm6=Geps 
	mulpd  xmm7, xmm2	;# xmm7=Heps2 
	addpd  xmm5, xmm6
	addpd  xmm5, xmm7	;# xmm5=Fp 	
	movapd xmm3, [esp + nb303nf_qqM]
	mulpd  xmm5, xmm1 ;# xmm5=eps*Fp 
	addpd  xmm5, xmm4 ;# xmm5=VV 
	mulpd  xmm5, xmm3 ;# vcoul=qq*VV  
    ;# at this point mm5 contains vcoul 
    ;# increment vcoul - then we can get rid of mm5 
    addpd  xmm5, [esp + nb303nf_vctot]
    movapd [esp + nb303nf_vctot], xmm5