nb_kernel211_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,010 行 · 第 1/4 页

	mulsd  xmm4, xmm7		;# total fsH2 in xmm4 
	
	addsd  xmm5, [esp + nb211_vctot]

	movapd xmm0, [esp + nb211_dxH2]
	movapd xmm1, [esp + nb211_dyH2]
	movapd xmm2, [esp + nb211_dzH2]
	movlpd [esp + nb211_vctot], xmm5
	mulsd  xmm0, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm2, xmm4

	;# update H2 forces 
	movapd xmm3, [esp + nb211_fixH2]
	movapd xmm4, [esp + nb211_fiyH2]
	movapd xmm7, [esp + nb211_fizH2]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm7, xmm2
	movlpd [esp + nb211_fixH2], xmm3
	movlpd [esp + nb211_fiyH2], xmm4
	movlpd [esp + nb211_fizH2], xmm7

	mov edi, [ebp + nb211_faction]
	;# update j forces 
	addsd  xmm0, [esp + nb211_fjx]
	addsd  xmm1, [esp + nb211_fjy]
	addsd  xmm2, [esp + nb211_fjz]
	movlpd xmm3, [edi + eax*8]
	movlpd xmm4, [edi + eax*8 + 8]
	movlpd xmm5, [edi + eax*8 + 16]
	subsd xmm3, xmm0
	subsd xmm4, xmm1
	subsd xmm5, xmm2
	movlpd [edi + eax*8], xmm3
	movlpd [edi + eax*8 + 8], xmm4
	movlpd [edi + eax*8 + 16], xmm5	

.nb211_updateouterdata:
	mov   ecx, [esp + nb211_ii3]
	mov   edi, [ebp + nb211_faction]
	mov   esi, [ebp + nb211_fshift]
	mov   edx, [esp + nb211_is3]

	;# accumulate  Oi forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb211_fixO]
	movapd xmm1, [esp + nb211_fiyO]
	movapd xmm2, [esp + nb211_fizO]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	movapd xmm3, xmm0	
	movapd xmm4, xmm1	
	movapd xmm5, xmm2	

	;# increment i force 
	movsd  xmm3, [edi + ecx*8]
	movsd  xmm4, [edi + ecx*8 + 8]
	movsd  xmm5, [edi + ecx*8 + 16]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8],     xmm3
	movsd  [edi + ecx*8 + 8], xmm4
	movsd  [edi + ecx*8 + 16], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	movapd xmm6, xmm0
	movsd xmm7, xmm2
	unpcklpd xmm6, xmm1

	;# accumulate H1i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb211_fixH1]
	movapd xmm1, [esp + nb211_fiyH1]
	movapd xmm2, [esp + nb211_fizH1]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 24]
	movsd  xmm4, [edi + ecx*8 + 32]
	movsd  xmm5, [edi + ecx*8 + 40]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 24], xmm3
	movsd  [edi + ecx*8 + 32], xmm4
	movsd  [edi + ecx*8 + 40], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# accumulate H2i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb211_fixH2]
	movapd xmm1, [esp + nb211_fiyH2]
	movapd xmm2, [esp + nb211_fizH2]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	movapd xmm3, xmm0	
	movapd xmm4, xmm1	
	movapd xmm5, xmm2	

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 48]
	movsd  xmm4, [edi + ecx*8 + 56]
	movsd  xmm5, [edi + ecx*8 + 64]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 48], xmm3
	movsd  [edi + ecx*8 + 56], xmm4
	movsd  [edi + ecx*8 + 64], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# increment fshift force 
	movlpd xmm3, [esi + edx*8]
	movhpd xmm3, [esi + edx*8 + 8]
	movsd  xmm4, [esi + edx*8 + 16]
	addpd  xmm3, xmm6
	addsd  xmm4, xmm7
	movlpd [esi + edx*8],      xmm3
	movhpd [esi + edx*8 + 8],  xmm3
	movsd  [esi + edx*8 + 16], xmm4

	;# get n from stack
	mov esi, [esp + nb211_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb211_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [esp + nb211_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb211_Vc]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
	;# accumulate total lj energy and update it 
	movapd xmm7, [esp + nb211_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 
	
	;# add earlier value from mem 
	mov   eax, [ebp + nb211_Vvdw]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
       ;# finish if last 
        mov ecx, [esp + nb211_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb211_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb211_n], esi
        jmp .nb211_outer
.nb211_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb211_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb211_end
        ;# non-zero, do one more workunit
        jmp   .nb211_threadloop
.nb211_end:
	emms

	mov eax, [esp + nb211_nouter]
	mov ebx, [esp + nb211_ninner]
	mov ecx, [ebp + nb211_outeriter]
	mov edx, [ebp + nb211_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb211_salign]
	add esp, eax
	add esp, 812
	pop edi
	pop esi
    pop edx
    pop ecx
    pop ebx
    pop eax
	leave
	ret




.globl nb_kernel211nf_ia32_sse2
.globl _nb_kernel211nf_ia32_sse2
nb_kernel211nf_ia32_sse2:	
_nb_kernel211nf_ia32_sse2:	
.equiv          nb211nf_p_nri,          8
.equiv          nb211nf_iinr,           12
.equiv          nb211nf_jindex,         16
.equiv          nb211nf_jjnr,           20
.equiv          nb211nf_shift,          24
.equiv          nb211nf_shiftvec,       28
.equiv          nb211nf_fshift,         32
.equiv          nb211nf_gid,            36
.equiv          nb211nf_pos,            40
.equiv          nb211nf_faction,        44
.equiv          nb211nf_charge,         48
.equiv          nb211nf_p_facel,        52
.equiv          nb211nf_argkrf,         56
.equiv          nb211nf_argcrf,         60
.equiv          nb211nf_Vc,             64
.equiv          nb211nf_type,           68
.equiv          nb211nf_p_ntype,        72
.equiv          nb211nf_vdwparam,       76
.equiv          nb211nf_Vvdw,           80
.equiv          nb211nf_p_tabscale,     84
.equiv          nb211nf_VFtab,          88
.equiv          nb211nf_invsqrta,       92
.equiv          nb211nf_dvda,           96
.equiv          nb211nf_p_gbtabscale,   100
.equiv          nb211nf_GBtab,          104
.equiv          nb211nf_p_nthreads,     108
.equiv          nb211nf_count,          112
.equiv          nb211nf_mtx,            116
.equiv          nb211nf_outeriter,      120
.equiv          nb211nf_inneriter,      124
.equiv          nb211nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb211nf_ixO,            0
.equiv          nb211nf_iyO,            16
.equiv          nb211nf_izO,            32
.equiv          nb211nf_ixH1,           48
.equiv          nb211nf_iyH1,           64
.equiv          nb211nf_izH1,           80
.equiv          nb211nf_ixH2,           96
.equiv          nb211nf_iyH2,           112
.equiv          nb211nf_izH2,           128
.equiv          nb211nf_iqO,            144
.equiv          nb211nf_iqH,            160
.equiv          nb211nf_qqO,            176
.equiv          nb211nf_qqH,            192
.equiv          nb211nf_c6,             208
.equiv          nb211nf_c12,            224
.equiv          nb211nf_vctot,          240
.equiv          nb211nf_Vvdwtot,        256
.equiv          nb211nf_half,           272
.equiv          nb211nf_three,          288
.equiv          nb211nf_krf,            304
.equiv          nb211nf_crf,            320
.equiv          nb211nf_krsqO,          336
.equiv          nb211nf_krsqH1,         352
.equiv          nb211nf_krsqH2,         368
.equiv          nb211nf_is3,            384
.equiv          nb211nf_ii3,            388
.equiv          nb211nf_ntia,           392
.equiv          nb211nf_innerjjnr,      396
.equiv          nb211nf_innerk,         400
.equiv          nb211nf_n,              404
.equiv          nb211nf_nn1,            408
.equiv          nb211nf_nri,            412
.equiv          nb211nf_nouter,         416
.equiv          nb211nf_ninner,         420
.equiv          nb211nf_salign,         424
	push ebp
	mov ebp,esp	
    push eax
    push ebx
    push ecx
    push edx
	push esi
	push edi
	sub esp, 428		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb211nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb211nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb211nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb211nf_nouter], eax
	mov [esp + nb211nf_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb211nf_half], eax
	mov [esp + nb211nf_half+4], ebx
	movsd xmm1, [esp + nb211nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb211nf_half], xmm1
	movapd [esp + nb211nf_three], xmm3

	mov esi, [ebp + nb211nf_argkrf]
	mov edi, [ebp + nb211nf_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb211nf_krf], xmm5
	movapd [esp + nb211nf_crf], xmm6
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb211nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb211nf_charge]
	movsd xmm3, [edx + ebx*8]	
	movsd xmm4, [edx + ebx*8 + 8]	
	mov esi, [ebp + nb211nf_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb211nf_iqO], xmm3
	movapd [esp + nb211nf_iqH], xmm4
	
	mov   edx, [ebp + nb211nf_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb211nf_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb211nf_ntia], ecx		
.nb211nf_threadloop:
        mov   esi, [ebp + nb211nf_count]        ;# pointer to sync counter
        mov   eax, [esi]
.nb211nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           	;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb211nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb211nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb211nf_n], eax
        mov [esp + nb211nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb211nf_outerstart
        jmp .nb211nf_end

.nb211nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb211nf_nouter]
	mov [esp + nb211nf_nouter], ebx

.nb211nf_outer:
	mov   eax, [ebp + nb211nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb211nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb211nf_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb211nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb211nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb211nf_ii3], ebx

	addsd xmm3, [eax + ebx*8]
	addsd xmm4, [eax + ebx*8 + 8]
	addsd xmm5, [eax + ebx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb211nf_ixO], xmm3
	movapd [esp + nb211nf_iyO], xmm4
	movapd [esp + nb211nf_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 24]
	addsd xmm1, [eax + ebx*8 + 32]
	addsd xmm2, [eax + ebx*8 + 40]		
	addsd xmm3, [eax + ebx*8 + 48]
	addsd xmm4, [eax + ebx*8 + 56]
	addsd xmm5, [eax + ebx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb211nf_ixH1], xmm0
	movapd [esp + nb211nf_iyH1], xmm1
	movapd [esp + nb211nf_izH1], xmm2
	movapd [esp + nb211nf_ixH2], xmm3
	movapd [esp + nb211nf_iyH2], xmm4
	movapd [esp + nb211nf_izH2], xmm5
	
	;# clear vctot 
	xorpd xmm4, xmm4
	movapd [esp + nb211nf_vctot], xmm4
	movapd [esp + nb211nf_Vvdwtot], xmm4
	
	mov   eax, [ebp + nb211nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb211nf_pos]
	mov   eax, [ebp + nb211nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb211nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb211nf_ninner]
	mov   [esp + nb211nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb211nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb211nf_unroll_loop
	jmp   .nb211nf_checksingle
.nb211nf_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb211nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb211nf_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb211nf_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb211nf_iqO]
	mulpd  xmm4, [esp + nb211nf_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx

	movapd  [esp + nb211nf_qqO], xmm3
	movapd  [esp + nb211nf_qqH], xmm4
	
	mov esi, [ebp + nb211nf_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb211nf_vdwparam]