nb_kernel204_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,835 行 · 第 1/5 页

##
## $Id: nb_kernel204_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel204_ia32_sse2
.globl _nb_kernel204_ia32_sse2
nb_kernel204_ia32_sse2: 
_nb_kernel204_ia32_sse2:        
.set nb204_p_nri, 8
.set nb204_iinr, 12
.set nb204_jindex, 16
.set nb204_jjnr, 20
.set nb204_shift, 24
.set nb204_shiftvec, 28
.set nb204_fshift, 32
.set nb204_gid, 36
.set nb204_pos, 40
.set nb204_faction, 44
.set nb204_charge, 48
.set nb204_p_facel, 52
.set nb204_argkrf, 56
.set nb204_argcrf, 60
.set nb204_Vc, 64
.set nb204_type, 68
.set nb204_p_ntype, 72
.set nb204_vdwparam, 76
.set nb204_Vvdw, 80
.set nb204_p_tabscale, 84
.set nb204_VFtab, 88
.set nb204_invsqrta, 92
.set nb204_dvda, 96
.set nb204_p_gbtabscale, 100
.set nb204_GBtab, 104
.set nb204_p_nthreads, 108
.set nb204_count, 112
.set nb204_mtx, 116
.set nb204_outeriter, 120
.set nb204_inneriter, 124
.set nb204_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb204_ixM, 0
.set nb204_iyM, 16
.set nb204_izM, 32
.set nb204_ixH1, 48
.set nb204_iyH1, 64
.set nb204_izH1, 80
.set nb204_ixH2, 96
.set nb204_iyH2, 112
.set nb204_izH2, 128
.set nb204_jxM, 144
.set nb204_jyM, 160
.set nb204_jzM, 176
.set nb204_jxH1, 192
.set nb204_jyH1, 208
.set nb204_jzH1, 224
.set nb204_jxH2, 240
.set nb204_jyH2, 256
.set nb204_jzH2, 272
.set nb204_dxMM, 288
.set nb204_dyMM, 304
.set nb204_dzMM, 320
.set nb204_dxMH1, 336
.set nb204_dyMH1, 352
.set nb204_dzMH1, 368
.set nb204_dxMH2, 384
.set nb204_dyMH2, 400
.set nb204_dzMH2, 416
.set nb204_dxH1M, 432
.set nb204_dyH1M, 448
.set nb204_dzH1M, 464
.set nb204_dxH1H1, 480
.set nb204_dyH1H1, 496
.set nb204_dzH1H1, 512
.set nb204_dxH1H2, 528
.set nb204_dyH1H2, 544
.set nb204_dzH1H2, 560
.set nb204_dxH2M, 576
.set nb204_dyH2M, 592
.set nb204_dzH2M, 608
.set nb204_dxH2H1, 624
.set nb204_dyH2H1, 640
.set nb204_dzH2H1, 656
.set nb204_dxH2H2, 672
.set nb204_dyH2H2, 688
.set nb204_dzH2H2, 704
.set nb204_qqMM, 720
.set nb204_qqMH, 736
.set nb204_qqHH, 752
.set nb204_vctot, 768
.set nb204_fixM, 784
.set nb204_fiyM, 800
.set nb204_fizM, 816
.set nb204_fixH1, 832
.set nb204_fiyH1, 848
.set nb204_fizH1, 864
.set nb204_fixH2, 880
.set nb204_fiyH2, 896
.set nb204_fizH2, 912
.set nb204_fjxM, 928
.set nb204_fjyM, 944
.set nb204_fjzM, 960
.set nb204_fjxH1, 976
.set nb204_fjyH1, 992
.set nb204_fjzH1, 1008
.set nb204_fjxH2, 1024
.set nb204_fjyH2, 1040
.set nb204_fjzH2, 1056
.set nb204_half, 1072
.set nb204_three, 1088
.set nb204_rsqMM, 1104
.set nb204_rsqMH1, 1120
.set nb204_rsqMH2, 1136
.set nb204_rsqH1M, 1152
.set nb204_rsqH1H1, 1168
.set nb204_rsqH1H2, 1184
.set nb204_rsqH2M, 1200
.set nb204_rsqH2H1, 1216
.set nb204_rsqH2H2, 1232
.set nb204_rinvMM, 1248
.set nb204_rinvMH1, 1264
.set nb204_rinvMH2, 1280
.set nb204_rinvH1M, 1296
.set nb204_rinvH1H1, 1312
.set nb204_rinvH1H2, 1328
.set nb204_rinvH2M, 1344
.set nb204_rinvH2H1, 1360
.set nb204_rinvH2H2, 1376
.set nb204_two, 1392
.set nb204_krf, 1408
.set nb204_crf, 1424
.set nb204_is3, 1440
.set nb204_ii3, 1444
.set nb204_innerjjnr, 1448
.set nb204_innerk, 1452
.set nb204_n, 1456
.set nb204_nn1, 1460
.set nb204_nri, 1464
.set nb204_nouter, 1468
.set nb204_ninner, 1472
.set nb204_salign, 1476
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $1480,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb204_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb204_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb204_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb204_nouter(%esp)
        movl %eax,nb204_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb204_half(%esp)
        movl %ebx,nb204_half+4(%esp)
        movsd nb204_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb204_half(%esp)
        movapd %xmm2,nb204_two(%esp)
        movapd %xmm3,nb204_three(%esp)

        movl nb204_argkrf(%ebp),%esi
        movl nb204_argcrf(%ebp),%edi
        movsd (%esi),%xmm5
        movsd (%edi),%xmm6
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        movapd %xmm5,nb204_krf(%esp)
        movapd %xmm6,nb204_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb204_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb204_charge(%ebp),%edx
        movsd 24(%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb204_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb204_qqMM(%esp)
        movapd %xmm4,nb204_qqMH(%esp)
        movapd %xmm5,nb204_qqHH(%esp)

_nb_kernel204_ia32_sse2.nb204_threadloop: 
        movl  nb204_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel204_ia32_sse2.nb204_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel204_ia32_sse2.nb204_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb204_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb204_n(%esp)
        movl %ebx,nb204_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel204_ia32_sse2.nb204_outerstart
        jmp _nb_kernel204_ia32_sse2.nb204_end

_nb_kernel204_ia32_sse2.nb204_outerstart: 
        ## ebx contains number of outer iterations
        addl nb204_nouter(%esp),%ebx
        movl %ebx,nb204_nouter(%esp)

_nb_kernel204_ia32_sse2.nb204_outer: 
        movl  nb204_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb204_is3(%esp)      ## store is3 

        movl  nb204_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb204_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb204_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb204_ii3(%esp)

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm3
        addsd 32(%eax,%ebx,8),%xmm4
        addsd 40(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb204_ixH1(%esp)
        movapd %xmm4,nb204_iyH1(%esp)
        movapd %xmm5,nb204_izH1(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 48(%eax,%ebx,8),%xmm0
        addsd 56(%eax,%ebx,8),%xmm1
        addsd 64(%eax,%ebx,8),%xmm2
        addsd 72(%eax,%ebx,8),%xmm3
        addsd 80(%eax,%ebx,8),%xmm4
        addsd 88(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb204_ixH2(%esp)
        movapd %xmm1,nb204_iyH2(%esp)
        movapd %xmm2,nb204_izH2(%esp)
        movapd %xmm3,nb204_ixM(%esp)
        movapd %xmm4,nb204_iyM(%esp)
        movapd %xmm5,nb204_izM(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb204_vctot(%esp)
        movapd %xmm4,nb204_fixM(%esp)
        movapd %xmm4,nb204_fiyM(%esp)
        movapd %xmm4,nb204_fizM(%esp)
        movapd %xmm4,nb204_fixH1(%esp)
        movapd %xmm4,nb204_fiyH1(%esp)
        movapd %xmm4,nb204_fizH1(%esp)
        movapd %xmm4,nb204_fixH2(%esp)
        movapd %xmm4,nb204_fiyH2(%esp)
        movapd %xmm4,nb204_fizH2(%esp)

        movl  nb204_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb204_pos(%ebp),%esi
        movl  nb204_faction(%ebp),%edi
        movl  nb204_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb204_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb204_ninner(%esp),%ecx
        movl  %ecx,nb204_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb204_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel204_ia32_sse2.nb204_unroll_loop
        jmp   _nb_kernel204_ia32_sse2.nb204_checksingle
_nb_kernel204_ia32_sse2.nb204_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb204_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb204_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 

        movl nb204_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move j coordinates to local temp variables 
        movlpd 24(%esi,%eax,8),%xmm2