nb_kernel201_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,790 行 · 第 1/4 页

;#
;# $Id: nb_kernel201_ia32_sse2.intel_syntax.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



	

.globl nb_kernel201_ia32_sse2
.globl _nb_kernel201_ia32_sse2
nb_kernel201_ia32_sse2:	
_nb_kernel201_ia32_sse2:	
.equiv          nb201_p_nri,            8
.equiv          nb201_iinr,             12
.equiv          nb201_jindex,           16
.equiv          nb201_jjnr,             20
.equiv          nb201_shift,            24
.equiv          nb201_shiftvec,         28
.equiv          nb201_fshift,           32
.equiv          nb201_gid,              36
.equiv          nb201_pos,              40
.equiv          nb201_faction,          44
.equiv          nb201_charge,           48
.equiv          nb201_p_facel,          52
.equiv          nb201_argkrf,           56
.equiv          nb201_argcrf,           60
.equiv          nb201_Vc,               64
.equiv          nb201_type,             68
.equiv          nb201_p_ntype,          72
.equiv          nb201_vdwparam,         76
.equiv          nb201_Vvdw,             80
.equiv          nb201_p_tabscale,       84
.equiv          nb201_VFtab,            88
.equiv          nb201_invsqrta,         92
.equiv          nb201_dvda,             96
.equiv          nb201_p_gbtabscale,     100
.equiv          nb201_GBtab,            104
.equiv          nb201_p_nthreads,       108
.equiv          nb201_count,            112
.equiv          nb201_mtx,              116
.equiv          nb201_outeriter,        120
.equiv          nb201_inneriter,        124
.equiv          nb201_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb201_ixO,              0
.equiv          nb201_iyO,              16
.equiv          nb201_izO,              32
.equiv          nb201_ixH1,             48
.equiv          nb201_iyH1,             64
.equiv          nb201_izH1,             80
.equiv          nb201_ixH2,             96
.equiv          nb201_iyH2,             112
.equiv          nb201_izH2,             128
.equiv          nb201_iqO,              144
.equiv          nb201_iqH,              160
.equiv          nb201_dxO,              176
.equiv          nb201_dyO,              192
.equiv          nb201_dzO,              208
.equiv          nb201_dxH1,             224
.equiv          nb201_dyH1,             240
.equiv          nb201_dzH1,             256
.equiv          nb201_dxH2,             272
.equiv          nb201_dyH2,             288
.equiv          nb201_dzH2,             304
.equiv          nb201_qqO,              320
.equiv          nb201_qqH,              336
.equiv          nb201_vctot,            352
.equiv          nb201_fixO,             384
.equiv          nb201_fiyO,             400
.equiv          nb201_fizO,             416
.equiv          nb201_fixH1,            432
.equiv          nb201_fiyH1,            448
.equiv          nb201_fizH1,            464
.equiv          nb201_fixH2,            480
.equiv          nb201_fiyH2,            496
.equiv          nb201_fizH2,            512
.equiv          nb201_fjx,              528
.equiv          nb201_fjy,              544
.equiv          nb201_fjz,              560
.equiv          nb201_half,             576
.equiv          nb201_three,            592
.equiv          nb201_two,              608
.equiv          nb201_krf,              624
.equiv          nb201_crf,              640
.equiv          nb201_krsqO,            656
.equiv          nb201_krsqH1,           672
.equiv          nb201_krsqH2,           688
.equiv          nb201_is3,              704
.equiv          nb201_ii3,              708
.equiv          nb201_innerjjnr,        712
.equiv          nb201_innerk,           716
.equiv          nb201_n,                720
.equiv          nb201_nn1,              724
.equiv          nb201_nri,              728
.equiv          nb201_nouter,           732
.equiv          nb201_ninner,           736
.equiv          nb201_salign,           740
	push ebp
	mov ebp,esp	
    push eax
    push ebx
    push ecx
    push edx
	push esi
	push edi
	sub esp, 744		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb201_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb201_p_nri]
	mov ecx, [ecx]
	mov [esp + nb201_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb201_nouter], eax
	mov [esp + nb201_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb201_half], eax
	mov [esp + nb201_half+4], ebx
	movsd xmm1, [esp + nb201_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb201_half], xmm1
	movapd [esp + nb201_two], xmm2
	movapd [esp + nb201_three], xmm3

	mov esi, [ebp + nb201_argkrf]
	mov edi, [ebp + nb201_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb201_krf], xmm5
	movapd [esp + nb201_crf], xmm6
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb201_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb201_charge]
	movsd xmm3, [edx + ebx*8]	
	movsd xmm4, [edx + ebx*8 + 8]	
	mov esi, [ebp + nb201_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb201_iqO], xmm3
	movapd [esp + nb201_iqH], xmm4
			
.nb201_threadloop:
        mov   esi, [ebp + nb201_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb201_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb201_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb201_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb201_n], eax
        mov [esp + nb201_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb201_outerstart
        jmp .nb201_end

.nb201_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb201_nouter]
	mov [esp + nb201_nouter], ebx

.nb201_outer:
	mov   eax, [ebp + nb201_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb201_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb201_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb201_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb201_pos]    ;# eax = base of pos[]  
	mov   [esp + nb201_ii3], ebx

	addsd xmm3, [eax + ebx*8]
	addsd xmm4, [eax + ebx*8 + 8]
	addsd xmm5, [eax + ebx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb201_ixO], xmm3
	movapd [esp + nb201_iyO], xmm4
	movapd [esp + nb201_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 24]
	addsd xmm1, [eax + ebx*8 + 32]
	addsd xmm2, [eax + ebx*8 + 40]		
	addsd xmm3, [eax + ebx*8 + 48]
	addsd xmm4, [eax + ebx*8 + 56]
	addsd xmm5, [eax + ebx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb201_ixH1], xmm0
	movapd [esp + nb201_iyH1], xmm1
	movapd [esp + nb201_izH1], xmm2
	movapd [esp + nb201_ixH2], xmm3
	movapd [esp + nb201_iyH2], xmm4
	movapd [esp + nb201_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [esp + nb201_vctot], xmm4
	movapd [esp + nb201_fixO], xmm4
	movapd [esp + nb201_fiyO], xmm4
	movapd [esp + nb201_fizO], xmm4
	movapd [esp + nb201_fixH1], xmm4
	movapd [esp + nb201_fiyH1], xmm4
	movapd [esp + nb201_fizH1], xmm4
	movapd [esp + nb201_fixH2], xmm4
	movapd [esp + nb201_fiyH2], xmm4
	movapd [esp + nb201_fizH2], xmm4
	
	mov   eax, [ebp + nb201_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb201_pos]
	mov   edi, [ebp + nb201_faction]	
	mov   eax, [ebp + nb201_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb201_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb201_ninner]
	mov   [esp + nb201_ninner], ecx
	add   edx, 0
	mov   [esp + nb201_innerk], edx    ;# number of innerloop atoms 
	jge   .nb201_unroll_loop
	jmp   .nb201_checksingle
.nb201_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb201_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb201_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb201_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb201_iqO]
	mulpd  xmm4, [esp + nb201_iqH]
	movapd  [esp + nb201_qqO], xmm3
	movapd  [esp + nb201_qqH], xmm4	

	mov esi, [ebp + nb201_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]

	;# move ixO-izO to xmm4-xmm6 
	movapd xmm4, [esp + nb201_ixO]
	movapd xmm5, [esp + nb201_iyO]
	movapd xmm6, [esp + nb201_izO]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb201_dxO], xmm4
	movapd [esp + nb201_dyO], xmm5
	movapd [esp + nb201_dzO], xmm6

	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqO in xmm7 

	;# move ixH1-izH1 to xmm4-xmm6 
	movapd xmm4, [esp + nb201_ixH1]
	movapd xmm5, [esp + nb201_iyH1]
	movapd xmm6, [esp + nb201_izH1]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb201_dxH1], xmm4
	movapd [esp + nb201_dyH1], xmm5
	movapd [esp + nb201_dzH1], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm6, xmm5
	addpd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movapd xmm3, [esp + nb201_ixH2]
	movapd xmm4, [esp + nb201_iyH2]
	movapd xmm5, [esp + nb201_izH2]

	;# calc dr 
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2

	;# store dr 
	movapd [esp + nb201_dxH2], xmm3
	movapd [esp + nb201_dyH2], xmm4
	movapd [esp + nb201_dzH2], xmm5
	;# square it 
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	addpd xmm5, xmm4
	addpd xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

	movapd xmm0, xmm5
	movapd xmm1, xmm6
	movapd xmm2, xmm7

	mulpd  xmm0, [esp + nb201_krf]	
	mulpd  xmm1, [esp + nb201_krf]	
	mulpd  xmm2, [esp + nb201_krf]	

	movapd [esp + nb201_krsqH2], xmm0
	movapd [esp + nb201_krsqH1], xmm1
	movapd [esp + nb201_krsqO], xmm2
	
	;# start with rsqO - put seed in xmm2 
	cvtpd2ps xmm2, xmm7	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb201_three]