nb_kernel133_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,398 行 · 第 1/5 页

	movsd [eax + edx*8], xmm7 
	
	;# accumulate total lj energy and update it 
	movapd xmm7, [esp + nb133_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb133_Vvdw]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
       ;# finish if last 
        mov ecx, [esp + nb133_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb133_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb133_n], esi
        jmp .nb133_outer
.nb133_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb133_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb133_end
        ;# non-zero, do one more workunit
        jmp   .nb133_threadloop
.nb133_end:
	emms

	mov eax, [esp + nb133_nouter]
	mov ebx, [esp + nb133_ninner]
	mov ecx, [ebp + nb133_outeriter]
	mov edx, [ebp + nb133_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb133_salign]
	add esp, eax
	add esp, 1020
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret




.globl nb_kernel133nf_ia32_sse2
.globl _nb_kernel133nf_ia32_sse2
nb_kernel133nf_ia32_sse2:	
_nb_kernel133nf_ia32_sse2:	
.equiv          nb133nf_p_nri,            8
.equiv          nb133nf_iinr,             12
.equiv          nb133nf_jindex,           16
.equiv          nb133nf_jjnr,             20
.equiv          nb133nf_shift,            24
.equiv          nb133nf_shiftvec,         28
.equiv          nb133nf_fshift,           32
.equiv          nb133nf_gid,              36
.equiv          nb133nf_pos,              40
.equiv          nb133nf_faction,          44
.equiv          nb133nf_charge,           48
.equiv          nb133nf_p_facel,          52
.equiv          nb133nf_argkrf,           56
.equiv          nb133nf_argcrf,           60
.equiv          nb133nf_Vc,               64
.equiv          nb133nf_type,             68
.equiv          nb133nf_p_ntype,          72
.equiv          nb133nf_vdwparam,         76
.equiv          nb133nf_Vvdw,             80
.equiv          nb133nf_p_tabscale,       84
.equiv          nb133nf_VFtab,            88
.equiv          nb133nf_invsqrta,         92
.equiv          nb133nf_dvda,             96
.equiv          nb133nf_p_gbtabscale,     100
.equiv          nb133nf_GBtab,            104
.equiv          nb133nf_p_nthreads,       108
.equiv          nb133nf_count,            112
.equiv          nb133nf_mtx,              116
.equiv          nb133nf_outeriter,        120
.equiv          nb133nf_inneriter,        124
.equiv          nb133nf_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb133nf_ixO,              0
.equiv          nb133nf_iyO,              16
.equiv          nb133nf_izO,              32
.equiv          nb133nf_ixH1,             48
.equiv          nb133nf_iyH1,             64
.equiv          nb133nf_izH1,             80
.equiv          nb133nf_ixH2,             96
.equiv          nb133nf_iyH2,             112
.equiv          nb133nf_izH2,             128
.equiv          nb133nf_ixM,              144
.equiv          nb133nf_iyM,              160
.equiv          nb133nf_izM,              176
.equiv          nb133nf_iqH,              192
.equiv          nb133nf_iqM,              208
.equiv          nb133nf_qqH,              224
.equiv          nb133nf_qqM,              240
.equiv          nb133nf_c6,               256
.equiv          nb133nf_c12,              272
.equiv          nb133nf_tsc,              288
.equiv          nb133nf_vctot,            304
.equiv          nb133nf_Vvdwtot,          320
.equiv          nb133nf_half,             336
.equiv          nb133nf_three,            352
.equiv          nb133nf_two,              368
.equiv          nb133nf_rinvH1,           384
.equiv          nb133nf_rinvH2,           400
.equiv          nb133nf_rinvM,            416
.equiv          nb133nf_krsqH1,           432
.equiv          nb133nf_krsqH2,           448
.equiv          nb133nf_krsqM,            464
.equiv          nb133nf_rsqO,             512
.equiv          nb133nf_is3,              528
.equiv          nb133nf_ii3,              532
.equiv          nb133nf_ntia,             536
.equiv          nb133nf_innerjjnr,        540
.equiv          nb133nf_innerk,           544
.equiv          nb133nf_n,                548
.equiv          nb133nf_nn1,              552
.equiv          nb133nf_nri,              556
.equiv          nb133nf_nouter,           560
.equiv          nb133nf_ninner,           564
.equiv          nb133nf_salign,           568
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 572		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb133nf_salign], eax
	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb133nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb133nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb133nf_nouter], eax
	mov [esp + nb133nf_ninner], eax

	mov eax, [ebp + nb133nf_p_tabscale]
	movsd xmm3, [eax]
	shufpd xmm3, xmm3, 0
	movapd [esp + nb133nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb133nf_half], eax
	mov [esp + nb133nf_half+4], ebx
	movsd xmm1, [esp + nb133nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb133nf_half], xmm1
	movapd [esp + nb133nf_two], xmm2
	movapd [esp + nb133nf_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb133nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb133nf_charge]
	movsd xmm3, [edx + ebx*8 + 8]	
	movsd xmm4, [edx + ebx*8 + 24]	
	mov esi, [ebp + nb133nf_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb133nf_iqH], xmm3
	movapd [esp + nb133nf_iqM], xmm4
	
	mov   edx, [ebp + nb133nf_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb133nf_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb133nf_ntia], ecx		
.nb133nf_threadloop:
        mov   esi, [ebp + nb133nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb133nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb133nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb133nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb133nf_n], eax
        mov [esp + nb133nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb133nf_outerstart
        jmp .nb133nf_end

.nb133nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb133nf_nouter]
	mov [esp + nb133nf_nouter], ebx

.nb133nf_outer:
	mov   eax, [ebp + nb133nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb133nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb133nf_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb133nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	movapd xmm6, xmm0
	movapd xmm7, xmm1

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb133nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb133nf_ii3], ebx

	addsd xmm3, [eax + ebx*8] 	;# ox
	addsd xmm4, [eax + ebx*8 + 8] 	;# oy
	addsd xmm5, [eax + ebx*8 + 16]	;# oz	
	addsd xmm6, [eax + ebx*8 + 24] 	;# h1x
	addsd xmm7, [eax + ebx*8 + 32] 	;# h1y
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	shufpd xmm7, xmm7, 0
	movapd [esp + nb133nf_ixO], xmm3
	movapd [esp + nb133nf_iyO], xmm4
	movapd [esp + nb133nf_izO], xmm5
	movapd [esp + nb133nf_ixH1], xmm6
	movapd [esp + nb133nf_iyH1], xmm7

	movsd xmm6, xmm2
	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm6, [eax + ebx*8 + 40] ;# h1z
	addsd xmm0, [eax + ebx*8 + 48] ;# h2x
	addsd xmm1, [eax + ebx*8 + 56] ;# h2y
	addsd xmm2, [eax + ebx*8 + 64] ;# h2z
	addsd xmm3, [eax + ebx*8 + 72] ;# mx
	addsd xmm4, [eax + ebx*8 + 80] ;# my
	addsd xmm5, [eax + ebx*8 + 88] ;# mz

	shufpd xmm6, xmm6, 0
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb133nf_izH1], xmm6
	movapd [esp + nb133nf_ixH2], xmm0
	movapd [esp + nb133nf_iyH2], xmm1
	movapd [esp + nb133nf_izH2], xmm2
	movapd [esp + nb133nf_ixM], xmm3
	movapd [esp + nb133nf_iyM], xmm4
	movapd [esp + nb133nf_izM], xmm5

	;# clear vctot
	xorpd xmm4, xmm4
	movapd [esp + nb133nf_vctot], xmm4
	movapd [esp + nb133nf_Vvdwtot], xmm4
	
	mov   eax, [ebp + nb133nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb133nf_pos]
	mov   edi, [ebp + nb133nf_faction]	
	mov   eax, [ebp + nb133nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb133nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb133nf_ninner]
	mov   [esp + nb133nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb133nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb133nf_unroll_loop
	jmp   .nb133nf_checksingle
.nb133nf_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb133nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb133nf_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb133nf_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb133nf_iqM]
	mulpd  xmm4, [esp + nb133nf_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx

	movapd  [esp + nb133nf_qqM], xmm3
	movapd  [esp + nb133nf_qqH], xmm4
	
	mov esi, [ebp + nb133nf_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb133nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	mov edi, [esp + nb133nf_ntia]
	add eax, edi
	add ebx, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movlpd xmm7, [esi + ebx*8]	;# c6b
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	movhpd xmm7, [esi + ebx*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0
	movd  ebx, mm1
	movapd [esp + nb133nf_c6], xmm4
	movapd [esp + nb133nf_c12], xmm6
	
	mov esi, [ebp + nb133nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		

	;# move ixO-izO to xmm4-xmm6 
	movapd xmm4, [esp + nb133nf_ixO]
	movapd xmm5, [esp + nb133nf_iyO]
	movapd xmm6, [esp + nb133nf_izO]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqO in xmm7 

	;# move ixH1-izH1 to xmm4-xmm6 
	movapd xmm4, [esp + nb133nf_ixH1]
	movapd xmm5, [esp + nb133nf_iyH1]
	movapd xmm6, [esp + nb133nf_izH1]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm6, xmm5
	addpd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movapd xmm3, [esp + nb133nf_ixH2]
	movapd xmm4, [esp + nb133nf_iyH2]
	movapd xmm5, [esp + nb133nf_izH2]

	;# calc dr 
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2

	;# square it 
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	addpd xmm5, xmm4
	addpd xmm5, xmm3

	;# move ixM-izM to xmm2-xmm4  
	movapd xmm3, [esp + nb133nf_iyM]
	movapd xmm4, [esp + nb133nf_izM]
	subpd  xmm3, xmm1
	subpd  xmm4, xmm2
	movapd xmm2, [esp + nb133nf_ixM]
	subpd  xmm2, xmm0	

	;# square it 
	mulpd xmm2,xmm2
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	addpd xmm4, xmm3
	addpd xmm4, xmm2	
	;# rsqM in xmm4, rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 
	movapd [esp + nb133nf_rsqO], xmm7
	
	;# start with rsqH1 - put seed in xmm2 
	cvtpd2ps xmm2, xmm6	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2
	
	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm1, [esp + nb133nf_three]
	mulpd   xmm2, xmm6	;# rsq*lu*lu 
	subpd   xmm1, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm1, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm1, [esp + nb133nf_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm1
	mulpd xmm1, xmm1	;# lu*lu 
	mulpd xmm6, xmm1	;# rsq*lu*lu 
	movapd xmm1, [esp + nb133nf_three]
	subpd xmm1, xmm6	;# 3-rsq*lu*lu 
	mulpd xmm1, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm1, [esp + nb133nf_half] ;# rinv 
	movapd  [esp + nb133nf_rinvH1], xmm1