nb_kernel103_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,668 行 · 第 1/3 页

;#
;# $Id: nb_kernel103_ia32_sse2.intel_syntax.s,v 1.1.2.2 2007/11/28 18:35:33 spoel Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as


	
	

.globl nb_kernel103_ia32_sse2
.globl _nb_kernel103_ia32_sse2
nb_kernel103_ia32_sse2:	
_nb_kernel103_ia32_sse2:	
.equiv          nb103_p_nri,            8
.equiv          nb103_iinr,             12
.equiv          nb103_jindex,           16
.equiv          nb103_jjnr,             20
.equiv          nb103_shift,            24
.equiv          nb103_shiftvec,         28
.equiv          nb103_fshift,           32
.equiv          nb103_gid,              36
.equiv          nb103_pos,              40
.equiv          nb103_faction,          44
.equiv          nb103_charge,           48
.equiv          nb103_p_facel,          52
.equiv          nb103_argkrf,           56
.equiv          nb103_argcrf,           60
.equiv          nb103_Vc,               64
.equiv          nb103_type,             68
.equiv          nb103_p_ntype,          72
.equiv          nb103_vdwparam,         76
.equiv          nb103_Vvdw,             80
.equiv          nb103_p_tabscale,       84
.equiv          nb103_VFtab,            88
.equiv          nb103_invsqrta,         92
.equiv          nb103_dvda,             96
.equiv          nb103_p_gbtabscale,     100
.equiv          nb103_GBtab,            104
.equiv          nb103_p_nthreads,       108
.equiv          nb103_count,            112
.equiv          nb103_mtx,              116
.equiv          nb103_outeriter,        120
.equiv          nb103_inneriter,        124
.equiv          nb103_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb103_ixH1,             0
.equiv          nb103_iyH1,             16
.equiv          nb103_izH1,             32
.equiv          nb103_ixH2,             48
.equiv          nb103_iyH2,             64
.equiv          nb103_izH2,             80
.equiv          nb103_ixM,              96
.equiv          nb103_iyM,              112
.equiv          nb103_izM,              128
.equiv          nb103_iqM,              144
.equiv          nb103_iqH,              160
.equiv          nb103_dxH1,             176
.equiv          nb103_dyH1,             192
.equiv          nb103_dzH1,             208
.equiv          nb103_dxH2,             224
.equiv          nb103_dyH2,             240
.equiv          nb103_dzH2,             256
.equiv          nb103_dxM,              272
.equiv          nb103_dyM,              288
.equiv          nb103_dzM,              304
.equiv          nb103_qqM,              320
.equiv          nb103_qqH,              336
.equiv          nb103_vctot,            352
.equiv          nb103_fixM,             368
.equiv          nb103_fiyM,             384
.equiv          nb103_fizM,             400
.equiv          nb103_fixH1,            416
.equiv          nb103_fiyH1,            432
.equiv          nb103_fizH1,            448
.equiv          nb103_fixH2,            464
.equiv          nb103_fiyH2,            480
.equiv          nb103_fizH2,            496
.equiv          nb103_fjx,              512
.equiv          nb103_fjy,              528
.equiv          nb103_fjz,              544
.equiv          nb103_half,             560
.equiv          nb103_three,            576
.equiv          nb103_is3,              592
.equiv          nb103_ii3,              596
.equiv          nb103_innerjjnr,        600
.equiv          nb103_innerk,           604
.equiv          nb103_n,                608
.equiv          nb103_nn1,              612
.equiv          nb103_nri,              616
.equiv          nb103_nouter,           620
.equiv          nb103_ninner,           624
.equiv          nb103_salign,           628
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 632		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb103_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb103_p_nri]
	mov ecx, [ecx]
	mov [esp + nb103_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb103_nouter], eax
	mov [esp + nb103_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb103_half], eax
	mov [esp + nb103_half+4], ebx
	movsd xmm1, [esp + nb103_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb103_half], xmm1
	movapd [esp + nb103_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb103_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb103_charge]
	movsd xmm3, [edx + ebx*8 + 8]	
	movsd xmm4, [edx + ebx*8 + 24]	
	mov esi, [ebp + nb103_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb103_iqH], xmm3
	movapd [esp + nb103_iqM], xmm4
	
.nb103_threadloop:
        mov   esi, [ebp + nb103_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb103_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb103_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb103_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb103_n], eax
        mov [esp + nb103_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb103_outerstart
        jmp .nb103_end

.nb103_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb103_nouter]
	mov [esp + nb103_nouter], ebx

.nb103_outer:
	mov   eax, [ebp + nb103_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax + esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb103_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb103_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb103_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb103_pos]    ;# eax = base of pos[]  
	mov   [esp + nb103_ii3], ebx

	addsd xmm3, [eax + ebx*8 + 24]
	addsd xmm4, [eax + ebx*8 + 32]
	addsd xmm5, [eax + ebx*8 + 40]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb103_ixH1], xmm3
	movapd [esp + nb103_iyH1], xmm4
	movapd [esp + nb103_izH1], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 48]
	addsd xmm1, [eax + ebx*8 + 56]
	addsd xmm2, [eax + ebx*8 + 64]		
	addsd xmm3, [eax + ebx*8 + 72]
	addsd xmm4, [eax + ebx*8 + 80]
	addsd xmm5, [eax + ebx*8 + 88]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb103_ixH2], xmm0
	movapd [esp + nb103_iyH2], xmm1
	movapd [esp + nb103_izH2], xmm2
	movapd [esp + nb103_ixM], xmm3
	movapd [esp + nb103_iyM], xmm4
	movapd [esp + nb103_izM], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [esp + nb103_vctot], xmm4
	movapd [esp + nb103_fixM], xmm4
	movapd [esp + nb103_fiyM], xmm4
	movapd [esp + nb103_fizM], xmm4
	movapd [esp + nb103_fixH1], xmm4
	movapd [esp + nb103_fiyH1], xmm4
	movapd [esp + nb103_fizH1], xmm4
	movapd [esp + nb103_fixH2], xmm4
	movapd [esp + nb103_fiyH2], xmm4
	movapd [esp + nb103_fizH2], xmm4
	
	mov   eax, [ebp + nb103_jindex]
	mov   ecx, [eax+esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb103_pos]
	mov   edi, [ebp + nb103_faction]	
	mov   eax, [ebp + nb103_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb103_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb103_ninner]
	mov   [esp + nb103_ninner], ecx
	add   edx, 0
	mov   [esp + nb103_innerk], edx    ;# number of innerloop atoms 
	jge   .nb103_unroll_loop
	jmp   .nb103_checksingle
.nb103_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb103_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              

	add dword ptr [esp + nb103_innerjjnr],  8 ;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb103_charge]    ;# base of charge[] 
	
	
	movlpd xmm6, [esi + eax*8]	;# jq A 
	movhpd xmm6, [esi + ebx*8]	;# jq B 
	movapd xmm3, [esp + nb103_iqM]
	movapd xmm4, [esp + nb103_iqH]
	mulpd xmm3, xmm6		;# qqM 
	mulpd xmm4, xmm6		;# qqH 
	
	movapd  [esp + nb103_qqM], xmm3
	movapd  [esp + nb103_qqH], xmm4	

	mov esi, [ebp + nb103_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 	
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		

	;# move ixM-izM to xmm4-xmm6 
	movapd xmm4, [esp + nb103_ixM]
	movapd xmm5, [esp + nb103_iyM]
	movapd xmm6, [esp + nb103_izM]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb103_dxM], xmm4
	movapd [esp + nb103_dyM], xmm5
	movapd [esp + nb103_dzM], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqO in xmm7 

	;# move ixH1-izH1 to xmm4-xmm6 
	movapd xmm4, [esp + nb103_ixH1]
	movapd xmm5, [esp + nb103_iyH1]
	movapd xmm6, [esp + nb103_izH1]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb103_dxH1], xmm4
	movapd [esp + nb103_dyH1], xmm5
	movapd [esp + nb103_dzH1], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm6, xmm5
	addpd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movapd xmm3, [esp + nb103_ixH2]
	movapd xmm4, [esp + nb103_iyH2]
	movapd xmm5, [esp + nb103_izH2]

	;# calc dr 
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2

	;# store dr 
	movapd [esp + nb103_dxH2], xmm3
	movapd [esp + nb103_dyH2], xmm4
	movapd [esp + nb103_dzH2], xmm5
	;# square it 
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	addpd xmm5, xmm4
	addpd xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

	;# start with rsqM - put seed in xmm2 
	cvtpd2ps xmm2, xmm7	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb103_three]
	mulpd   xmm2, xmm7	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm7, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb103_three]
	subpd xmm4, xmm7	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb103_half] ;# rinv 
	movapd  xmm7, xmm4	;# rinvM in xmm7 
	
	;# rsqH1 - seed in xmm2 
	cvtpd2ps xmm2, xmm6	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb103_three]
	mulpd   xmm2, xmm6	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm6, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb103_three]
	subpd xmm4, xmm6	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb103_half] ;# rinv 
	movapd  xmm6, xmm4	;# rinvH1 in xmm6 
	
	;# rsqH2 - seed in xmm2 
	cvtpd2ps xmm2, xmm5	
	rsqrtps xmm2, xmm2
	cvtps2pd xmm2, xmm2

	movapd  xmm3, xmm2
	mulpd   xmm2, xmm2
	movapd  xmm4, [esp + nb103_three]
	mulpd   xmm2, xmm5	;# rsq*lu*lu 
	subpd   xmm4, xmm2	;# 30-rsq*lu*lu 
	mulpd   xmm4, xmm3	;# lu*(3-rsq*lu*lu) 
	mulpd   xmm4, [esp + nb103_half] ;# iter1 ( new lu) 

	movapd xmm3, xmm4
	mulpd xmm4, xmm4	;# lu*lu 
	mulpd xmm5, xmm4	;# rsq*lu*lu 
	movapd xmm4, [esp + nb103_three]
	subpd xmm4, xmm5	;# 3-rsq*lu*lu 
	mulpd xmm4, xmm3	;# lu*(	3-rsq*lu*lu) 
	mulpd xmm4, [esp + nb103_half] ;# rinv 
	movapd  xmm5, xmm4	;# rinvH2 in xmm5 

	;# do M interactions 
	movapd  xmm4, xmm7	
	mulpd   xmm4, xmm4	;# xmm7=rinv, xmm4=rinvsq 
	mulpd  xmm7, [esp + nb103_qqM]	;# xmm7=vcoul 
	
	mulpd  xmm4, xmm7	;# total fsO in xmm4 

	addpd  xmm7, [esp + nb103_vctot]
	
	movapd [esp + nb103_vctot], xmm7

	movapd xmm0, [esp + nb103_dxM]
	movapd xmm1, [esp + nb103_dyM]
	movapd xmm2, [esp + nb103_dzM]
	mulpd  xmm0, xmm4
	mulpd  xmm1, xmm4
	mulpd  xmm2, xmm4

	;# update M forces 
	movapd xmm3, [esp + nb103_fixM]
	movapd xmm4, [esp + nb103_fiyM]
	movapd xmm7, [esp + nb103_fizM]
	addpd  xmm3, xmm0
	addpd  xmm4, xmm1
	addpd  xmm7, xmm2
	movapd [esp + nb103_fixM], xmm3
	movapd [esp + nb103_fiyM], xmm4
	movapd [esp + nb103_fizM], xmm7
	;# update j forces with water M
	movapd [esp + nb103_fjx], xmm0
	movapd [esp + nb103_fjy], xmm1
	movapd [esp + nb103_fjz], xmm2

	;# H1 interactions 
	movapd  xmm4, xmm6	
	mulpd   xmm4, xmm4	;# xmm6=rinv, xmm4=rinvsq 
	mulpd  xmm6, [esp + nb103_qqH]	;# xmm6=vcoul 
	mulpd  xmm4, xmm6		;# total fsH1 in xmm4 
	
	addpd  xmm6, [esp + nb103_vctot]

	movapd xmm0, [esp + nb103_dxH1]
	movapd xmm1, [esp + nb103_dyH1]
	movapd xmm2, [esp + nb103_dzH1]
	movapd [esp + nb103_vctot], xmm6
	mulpd  xmm0, xmm4
	mulpd  xmm1, xmm4
	mulpd  xmm2, xmm4

	;# update H1 forces 
	movapd xmm3, [esp + nb103_fixH1]
	movapd xmm4, [esp + nb103_fiyH1]
	movapd xmm7, [esp + nb103_fizH1]
	addpd  xmm3, xmm0
	addpd  xmm4, xmm1
	addpd  xmm7, xmm2
	movapd [esp + nb103_fixH1], xmm3
	movapd [esp + nb103_fiyH1], xmm4
	movapd [esp + nb103_fizH1], xmm7
	;# update j forces with water H1 
	addpd  xmm0, [esp + nb103_fjx]
	addpd  xmm1, [esp + nb103_fjy]
	addpd  xmm2, [esp + nb103_fjz]
	movapd [esp + nb103_fjx], xmm0
	movapd [esp + nb103_fjy], xmm1
	movapd [esp + nb103_fjz], xmm2

	;# H2 interactions 
	movapd  xmm4, xmm5	
	mulpd   xmm4, xmm4	;# xmm5=rinv, xmm4=rinvsq 
	mulpd  xmm5, [esp + nb103_qqH]	;# xmm5=vcoul 
	mulpd  xmm4, xmm5		;# total fsH1 in xmm4 
	
	addpd  xmm5, [esp + nb103_vctot]

	movapd xmm0, [esp + nb103_dxH2]