nb_kernel304_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,884 行 · 第 1/5 页

##
## $Id: nb_kernel304_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:36 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel304_ia32_sse2
.globl _nb_kernel304_ia32_sse2
nb_kernel304_ia32_sse2: 
_nb_kernel304_ia32_sse2:        
.set nb304_p_nri, 8
.set nb304_iinr, 12
.set nb304_jindex, 16
.set nb304_jjnr, 20
.set nb304_shift, 24
.set nb304_shiftvec, 28
.set nb304_fshift, 32
.set nb304_gid, 36
.set nb304_pos, 40
.set nb304_faction, 44
.set nb304_charge, 48
.set nb304_p_facel, 52
.set nb304_argkrf, 56
.set nb304_argcrf, 60
.set nb304_Vc, 64
.set nb304_type, 68
.set nb304_p_ntype, 72
.set nb304_vdwparam, 76
.set nb304_Vvdw, 80
.set nb304_p_tabscale, 84
.set nb304_VFtab, 88
.set nb304_invsqrta, 92
.set nb304_dvda, 96
.set nb304_p_gbtabscale, 100
.set nb304_GBtab, 104
.set nb304_p_nthreads, 108
.set nb304_count, 112
.set nb304_mtx, 116
.set nb304_outeriter, 120
.set nb304_inneriter, 124
.set nb304_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb304_ixM, 0
.set nb304_iyM, 16
.set nb304_izM, 32
.set nb304_ixH1, 48
.set nb304_iyH1, 64
.set nb304_izH1, 80
.set nb304_ixH2, 96
.set nb304_iyH2, 112
.set nb304_izH2, 128
.set nb304_jxM, 144
.set nb304_jyM, 160
.set nb304_jzM, 176
.set nb304_jxH1, 192
.set nb304_jyH1, 208
.set nb304_jzH1, 224
.set nb304_jxH2, 240
.set nb304_jyH2, 256
.set nb304_jzH2, 272
.set nb304_dxMM, 288
.set nb304_dyMM, 304
.set nb304_dzMM, 320
.set nb304_dxMH1, 336
.set nb304_dyMH1, 352
.set nb304_dzMH1, 368
.set nb304_dxMH2, 384
.set nb304_dyMH2, 400
.set nb304_dzMH2, 416
.set nb304_dxH1M, 432
.set nb304_dyH1M, 448
.set nb304_dzH1M, 464
.set nb304_dxH1H1, 480
.set nb304_dyH1H1, 496
.set nb304_dzH1H1, 512
.set nb304_dxH1H2, 528
.set nb304_dyH1H2, 544
.set nb304_dzH1H2, 560
.set nb304_dxH2M, 576
.set nb304_dyH2M, 592
.set nb304_dzH2M, 608
.set nb304_dxH2H1, 624
.set nb304_dyH2H1, 640
.set nb304_dzH2H1, 656
.set nb304_dxH2H2, 672
.set nb304_dyH2H2, 688
.set nb304_dzH2H2, 704
.set nb304_qqMM, 720
.set nb304_qqMH, 736
.set nb304_qqHH, 752
.set nb304_two, 768
.set nb304_tsc, 784
.set nb304_vctot, 800
.set nb304_fixM, 816
.set nb304_fiyM, 832
.set nb304_fizM, 848
.set nb304_fixH1, 864
.set nb304_fiyH1, 880
.set nb304_fizH1, 896
.set nb304_fixH2, 912
.set nb304_fiyH2, 928
.set nb304_fizH2, 944
.set nb304_fjxM, 960
.set nb304_fjyM, 976
.set nb304_fjzM, 992
.set nb304_fjxH1, 1008
.set nb304_fjyH1, 1024
.set nb304_fjzH1, 1040
.set nb304_fjxH2, 1056
.set nb304_fjyH2, 1072
.set nb304_fjzH2, 1088
.set nb304_half, 1104
.set nb304_three, 1120
.set nb304_rsqMM, 1136
.set nb304_rsqMH1, 1152
.set nb304_rsqMH2, 1168
.set nb304_rsqH1M, 1184
.set nb304_rsqH1H1, 1200
.set nb304_rsqH1H2, 1216
.set nb304_rsqH2M, 1232
.set nb304_rsqH2H1, 1248
.set nb304_rsqH2H2, 1264
.set nb304_rinvMM, 1280
.set nb304_rinvMH1, 1296
.set nb304_rinvMH2, 1312
.set nb304_rinvH1M, 1328
.set nb304_rinvH1H1, 1344
.set nb304_rinvH1H2, 1360
.set nb304_rinvH2M, 1376
.set nb304_rinvH2H1, 1392
.set nb304_rinvH2H2, 1408
.set nb304_is3, 1424
.set nb304_ii3, 1428
.set nb304_innerjjnr, 1432
.set nb304_innerk, 1436
.set nb304_n, 1440
.set nb304_nn1, 1444
.set nb304_nri, 1448
.set nb304_nouter, 1452
.set nb304_ninner, 1456
.set nb304_salign, 1460
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $1464,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb304_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb304_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb304_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb304_nouter(%esp)
        movl %eax,nb304_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb304_half(%esp)
        movl %ebx,nb304_half+4(%esp)
        movsd nb304_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb304_half(%esp)
        movapd %xmm2,nb304_two(%esp)
        movapd %xmm3,nb304_three(%esp)

        movl nb304_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb304_tsc(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb304_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb304_charge(%ebp),%edx
        movsd 24(%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb304_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb304_qqMM(%esp)
        movapd %xmm4,nb304_qqMH(%esp)
        movapd %xmm5,nb304_qqHH(%esp)

_nb_kernel304_ia32_sse2.nb304_threadloop: 
        movl  nb304_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel304_ia32_sse2.nb304_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel304_ia32_sse2.nb304_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb304_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb304_n(%esp)
        movl %ebx,nb304_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel304_ia32_sse2.nb304_outerstart
        jmp _nb_kernel304_ia32_sse2.nb304_end

_nb_kernel304_ia32_sse2.nb304_outerstart: 
        ## ebx contains number of outer iterations
        addl nb304_nouter(%esp),%ebx
        movl %ebx,nb304_nouter(%esp)

_nb_kernel304_ia32_sse2.nb304_outer: 
        movl  nb304_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb304_is3(%esp)      ## store is3 

        movl  nb304_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb304_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb304_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb304_ii3(%esp)

        movapd %xmm0,%xmm3
        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm3
        addsd 32(%eax,%ebx,8),%xmm4
        addsd 40(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb304_ixH1(%esp)
        movapd %xmm4,nb304_iyH1(%esp)
        movapd %xmm5,nb304_izH1(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 48(%eax,%ebx,8),%xmm0
        addsd 56(%eax,%ebx,8),%xmm1
        addsd 64(%eax,%ebx,8),%xmm2
        addsd 72(%eax,%ebx,8),%xmm3
        addsd 80(%eax,%ebx,8),%xmm4
        addsd 88(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb304_ixH2(%esp)
        movapd %xmm1,nb304_iyH2(%esp)
        movapd %xmm2,nb304_izH2(%esp)
        movapd %xmm3,nb304_ixM(%esp)
        movapd %xmm4,nb304_iyM(%esp)
        movapd %xmm5,nb304_izM(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb304_vctot(%esp)
        movapd %xmm4,nb304_fixM(%esp)
        movapd %xmm4,nb304_fiyM(%esp)
        movapd %xmm4,nb304_fizM(%esp)
        movapd %xmm4,nb304_fixH1(%esp)
        movapd %xmm4,nb304_fiyH1(%esp)
        movapd %xmm4,nb304_fizH1(%esp)
        movapd %xmm4,nb304_fixH2(%esp)
        movapd %xmm4,nb304_fiyH2(%esp)
        movapd %xmm4,nb304_fizH2(%esp)

        movl  nb304_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb304_pos(%ebp),%esi
        movl  nb304_faction(%ebp),%edi
        movl  nb304_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb304_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb304_ninner(%esp),%ecx
        movl  %ecx,nb304_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb304_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel304_ia32_sse2.nb304_unroll_loop
        jmp   _nb_kernel304_ia32_sse2.nb304_checksingle
_nb_kernel304_ia32_sse2.nb304_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb304_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb304_innerjjnr(%esp)            ## advance pointer (unrolled 2) 

        movl nb304_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move j coordinates to local temp variables 
        movlpd 24(%esi,%eax,8),%xmm2
        movlpd 32(%esi,%eax,8),%xmm3
        movlpd 40(%esi,%eax,8),%xmm4
        movlpd 48(%esi,%eax,8),%xmm5
        movlpd 56(%esi,%eax,8),%xmm6
        movlpd 64(%esi,%eax,8),%xmm7
        movhpd 24(%esi,%ebx,8),%xmm2
        movhpd 32(%esi,%ebx,8),%xmm3
        movhpd 40(%esi,%ebx,8),%xmm4
        movhpd 48(%esi,%ebx,8),%xmm5
        movhpd 56(%esi,%ebx,8),%xmm6
        movhpd 64(%esi,%ebx,8),%xmm7
        movapd  %xmm2,nb304_jxH1(%esp)
        movapd  %xmm3,nb304_jyH1(%esp)
        movapd  %xmm4,nb304_jzH1(%esp)