nb_kernel211_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,984 行 · 第 1/5 页

##
## $Id: nb_kernel211_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##




.globl nb_kernel211_ia32_sse2
.globl _nb_kernel211_ia32_sse2
nb_kernel211_ia32_sse2: 
_nb_kernel211_ia32_sse2:        
.set nb211_p_nri, 8
.set nb211_iinr, 12
.set nb211_jindex, 16
.set nb211_jjnr, 20
.set nb211_shift, 24
.set nb211_shiftvec, 28
.set nb211_fshift, 32
.set nb211_gid, 36
.set nb211_pos, 40
.set nb211_faction, 44
.set nb211_charge, 48
.set nb211_p_facel, 52
.set nb211_argkrf, 56
.set nb211_argcrf, 60
.set nb211_Vc, 64
.set nb211_type, 68
.set nb211_p_ntype, 72
.set nb211_vdwparam, 76
.set nb211_Vvdw, 80
.set nb211_p_tabscale, 84
.set nb211_VFtab, 88
.set nb211_invsqrta, 92
.set nb211_dvda, 96
.set nb211_p_gbtabscale, 100
.set nb211_GBtab, 104
.set nb211_p_nthreads, 108
.set nb211_count, 112
.set nb211_mtx, 116
.set nb211_outeriter, 120
.set nb211_inneriter, 124
.set nb211_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb211_ixO, 0
.set nb211_iyO, 16
.set nb211_izO, 32
.set nb211_ixH1, 48
.set nb211_iyH1, 64
.set nb211_izH1, 80
.set nb211_ixH2, 96
.set nb211_iyH2, 112
.set nb211_izH2, 128
.set nb211_iqO, 144
.set nb211_iqH, 160
.set nb211_dxO, 176
.set nb211_dyO, 192
.set nb211_dzO, 208
.set nb211_dxH1, 224
.set nb211_dyH1, 240
.set nb211_dzH1, 256
.set nb211_dxH2, 272
.set nb211_dyH2, 288
.set nb211_dzH2, 304
.set nb211_qqO, 320
.set nb211_qqH, 336
.set nb211_c6, 352
.set nb211_c12, 368
.set nb211_six, 384
.set nb211_twelve, 400
.set nb211_vctot, 416
.set nb211_Vvdwtot, 432
.set nb211_fixO, 448
.set nb211_fiyO, 464
.set nb211_fizO, 480
.set nb211_fixH1, 496
.set nb211_fiyH1, 512
.set nb211_fizH1, 528
.set nb211_fixH2, 544
.set nb211_fiyH2, 560
.set nb211_fizH2, 576
.set nb211_fjx, 592
.set nb211_fjy, 608
.set nb211_fjz, 624
.set nb211_half, 640
.set nb211_three, 656
.set nb211_two, 672
.set nb211_krf, 688
.set nb211_crf, 704
.set nb211_krsqO, 720
.set nb211_krsqH1, 736
.set nb211_krsqH2, 752
.set nb211_is3, 768
.set nb211_ii3, 772
.set nb211_ntia, 776
.set nb211_innerjjnr, 780
.set nb211_innerk, 784
.set nb211_n, 788
.set nb211_nn1, 792
.set nb211_nri, 796
.set nb211_nouter, 800
.set nb211_ninner, 804
.set nb211_salign, 808
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $812,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb211_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb211_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb211_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb211_nouter(%esp)
        movl %eax,nb211_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb211_half(%esp)
        movl %ebx,nb211_half+4(%esp)
        movsd nb211_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## 6.0
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## 12.0
        movapd %xmm1,nb211_half(%esp)
        movapd %xmm2,nb211_two(%esp)
        movapd %xmm3,nb211_three(%esp)
        movapd %xmm4,nb211_six(%esp)
        movapd %xmm5,nb211_twelve(%esp)

        movl nb211_argkrf(%ebp),%esi
        movl nb211_argcrf(%ebp),%edi
        movsd (%esi),%xmm5
        movsd (%edi),%xmm6
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        movapd %xmm5,nb211_krf(%esp)
        movapd %xmm6,nb211_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb211_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb211_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        movsd 8(%edx,%ebx,8),%xmm4
        movl nb211_p_facel(%ebp),%esi
        movsd (%esi),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb211_iqO(%esp)
        movapd %xmm4,nb211_iqH(%esp)

        movl  nb211_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl nb211_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb211_ntia(%esp)
_nb_kernel211_ia32_sse2.nb211_threadloop: 
        movl  nb211_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel211_ia32_sse2.nb211_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel211_ia32_sse2.nb211_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb211_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb211_n(%esp)
        movl %ebx,nb211_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel211_ia32_sse2.nb211_outerstart
        jmp _nb_kernel211_ia32_sse2.nb211_end

_nb_kernel211_ia32_sse2.nb211_outerstart: 
        ## ebx contains number of outer iterations
        addl nb211_nouter(%esp),%ebx
        movl %ebx,nb211_nouter(%esp)

_nb_kernel211_ia32_sse2.nb211_outer: 
        movl  nb211_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb211_is3(%esp)      ## store is3 

        movl  nb211_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb211_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb211_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb211_ii3(%esp)

        addsd (%eax,%ebx,8),%xmm3
        addsd 8(%eax,%ebx,8),%xmm4
        addsd 16(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb211_ixO(%esp)
        movapd %xmm4,nb211_iyO(%esp)
        movapd %xmm5,nb211_izO(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm0
        addsd 32(%eax,%ebx,8),%xmm1
        addsd 40(%eax,%ebx,8),%xmm2
        addsd 48(%eax,%ebx,8),%xmm3
        addsd 56(%eax,%ebx,8),%xmm4
        addsd 64(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb211_ixH1(%esp)
        movapd %xmm1,nb211_iyH1(%esp)
        movapd %xmm2,nb211_izH1(%esp)
        movapd %xmm3,nb211_ixH2(%esp)
        movapd %xmm4,nb211_iyH2(%esp)
        movapd %xmm5,nb211_izH2(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb211_vctot(%esp)
        movapd %xmm4,nb211_Vvdwtot(%esp)
        movapd %xmm4,nb211_fixO(%esp)
        movapd %xmm4,nb211_fiyO(%esp)
        movapd %xmm4,nb211_fizO(%esp)
        movapd %xmm4,nb211_fixH1(%esp)
        movapd %xmm4,nb211_fiyH1(%esp)
        movapd %xmm4,nb211_fizH1(%esp)
        movapd %xmm4,nb211_fixH2(%esp)
        movapd %xmm4,nb211_fiyH2(%esp)
        movapd %xmm4,nb211_fizH2(%esp)

        movl  nb211_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx     ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb211_pos(%ebp),%esi
        movl  nb211_faction(%ebp),%edi
        movl  nb211_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb211_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb211_ninner(%esp),%ecx
        movl  %ecx,nb211_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb211_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel211_ia32_sse2.nb211_unroll_loop
        jmp   _nb_kernel211_ia32_sse2.nb211_checksingle
_nb_kernel211_ia32_sse2.nb211_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb211_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb211_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 

        movl nb211_charge(%ebp),%esi     ## base of charge[] 

        movlpd (%esi,%eax,8),%xmm3
        movhpd (%esi,%ebx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb211_iqO(%esp),%xmm3
        mulpd  nb211_iqH(%esp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1

        movapd  %xmm3,nb211_qqO(%esp)
        movapd  %xmm4,nb211_qqH(%esp)

        movl nb211_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl nb211_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        movl nb211_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx

        movlpd (%esi,%eax,8),%xmm6      ## c6a
        movlpd (%esi,%ebx,8),%xmm7      ## c6b
        movhpd 8(%esi,%eax,8),%xmm6     ## c6a c12a 
        movhpd 8(%esi,%ebx,8),%xmm7     ## c6b c12b 
        movapd %xmm6,%xmm4
        unpcklpd %xmm7,%xmm4
        unpckhpd %xmm7,%xmm6

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movapd %xmm4,nb211_c6(%esp)
        movapd %xmm6,nb211_c12(%esp)

        movl nb211_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move two coordinates to xmm0-xmm2 
        movlpd (%esi,%eax,8),%xmm0
        movlpd 8(%esi,%eax,8),%xmm1
        movlpd 16(%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm0
        movhpd 8(%esi,%ebx,8),%xmm1
        movhpd 16(%esi,%ebx,8),%xmm2

        ## move ixO-izO to xmm4-xmm6 
        movapd nb211_ixO(%esp),%xmm4
        movapd nb211_iyO(%esp),%xmm5
        movapd nb211_izO(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb211_dxO(%esp)
        movapd %xmm5,nb211_dyO(%esp)
        movapd %xmm6,nb211_dzO(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4