nb_kernel230_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,544 行 · 第 1/3 页

	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movapd xmm3, [esp + nb230_fix]
	movapd xmm4, [esp + nb230_fiy]
	movapd xmm5, [esp + nb230_fiz]
	addpd  xmm3, xmm0
	addpd  xmm4, xmm1
	addpd  xmm5, xmm2
	movapd [esp + nb230_fix], xmm3
	movapd [esp + nb230_fiy], xmm4
	movapd [esp + nb230_fiz], xmm5
	;# the fj's - start by accumulating forces from memory 
	movlpd xmm3, [edi + eax*8]
	movlpd xmm4, [edi + eax*8 + 8]
	movlpd xmm5, [edi + eax*8 + 16]
	movhpd xmm3, [edi + ebx*8]
	movhpd xmm4, [edi + ebx*8 + 8]
	movhpd xmm5, [edi + ebx*8 + 16]
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2
	movlpd [edi + eax*8], xmm3
	movlpd [edi + eax*8 + 8], xmm4
	movlpd [edi + eax*8 + 16], xmm5
	movhpd [edi + ebx*8], xmm3
	movhpd [edi + ebx*8 + 8], xmm4
	movhpd [edi + ebx*8 + 16], xmm5
	
	;# should we do one more iteration? 
	sub dword ptr [esp + nb230_innerk],  2
	jl    .nb230_checksingle
	jmp   .nb230_unroll_loop

.nb230_checksingle:				
	mov   edx, [esp + nb230_innerk]
	and   edx, 1
	jnz    .nb230_dosingle
	jmp    .nb230_updateouterdata
.nb230_dosingle:			
	mov esi, [ebp + nb230_charge]
	mov edi, [ebp + nb230_pos]
	mov   ecx, [esp + nb230_innerjjnr]
	xorpd xmm3, xmm3
	mov   eax, [ecx]

	movlpd xmm3, [esi + eax*8]
	movapd xmm5, [esp + nb230_iq]
	mulpd xmm3, xmm5		;# qq 
	
	movd  mm0, eax		;# use mmx registers as temp storage 
	mov esi, [ebp + nb230_type]
	mov eax, [esi + eax*4]
	mov esi, [ebp + nb230_vdwparam]
	shl eax, 1
	mov edi, [esp + nb230_ntia]
	add eax, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	xorpd xmm7, xmm7
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0		
	movapd [esp + nb230_c6], xmm4
	movapd [esp + nb230_c12], xmm6
	
	mov esi, [ebp + nb230_pos]       ;# base of pos[] 

	lea eax, [eax + eax*2]     ;# replace jnr with j3 

	;# move two coordinates to xmm0-xmm2 	
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	
	;# move ix-iz to xmm4-xmm6 
	movapd xmm4, [esp + nb230_ix]
	movapd xmm5, [esp + nb230_iy]
	movapd xmm6, [esp + nb230_iz]

	;# calc dr 
	subsd xmm4, xmm0
	subsd xmm5, xmm1
	subsd xmm6, xmm2

	;# store dr 
	movapd [esp + nb230_dx], xmm4
	movapd [esp + nb230_dy], xmm5
	movapd [esp + nb230_dz], xmm6
	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm4, xmm5
	addsd xmm4, xmm6
	;# rsq in xmm4 

	cvtsd2ss xmm5, xmm4	
	rsqrtss xmm5, xmm5
	cvtss2sd xmm2, xmm5	;# lu in low xmm2 

	movapd xmm7, [esp + nb230_krf]	
	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulsd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [esp + nb230_three]
	mulsd xmm7, xmm4	;# krsq 
	mulsd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb230_half]
	subsd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulsd xmm1, xmm5	
	mulsd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulsd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [esp + nb230_three]
	mulsd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb230_half]
	subsd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulsd xmm2, xmm5	
	mulsd xmm0, xmm2	;# xmm0=rinv 
	movapd xmm6, xmm0
	addsd  xmm6, xmm7	;# xmm6=rinv+ krsq 
	movapd xmm1, xmm4
	subsd  xmm6, [esp + nb230_crf]
	mulsd  xmm6, xmm3	;# xmm6=vcoul=qq*(rinv+ krsq) 
	mulsd  xmm7, [esp + nb230_two]
	movapd xmm1, xmm0
	subsd  xmm1, xmm7   ;# rinv-2*krsq
	mulsd  xmm1, xmm0   ;# (rinv-2*krsq)*rinv
	mulsd  xmm1, xmm3
	movsd [esp + nb230_fstmp], xmm1
	
	addsd  xmm6, [esp + nb230_vctot]
	movsd [esp + nb230_vctot], xmm6

	;# LJ table interaction. xmm0=rinv, cmm4=rsq
	
	mulsd xmm4, xmm0	;# xmm4=r 
	mulsd xmm4, [esp + nb230_tsc]
	
	cvttsd2si ebx, xmm4	;# mm6 = lu idx 
	cvtsi2sd xmm5, ebx
	subsd xmm4, xmm5
	movsd xmm1, xmm4	;# xmm1=eps 
	movsd xmm2, xmm1	
	mulsd  xmm2, xmm2	;# xmm2=eps2 

	shl   ebx, 3

	mov  esi, [ebp + nb230_VFtab]

	;# dispersion 
	movlpd xmm4, [esi + ebx*8]	;# Y1 	
	movhpd xmm4, [esi + ebx*8 + 8]	;# Y1 F1 	
	movapd xmm5, xmm4
	unpcklpd xmm4, xmm3	;# Y1 Y2 
	unpckhpd xmm5, xmm3	;# F1 F2 

	movlpd xmm6, [esi + ebx*8 + 16]	;# G1
	movhpd xmm6, [esi + ebx*8 + 24]	;# G1 H1 	
	movapd xmm7, xmm6
	unpcklpd xmm6, xmm3	;# G1 G2 
	unpckhpd xmm7, xmm3	;# H1 H2 
	;# dispersion table ready, in xmm4-xmm7 	
	mulsd  xmm6, xmm1	;# xmm6=Geps 
	mulsd  xmm7, xmm2	;# xmm7=Heps2 
	addsd  xmm5, xmm6
	addsd  xmm5, xmm7	;# xmm5=Fp 	
	mulsd  xmm7, [esp + nb230_two]	;# two*Heps2 
	addsd  xmm7, xmm6
	addsd  xmm7, xmm5 ;# xmm7=FF 
	mulsd  xmm5, xmm1 ;# xmm5=eps*Fp 
	addsd  xmm5, xmm4 ;# xmm5=VV 

	movsd xmm4, [esp + nb230_c6]
	mulsd  xmm7, xmm4	 ;# fijD 
	mulsd  xmm5, xmm4	 ;# Vvdw6 

	;# put scalar force on stack Update Vvdwtot directly 
	addsd  xmm5, [esp + nb230_Vvdwtot]
	movsd xmm3, [esp + nb230_fstmp]
	mulsd  xmm7, [esp + nb230_tsc]
	subsd  xmm3, xmm7
	movsd [esp + nb230_fstmp], xmm3
	movsd [esp + nb230_Vvdwtot], xmm5

	;# repulsion 
	movlpd xmm4, [esi + ebx*8 + 32]	;# Y1 	
	movhpd xmm4, [esi + ebx*8 + 40]	;# Y1 F1 	

	movapd xmm5, xmm4
	unpcklpd xmm4, xmm3	;# Y1 Y2 
	unpckhpd xmm5, xmm3	;# F1 F2 

	movlpd xmm6, [esi + ebx*8 + 48]	;# G1
	movhpd xmm6, [esi + ebx*8 + 56]	;# G1 H1 	

	movapd xmm7, xmm6
	unpcklpd xmm6, xmm3	;# G1 G2 
	unpckhpd xmm7, xmm3	;# H1 H2 
	
	;# table ready, in xmm4-xmm7 	
	mulsd  xmm6, xmm1	;# xmm6=Geps 
	mulsd  xmm7, xmm2	;# xmm7=Heps2 
	addsd  xmm5, xmm6
	addsd  xmm5, xmm7	;# xmm5=Fp 	
	mulsd  xmm7, [esp + nb230_two]	;# two*Heps2 
	addsd  xmm7, xmm6
	addsd  xmm7, xmm5 ;# xmm7=FF 
	mulsd  xmm5, xmm1 ;# xmm5=eps*Fp 
	addsd  xmm5, xmm4 ;# xmm5=VV 
	
	movsd xmm4, [esp + nb230_c12]
	mulsd  xmm7, xmm4 
	mulsd  xmm5, xmm4  
	
	addsd  xmm5, [esp + nb230_Vvdwtot]
	movsd xmm3, [esp + nb230_fstmp]
	mulsd  xmm7, [esp + nb230_tsc]
	subsd  xmm3, xmm7
	movsd [esp + nb230_Vvdwtot], xmm5

	mulsd  xmm3, xmm0
		
	movsd xmm0, [esp + nb230_dx]
	movsd xmm1, [esp + nb230_dy]
	movsd xmm2, [esp + nb230_dz]

	mov    edi, [ebp + nb230_faction]
	mulsd  xmm0, xmm3
	mulsd  xmm1, xmm3
	mulsd  xmm2, xmm3
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movlpd xmm3, [esp + nb230_fix]
	movlpd xmm4, [esp + nb230_fiy]
	movlpd xmm5, [esp + nb230_fiz]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movlpd [esp + nb230_fix], xmm3
	movlpd [esp + nb230_fiy], xmm4
	movlpd [esp + nb230_fiz], xmm5
	;# the fj's - start by accumulating forces from memory 
	movlpd xmm3, [edi + eax*8]
	movlpd xmm4, [edi + eax*8 + 8]
	movlpd xmm5, [edi + eax*8 + 16]
	subsd xmm3, xmm0
	subsd xmm4, xmm1
	subsd xmm5, xmm2
	movlpd [edi + eax*8], xmm3
	movlpd [edi + eax*8 + 8], xmm4
	movlpd [edi + eax*8 + 16], xmm5
	
.nb230_updateouterdata:
	mov   ecx, [esp + nb230_ii3]
	mov   edi, [ebp + nb230_faction]
	mov   esi, [ebp + nb230_fshift]
	mov   edx, [esp + nb230_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb230_fix]
	movapd xmm1, [esp + nb230_fiy]
	movapd xmm2, [esp + nb230_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addpd  xmm0, xmm3
	addpd  xmm1, xmm4
	addpd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8]
	movsd  xmm4, [edi + ecx*8 + 8]
	movsd  xmm5, [edi + ecx*8 + 16]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8],     xmm3
	movsd  [edi + ecx*8 + 8], xmm4
	movsd  [edi + ecx*8 + 16], xmm5

	;# increment fshift force  
	movsd  xmm3, [esi + edx*8]
	movsd  xmm4, [esi + edx*8 + 8]
	movsd  xmm5, [esi + edx*8 + 16]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [esi + edx*8],     xmm3
	movsd  [esi + edx*8 + 8], xmm4
	movsd  [esi + edx*8 + 16], xmm5

	;# get n from stack
	mov esi, [esp + nb230_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb230_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [esp + nb230_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb230_Vc]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
	;# accumulate total lj energy and update it 
	movapd xmm7, [esp + nb230_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb230_Vvdw]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
        ;# finish if last 
        mov ecx, [esp + nb230_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb230_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb230_n], esi
        jmp .nb230_outer
.nb230_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb230_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb230_end
        ;# non-zero, do one more workunit
        jmp   .nb230_threadloop
.nb230_end:
	emms

	mov eax, [esp + nb230_nouter]
	mov ebx, [esp + nb230_ninner]
	mov ecx, [ebp + nb230_outeriter]
	mov edx, [ebp + nb230_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb230_salign]
	add esp, eax
	add esp,  392
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret


.globl nb_kernel230nf_ia32_sse2
.globl _nb_kernel230nf_ia32_sse2
nb_kernel230nf_ia32_sse2:	
_nb_kernel230nf_ia32_sse2:	
.equiv          nb230nf_p_nri,            8
.equiv          nb230nf_iinr,             12
.equiv          nb230nf_jindex,           16
.equiv          nb230nf_jjnr,             20
.equiv          nb230nf_shift,            24
.equiv          nb230nf_shiftvec,         28
.equiv          nb230nf_fshift,           32
.equiv          nb230nf_gid,              36
.equiv          nb230nf_pos,              40
.equiv          nb230nf_faction,          44
.equiv          nb230nf_charge,           48
.equiv          nb230nf_p_facel,          52
.equiv          nb230nf_argkrf,           56
.equiv          nb230nf_argcrf,           60
.equiv          nb230nf_Vc,               64
.equiv          nb230nf_type,             68
.equiv          nb230nf_p_ntype,          72
.equiv          nb230nf_vdwparam,         76
.equiv          nb230nf_Vvdw,             80
.equiv          nb230nf_p_tabscale,       84
.equiv          nb230nf_VFtab,            88
.equiv          nb230nf_invsqrta,         92
.equiv          nb230nf_dvda,             96
.equiv          nb230nf_p_gbtabscale,     100
.equiv          nb230nf_GBtab,            104
.equiv          nb230nf_p_nthreads,       108
.equiv          nb230nf_count,            112
.equiv          nb230nf_mtx,              116
.equiv          nb230nf_outeriter,        120
.equiv          nb230nf_inneriter,        124
.equiv          nb230nf_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb230nf_ix,               0
.equiv          nb230nf_iy,               16
.equiv          nb230nf_iz,               32
.equiv          nb230nf_iq,               48
.equiv          nb230nf_dx,               64
.equiv          nb230nf_dy,               80
.equiv          nb230nf_dz,               96
.equiv          nb230nf_c6,               112
.equiv          nb230nf_c12,              128
.equiv          nb230nf_tsc,              144
.equiv          nb230nf_vctot,            176
.equiv          nb230nf_Vvdwtot,          192
.equiv          nb230nf_half,             256
.equiv          nb230nf_three,            272
.equiv          nb230nf_krf,              304
.equiv          nb230nf_crf,              320
.equiv          nb230nf_is3,              336
.equiv          nb230nf_ii3,              340
.equiv          nb230nf_ntia,             344
.equiv          nb230nf_innerjjnr,        348
.equiv          nb230nf_innerk,           352
.equiv          nb230nf_n,                356
.equiv          nb230nf_nn1,              360
.equiv          nb230nf_nri,              364
.equiv          nb230nf_facel,            368   ;# uses 8 bytes
.equiv          nb230nf_ntype,            376
.equiv          nb230nf_nouter,           380
.equiv          nb230nf_ninner,           384
.equiv          nb230nf_salign,           388
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp,  392		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb230nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb230nf_p_nri]
	mov esi, [ebp + nb230nf_p_facel]
	mov edi, [ebp + nb230nf_p_ntype]
	mov ecx, [ecx]
	movsd xmm7, [esi]
	mov edi, [edi]
	mov [esp + nb230nf_nri], ecx
	movsd [esp + nb230nf_facel], xmm7
	mov [esp + nb230nf_ntype], edi

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb230nf_nouter], eax
	mov [esp + nb230nf_ninner], eax

	mov eax, [ebp + nb230nf_p_tabscale]
	movsd xmm3, [eax]
	shufpd xmm3, xmm3, 0
	movapd [esp + nb230nf_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb230nf_half], eax
	mov [esp + nb230nf_half+4], ebx
	movsd xmm1, [esp + nb230nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb230nf_half], xmm1
	movapd [esp + nb230nf_three], xmm3

	mov esi, [ebp + nb230nf_argkrf]
	mov edi, [ebp + nb230nf_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb230nf_krf], xmm5
	movapd [esp + nb230nf_crf], xmm6

.nb230nf_threadloop:
        mov   esi, [ebp + nb230nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb230nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb230nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb230nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.