nb_kernel430_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,690 行 · 第 1/4 页

##
## $Id: nb_kernel430_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:37 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel430_ia32_sse2
.globl _nb_kernel430_ia32_sse2
nb_kernel430_ia32_sse2: 
_nb_kernel430_ia32_sse2:        
.set nb430_p_nri, 8
.set nb430_iinr, 12
.set nb430_jindex, 16
.set nb430_jjnr, 20
.set nb430_shift, 24
.set nb430_shiftvec, 28
.set nb430_fshift, 32
.set nb430_gid, 36
.set nb430_pos, 40
.set nb430_faction, 44
.set nb430_charge, 48
.set nb430_p_facel, 52
.set nb430_argkrf, 56
.set nb430_argcrf, 60
.set nb430_Vc, 64
.set nb430_type, 68
.set nb430_p_ntype, 72
.set nb430_vdwparam, 76
.set nb430_Vvdw, 80
.set nb430_p_tabscale, 84
.set nb430_VFtab, 88
.set nb430_invsqrta, 92
.set nb430_dvda, 96
.set nb430_p_gbtabscale, 100
.set nb430_GBtab, 104
.set nb430_p_nthreads, 108
.set nb430_count, 112
.set nb430_mtx, 116
.set nb430_outeriter, 120
.set nb430_inneriter, 124
.set nb430_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb430_ix, 0
.set nb430_iy, 16
.set nb430_iz, 32
.set nb430_iq, 48
.set nb430_dx, 64
.set nb430_dy, 80
.set nb430_dz, 96
.set nb430_two, 112
.set nb430_gbtsc, 128
.set nb430_tsc, 144
.set nb430_qq, 160
.set nb430_c6, 176
.set nb430_c12, 192
.set nb430_fscal, 208
.set nb430_vctot, 224
.set nb430_Vvdwtot, 240
.set nb430_fix, 256
.set nb430_fiy, 272
.set nb430_fiz, 288
.set nb430_half, 304
.set nb430_three, 320
.set nb430_r, 336
.set nb430_isai, 352
.set nb430_isaprod, 368
.set nb430_dvdasum, 384
.set nb430_gbscale, 400
.set nb430_ii, 416
.set nb430_is3, 420
.set nb430_ii3, 424
.set nb430_ntia, 428
.set nb430_innerjjnr, 432
.set nb430_innerk, 436
.set nb430_n, 440
.set nb430_nn1, 444
.set nb430_nri, 448
.set nb430_facel, 456                         ## uses 8 bytes
.set nb430_ntype, 464
.set nb430_nouter, 468
.set nb430_ninner, 472
.set nb430_salign, 476
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $484,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb430_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb430_p_nri(%ebp),%ecx
        movl nb430_p_facel(%ebp),%esi
        movl nb430_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movsd (%esi),%xmm7
        movl (%edi),%edi
        movl %ecx,nb430_nri(%esp)
        movsd %xmm7,nb430_facel(%esp)
        movl %edi,nb430_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb430_nouter(%esp)
        movl %eax,nb430_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb430_half(%esp)
        movl %ebx,nb430_half+4(%esp)
        movsd nb430_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb430_half(%esp)
        movapd %xmm2,nb430_two(%esp)
        movapd %xmm3,nb430_three(%esp)
        movl nb430_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        movl nb430_p_gbtabscale(%ebp),%eax
        movsd (%eax),%xmm4
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb430_tsc(%esp)
        movapd %xmm4,nb430_gbtsc(%esp)

_nb_kernel430_ia32_sse2.nb430_threadloop: 
        movl  nb430_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel430_ia32_sse2.nb430_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel430_ia32_sse2.nb430_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb430_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb430_n(%esp)
        movl %ebx,nb430_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel430_ia32_sse2.nb430_outerstart
        jmp _nb_kernel430_ia32_sse2.nb430_end

_nb_kernel430_ia32_sse2.nb430_outerstart: 
        ## ebx contains number of outer iterations
        addl nb430_nouter(%esp),%ebx
        movl %ebx,nb430_nouter(%esp)

_nb_kernel430_ia32_sse2.nb430_outer: 
        movl  nb430_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb430_is3(%esp)      ## store is3 

        movl  nb430_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb430_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 
        movl  %ebx,nb430_ii(%esp)

        movl  nb430_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        mulsd nb430_facel(%esp),%xmm3
        shufpd $0,%xmm3,%xmm3

        movl  nb430_invsqrta(%ebp),%edx         ## load invsqrta[ii]
        movsd (%edx,%ebx,8),%xmm4
        shufpd $0,%xmm4,%xmm4

        movl  nb430_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb430_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb430_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb430_pos(%ebp),%eax      ## eax = base of pos[]  

        addsd (%eax,%ebx,8),%xmm0
        addsd 8(%eax,%ebx,8),%xmm1
        addsd 16(%eax,%ebx,8),%xmm2

        movapd %xmm3,nb430_iq(%esp)
        movapd %xmm4,nb430_isai(%esp)

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2

        movapd %xmm0,nb430_ix(%esp)
        movapd %xmm1,nb430_iy(%esp)
        movapd %xmm2,nb430_iz(%esp)

        movl  %ebx,nb430_ii3(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb430_vctot(%esp)
        movapd %xmm4,nb430_Vvdwtot(%esp)
        movapd %xmm4,nb430_dvdasum(%esp)
        movapd %xmm4,nb430_fix(%esp)
        movapd %xmm4,nb430_fiy(%esp)
        movapd %xmm4,nb430_fiz(%esp)

        movl  nb430_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb430_pos(%ebp),%esi
        movl  nb430_faction(%ebp),%edi
        movl  nb430_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb430_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb430_ninner(%esp),%ecx
        movl  %ecx,nb430_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb430_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel430_ia32_sse2.nb430_unroll_loop
        jmp   _nb_kernel430_ia32_sse2.nb430_checksingle
_nb_kernel430_ia32_sse2.nb430_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb430_innerjjnr(%esp),%edx     ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        addl $8,nb430_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 

        ## load isaj
        movl nb430_invsqrta(%ebp),%esi
        movlpd (%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm2
        mulpd  nb430_isai(%esp),%xmm2
        movapd %xmm2,nb430_isaprod(%esp)
        movapd %xmm2,%xmm1
        mulpd nb430_gbtsc(%esp),%xmm1
        movapd %xmm1,nb430_gbscale(%esp)

        movl nb430_charge(%ebp),%esi     ## base of charge[] 
        movlpd (%esi,%eax,8),%xmm3
        movhpd (%esi,%ebx,8),%xmm3

        mulpd nb430_iq(%esp),%xmm2
        mulpd  %xmm2,%xmm3
        movapd %xmm3,nb430_qq(%esp)

        movl nb430_type(%ebp),%esi
        movl (%esi,%eax,4),%ecx
        movl (%esi,%ebx,4),%edx
        movl nb430_vdwparam(%ebp),%esi
        shll %ecx
        shll %edx
        movl nb430_ntia(%esp),%edi
        addl %edi,%ecx
        addl %edi,%edx

        movlpd (%esi,%ecx,8),%xmm6      ## c6a
        movlpd (%esi,%edx,8),%xmm7      ## c6b
        movhpd 8(%esi,%ecx,8),%xmm6     ## c6a c12a 
        movhpd 8(%esi,%edx,8),%xmm7     ## c6b c12b 

        movapd %xmm6,%xmm4
        unpcklpd %xmm7,%xmm4
        unpckhpd %xmm7,%xmm6

        movapd %xmm4,nb430_c6(%esp)
        movapd %xmm6,nb430_c12(%esp)

        movl nb430_pos(%ebp),%esi               ## base of pos[] 

        movd  %eax,%mm2
        movd  %ebx,%mm3
        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move two coordinates to xmm0-xmm2 
        movlpd (%esi,%eax,8),%xmm0
        movlpd 8(%esi,%eax,8),%xmm1
        movlpd 16(%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm0
        movhpd 8(%esi,%ebx,8),%xmm1
        movhpd 16(%esi,%ebx,8),%xmm2

        movl   nb430_faction(%ebp),%edi

        ## move nb430_ix-iz to xmm4-xmm6 
        movapd nb430_ix(%esp),%xmm4
        movapd nb430_iy(%esp),%xmm5
        movapd nb430_iz(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb430_dx(%esp)
        movapd %xmm5,nb430_dy(%esp)
        movapd %xmm6,nb430_dz(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        ## rsq in xmm4 

        cvtpd2ps %xmm4,%xmm5
        rsqrtps %xmm5,%xmm5
        cvtps2pd %xmm5,%xmm2    ## lu in low xmm2 

        ## lookup seed in xmm2 
        movapd %xmm2,%xmm5      ## copy of lu 
        mulpd %xmm2,%xmm2       ## lu*lu 
        movapd nb430_three(%esp),%xmm1
        mulpd %xmm4,%xmm2       ## rsq*lu*lu                    
        movapd nb430_half(%esp),%xmm0
        subpd %xmm2,%xmm1       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm1
        mulpd %xmm0,%xmm1       ## xmm0=iter1 of rinv (new lu) 

        movapd %xmm1,%xmm5      ## copy of lu 
        mulpd %xmm1,%xmm1       ## lu*lu 
        movapd nb430_three(%esp),%xmm2
        mulpd %xmm4,%xmm1       ## rsq*lu*lu                    
        movapd nb430_half(%esp),%xmm0
        subpd %xmm1,%xmm2       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm2
        mulpd %xmm2,%xmm0       ## xmm0=iter2 of rinv 
        mulpd %xmm0,%xmm4       ## xmm4=r 
        movapd %xmm4,nb430_r(%esp)
        mulpd nb430_gbscale(%esp),%xmm4

        cvttpd2pi %xmm4,%mm6    ## mm6 = lu idx 
        cvtpi2pd %mm6,%xmm5
        subpd %xmm5,%xmm4
        movapd %xmm4,%xmm1      ## xmm1=eps 
        movapd %xmm1,%xmm2
        mulpd  %xmm2,%xmm2      ## xmm2=eps2 

        pslld $2,%mm6           ## idx *= 4 

        movl nb430_GBtab(%ebp),%esi
        movd %mm6,%ecx
        psrlq $32,%mm6
        movd %mm6,%edx          ## indices in eax/ebx 

        ## Coulomb 
        movapd (%esi,%ecx,8),%xmm4      ## Y1 F1        
        movapd (%esi,%edx,8),%xmm3      ## Y2 F2 
        movapd %xmm4,%xmm5
        unpcklpd %xmm3,%xmm4    ## Y1 Y2 
        unpckhpd %xmm3,%xmm5    ## F1 F2 

        movapd 16(%esi,%ecx,8),%xmm6    ## G1 H1        
        movapd 16(%esi,%edx,8),%xmm3    ## G2 H2 
        movapd %xmm6,%xmm7
        unpcklpd %xmm3,%xmm6    ## G1 G2 
        unpckhpd %xmm3,%xmm7    ## H1 H2 
        ## coulomb table ready, in xmm4-xmm7            
        mulpd  %xmm1,%xmm6      ## xmm6=Geps 
        mulpd  %xmm2,%xmm7      ## xmm7=Heps2 
        addpd  %xmm6,%xmm5
        addpd  %xmm7,%xmm5      ## xmm5=Fp      
        mulpd  nb430_two(%esp),%xmm7    ## two*Heps2 
        movapd nb430_qq(%esp),%xmm3
        addpd  %xmm6,%xmm7
        addpd  %xmm5,%xmm7 ## xmm7=FF 
        mulpd  %xmm1,%xmm5 ## xmm5=eps*Fp 
        addpd  %xmm4,%xmm5 ## xmm5=VV 
        mulpd  %xmm3,%xmm5 ## vcoul=qq*VV  
        mulpd  %xmm7,%xmm3 ## fijC=FF*qq 
        ## get jnr from regs
        movd %mm2,%ecx
        movd %mm3,%edx
        movl nb430_dvda(%ebp),%esi

        ## Calculate dVda
        xorpd %xmm7,%xmm7