nb_kernel303_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,026 行 · 第 1/5 页

##
## $Id: nb_kernel303_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel303_ia32_sse2
.globl _nb_kernel303_ia32_sse2
nb_kernel303_ia32_sse2: 
_nb_kernel303_ia32_sse2:        
.set nb303_p_nri, 8
.set nb303_iinr, 12
.set nb303_jindex, 16
.set nb303_jjnr, 20
.set nb303_shift, 24
.set nb303_shiftvec, 28
.set nb303_fshift, 32
.set nb303_gid, 36
.set nb303_pos, 40
.set nb303_faction, 44
.set nb303_charge, 48
.set nb303_p_facel, 52
.set nb303_argkrf, 56
.set nb303_argcrf, 60
.set nb303_Vc, 64
.set nb303_type, 68
.set nb303_p_ntype, 72
.set nb303_vdwparam, 76
.set nb303_Vvdw, 80
.set nb303_p_tabscale, 84
.set nb303_VFtab, 88
.set nb303_invsqrta, 92
.set nb303_dvda, 96
.set nb303_p_gbtabscale, 100
.set nb303_GBtab, 104
.set nb303_p_nthreads, 108
.set nb303_count, 112
.set nb303_mtx, 116
.set nb303_outeriter, 120
.set nb303_inneriter, 124
.set nb303_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb303_ixM, 0
.set nb303_iyM, 16
.set nb303_izM, 32
.set nb303_ixH1, 48
.set nb303_iyH1, 64
.set nb303_izH1, 80
.set nb303_ixH2, 96
.set nb303_iyH2, 112
.set nb303_izH2, 128
.set nb303_iqM, 144
.set nb303_iqH, 160
.set nb303_dxM, 176
.set nb303_dyM, 192
.set nb303_dzM, 208
.set nb303_dxH1, 224
.set nb303_dyH1, 240
.set nb303_dzH1, 256
.set nb303_dxH2, 272
.set nb303_dyH2, 288
.set nb303_dzH2, 304
.set nb303_qqM, 320
.set nb303_qqH, 336
.set nb303_rinvM, 352
.set nb303_rinvH1, 368
.set nb303_rinvH2, 384
.set nb303_rM, 400
.set nb303_rH1, 416
.set nb303_rH2, 432
.set nb303_tsc, 448
.set nb303_two, 464
.set nb303_vctot, 480
.set nb303_fixM, 496
.set nb303_fiyM, 512
.set nb303_fizM, 528
.set nb303_fixH1, 544
.set nb303_fiyH1, 560
.set nb303_fizH1, 576
.set nb303_fixH2, 592
.set nb303_fiyH2, 608
.set nb303_fizH2, 624
.set nb303_fjx, 640
.set nb303_fjy, 656
.set nb303_fjz, 672
.set nb303_half, 688
.set nb303_three, 704
.set nb303_is3, 720
.set nb303_ii3, 724
.set nb303_innerjjnr, 728
.set nb303_innerk, 732
.set nb303_n, 736
.set nb303_nn1, 740
.set nb303_nri, 744
.set nb303_nouter, 748
.set nb303_ninner, 752
.set nb303_salign, 756
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $760,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb303_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb303_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb303_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb303_nouter(%esp)
        movl %eax,nb303_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb303_half(%esp)
        movl %ebx,nb303_half+4(%esp)
        movsd nb303_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb303_half(%esp)
        movapd %xmm2,nb303_two(%esp)
        movapd %xmm3,nb303_three(%esp)

        movl nb303_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb303_tsc(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb303_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb303_charge(%ebp),%edx
        movsd 8(%edx,%ebx,8),%xmm3
        movsd 24(%edx,%ebx,8),%xmm4
        movl nb303_p_facel(%ebp),%esi
        movsd (%esi),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb303_iqH(%esp)
        movapd %xmm4,nb303_iqM(%esp)

_nb_kernel303_ia32_sse2.nb303_threadloop: 
        movl  nb303_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel303_ia32_sse2.nb303_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel303_ia32_sse2.nb303_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb303_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb303_n(%esp)
        movl %ebx,nb303_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel303_ia32_sse2.nb303_outerstart
        jmp _nb_kernel303_ia32_sse2.nb303_end

_nb_kernel303_ia32_sse2.nb303_outerstart: 
        ## ebx contains number of outer iterations
        addl nb303_nouter(%esp),%ebx
        movl %ebx,nb303_nouter(%esp)

_nb_kernel303_ia32_sse2.nb303_outer: 
        movl  nb303_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb303_is3(%esp)      ## store is3 

        movl  nb303_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb303_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb303_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb303_ii3(%esp)

        addsd 24(%eax,%ebx,8),%xmm3
        addsd 32(%eax,%ebx,8),%xmm4
        addsd 40(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb303_ixH1(%esp)
        movapd %xmm4,nb303_iyH1(%esp)
        movapd %xmm5,nb303_izH1(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 48(%eax,%ebx,8),%xmm0
        addsd 56(%eax,%ebx,8),%xmm1
        addsd 64(%eax,%ebx,8),%xmm2
        addsd 72(%eax,%ebx,8),%xmm3
        addsd 80(%eax,%ebx,8),%xmm4
        addsd 88(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb303_ixH2(%esp)
        movapd %xmm1,nb303_iyH2(%esp)
        movapd %xmm2,nb303_izH2(%esp)
        movapd %xmm3,nb303_ixM(%esp)
        movapd %xmm4,nb303_iyM(%esp)
        movapd %xmm5,nb303_izM(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb303_vctot(%esp)
        movapd %xmm4,nb303_fixM(%esp)
        movapd %xmm4,nb303_fiyM(%esp)
        movapd %xmm4,nb303_fizM(%esp)
        movapd %xmm4,nb303_fixH1(%esp)
        movapd %xmm4,nb303_fiyH1(%esp)
        movapd %xmm4,nb303_fizH1(%esp)
        movapd %xmm4,nb303_fixH2(%esp)
        movapd %xmm4,nb303_fiyH2(%esp)
        movapd %xmm4,nb303_fizH2(%esp)

        movl  nb303_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb303_pos(%ebp),%esi
        movl  nb303_faction(%ebp),%edi
        movl  nb303_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb303_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb303_ninner(%esp),%ecx
        movl  %ecx,nb303_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb303_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel303_ia32_sse2.nb303_unroll_loop
        jmp   _nb_kernel303_ia32_sse2.nb303_checksingle
_nb_kernel303_ia32_sse2.nb303_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb303_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb303_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 
        movl nb303_charge(%ebp),%esi     ## base of charge[] 

        movlpd (%esi,%eax,8),%xmm3
        movhpd (%esi,%ebx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb303_iqM(%esp),%xmm3
        mulpd  nb303_iqH(%esp),%xmm4

        movapd  %xmm3,nb303_qqM(%esp)
        movapd  %xmm4,nb303_qqH(%esp)

        movl nb303_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move two coordinates to xmm0-xmm2    
        movlpd (%esi,%eax,8),%xmm0
        movlpd 8(%esi,%eax,8),%xmm1
        movlpd 16(%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm0
        movhpd 8(%esi,%ebx,8),%xmm1
        movhpd 16(%esi,%ebx,8),%xmm2

        ## move ixM-izM to xmm4-xmm6 
        movapd nb303_ixM(%esp),%xmm4
        movapd nb303_iyM(%esp),%xmm5
        movapd nb303_izM(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb303_dxM(%esp)
        movapd %xmm5,nb303_dyM(%esp)
        movapd %xmm6,nb303_dzM(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        movapd %xmm4,%xmm7
        ## rsqM in xmm7 

        ## move ixH1-izH1 to xmm4-xmm6 
        movapd nb303_ixH1(%esp),%xmm4
        movapd nb303_iyH1(%esp),%xmm5
        movapd nb303_izH1(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb303_dxH1(%esp)
        movapd %xmm5,nb303_dyH1(%esp)
        movapd %xmm6,nb303_dzH1(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm6
        addpd %xmm4,%xmm6
        ## rsqH1 in xmm6 

        ## move ixH2-izH2 to xmm3-xmm5  
        movapd nb303_ixH2(%esp),%xmm3
        movapd nb303_iyH2(%esp),%xmm4
        movapd nb303_izH2(%esp),%xmm5

        ## calc dr 
        subpd %xmm0,%xmm3
        subpd %xmm1,%xmm4
        subpd %xmm2,%xmm5

        ## store dr 
        movapd %xmm3,nb303_dxH2(%esp)
        movapd %xmm4,nb303_dyH2(%esp)
        movapd %xmm5,nb303_dzH2(%esp)
        ## square it 
        mulpd %xmm3,%xmm3
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        addpd %xmm4,%xmm5
        addpd %xmm3,%xmm5
        ## rsqH2 in xmm5, rsqH1 in xmm6, rsqM in xmm7 

        ## start with rsqM - put seed in xmm2 
        cvtpd2ps %xmm7,%xmm2
        rsqrtps %xmm2,%xmm2
        cvtps2pd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulpd   %xmm2,%xmm2
        movapd  nb303_three(%esp),%xmm4
        mulpd   %xmm7,%xmm2     ## rsq*lu*lu 
        subpd   %xmm2,%xmm4     ## 30-rsq*lu*lu 
        mulpd   %xmm3,%xmm4     ## lu*(3-rsq*lu*lu)