nb_kernel134_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,926 行 · 第 1/5 页

##
## $Id: nb_kernel134_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel134_ia32_sse2
.globl _nb_kernel134_ia32_sse2
nb_kernel134_ia32_sse2: 
_nb_kernel134_ia32_sse2:        
.set nb134_p_nri, 8
.set nb134_iinr, 12
.set nb134_jindex, 16
.set nb134_jjnr, 20
.set nb134_shift, 24
.set nb134_shiftvec, 28
.set nb134_fshift, 32
.set nb134_gid, 36
.set nb134_pos, 40
.set nb134_faction, 44
.set nb134_charge, 48
.set nb134_p_facel, 52
.set nb134_argkrf, 56
.set nb134_argcrf, 60
.set nb134_Vc, 64
.set nb134_type, 68
.set nb134_p_ntype, 72
.set nb134_vdwparam, 76
.set nb134_Vvdw, 80
.set nb134_p_tabscale, 84
.set nb134_VFtab, 88
.set nb134_invsqrta, 92
.set nb134_dvda, 96
.set nb134_p_gbtabscale, 100
.set nb134_GBtab, 104
.set nb134_p_nthreads, 108
.set nb134_count, 112
.set nb134_mtx, 116
.set nb134_outeriter, 120
.set nb134_inneriter, 124
.set nb134_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb134_ixO, 0
.set nb134_iyO, 16
.set nb134_izO, 32
.set nb134_ixH1, 48
.set nb134_iyH1, 64
.set nb134_izH1, 80
.set nb134_ixH2, 96
.set nb134_iyH2, 112
.set nb134_izH2, 128
.set nb134_ixM, 144
.set nb134_iyM, 160
.set nb134_izM, 176
.set nb134_jxO, 192
.set nb134_jyO, 208
.set nb134_jzO, 224
.set nb134_jxH1, 240
.set nb134_jyH1, 256
.set nb134_jzH1, 272
.set nb134_jxH2, 288
.set nb134_jyH2, 304
.set nb134_jzH2, 320
.set nb134_jxM, 336
.set nb134_jyM, 352
.set nb134_jzM, 368
.set nb134_dxOO, 384
.set nb134_dyOO, 400
.set nb134_dzOO, 416
.set nb134_dxH1H1, 432
.set nb134_dyH1H1, 448
.set nb134_dzH1H1, 464
.set nb134_dxH1H2, 480
.set nb134_dyH1H2, 496
.set nb134_dzH1H2, 512
.set nb134_dxH1M, 528
.set nb134_dyH1M, 544
.set nb134_dzH1M, 560
.set nb134_dxH2H1, 576
.set nb134_dyH2H1, 592
.set nb134_dzH2H1, 608
.set nb134_dxH2H2, 624
.set nb134_dyH2H2, 640
.set nb134_dzH2H2, 656
.set nb134_dxH2M, 672
.set nb134_dyH2M, 688
.set nb134_dzH2M, 704
.set nb134_dxMH1, 720
.set nb134_dyMH1, 736
.set nb134_dzMH1, 752
.set nb134_dxMH2, 768
.set nb134_dyMH2, 784
.set nb134_dzMH2, 800
.set nb134_dxMM, 816
.set nb134_dyMM, 832
.set nb134_dzMM, 848
.set nb134_qqMM, 864
.set nb134_qqMH, 880
.set nb134_qqHH, 896
.set nb134_two, 912
.set nb134_c6, 944
.set nb134_c12, 960
.set nb134_vctot, 976
.set nb134_Vvdwtot, 992
.set nb134_fixO, 1008
.set nb134_fiyO, 1024
.set nb134_fizO, 1040
.set nb134_fixH1, 1056
.set nb134_fiyH1, 1072
.set nb134_fizH1, 1088
.set nb134_fixH2, 1104
.set nb134_fiyH2, 1120
.set nb134_fizH2, 1136
.set nb134_fixM, 1152
.set nb134_fiyM, 1168
.set nb134_fizM, 1184
.set nb134_fjxO, 1200
.set nb134_fjyO, 1216
.set nb134_fjzO, 1232
.set nb134_fjxH1, 1248
.set nb134_fjyH1, 1264
.set nb134_fjzH1, 1280
.set nb134_fjxH2, 1296
.set nb134_fjyH2, 1312
.set nb134_fjzH2, 1328
.set nb134_fjxM, 1344
.set nb134_fjyM, 1360
.set nb134_fjzM, 1376
.set nb134_half, 1392
.set nb134_three, 1408
.set nb134_tsc, 1424
.set nb134_fstmp, 1440
.set nb134_rsqOO, 1456
.set nb134_rsqH1H1, 1472
.set nb134_rsqH1H2, 1488
.set nb134_rsqH1M, 1504
.set nb134_rsqH2H1, 1520
.set nb134_rsqH2H2, 1536
.set nb134_rsqH2M, 1552
.set nb134_rsqMH1, 1568
.set nb134_rsqMH2, 1584
.set nb134_rsqMM, 1600
.set nb134_rinvOO, 1616
.set nb134_rinvH1H1, 1632
.set nb134_rinvH1H2, 1648
.set nb134_rinvH1M, 1664
.set nb134_rinvH2H1, 1680
.set nb134_rinvH2H2, 1696
.set nb134_rinvH2M, 1712
.set nb134_rinvMH1, 1728
.set nb134_rinvMH2, 1744
.set nb134_rinvMM, 1760
.set nb134_is3, 1808
.set nb134_ii3, 1812
.set nb134_innerjjnr, 1816
.set nb134_innerk, 1820
.set nb134_n, 1824
.set nb134_nn1, 1828
.set nb134_nri, 1832
.set nb134_nouter, 1836
.set nb134_ninner, 1840
.set nb134_salign, 1844
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1848,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb134_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb134_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb134_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb134_nouter(%esp)
        movl %eax,nb134_ninner(%esp)

        movl nb134_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb134_tsc(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb134_half(%esp)
        movl %ebx,nb134_half+4(%esp)
        movsd nb134_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb134_half(%esp)
        movapd %xmm2,nb134_two(%esp)
        movapd %xmm3,nb134_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb134_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb134_charge(%ebp),%edx
        movsd 24(%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb134_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb134_qqMM(%esp)
        movapd %xmm4,nb134_qqMH(%esp)
        movapd %xmm5,nb134_qqHH(%esp)

        xorpd %xmm0,%xmm0
        movl  nb134_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb134_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb134_vdwparam(%ebp),%eax
        movlpd (%eax,%edx,8),%xmm0
        movhpd 8(%eax,%edx,8),%xmm0
        movhlps %xmm0,%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb134_c6(%esp)
        movapd %xmm1,nb134_c12(%esp)

_nb_kernel134_ia32_sse2.nb134_threadloop: 
        movl  nb134_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel134_ia32_sse2.nb134_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel134_ia32_sse2.nb134_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb134_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb134_n(%esp)
        movl %ebx,nb134_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel134_ia32_sse2.nb134_outerstart
        jmp _nb_kernel134_ia32_sse2.nb134_end

_nb_kernel134_ia32_sse2.nb134_outerstart: 
        ## ebx contains number of outer iterations
        addl nb134_nouter(%esp),%ebx
        movl %ebx,nb134_nouter(%esp)

_nb_kernel134_ia32_sse2.nb134_outer: 
        movl  nb134_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb134_is3(%esp)      ## store is3 

        movl  nb134_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb134_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb134_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb134_ii3(%esp)

        addsd (%eax,%ebx,8),%xmm3       ## ox
        addsd 8(%eax,%ebx,8),%xmm4      ## oy
        addsd 16(%eax,%ebx,8),%xmm5     ## oz   
        addsd 24(%eax,%ebx,8),%xmm6     ## h1x
        addsd 32(%eax,%ebx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb134_ixO(%esp)
        movapd %xmm4,nb134_iyO(%esp)
        movapd %xmm5,nb134_izO(%esp)
        movapd %xmm6,nb134_ixH1(%esp)
        movapd %xmm7,nb134_iyH1(%esp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%eax,%ebx,8),%xmm6    ## h1z
        addsd 48(%eax,%ebx,8),%xmm0    ## h2x
        addsd 56(%eax,%ebx,8),%xmm1    ## h2y
        addsd 64(%eax,%ebx,8),%xmm2    ## h2z
        addsd 72(%eax,%ebx,8),%xmm3    ## mx
        addsd 80(%eax,%ebx,8),%xmm4    ## my
        addsd 88(%eax,%ebx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb134_izH1(%esp)
        movapd %xmm0,nb134_ixH2(%esp)
        movapd %xmm1,nb134_iyH2(%esp)
        movapd %xmm2,nb134_izH2(%esp)
        movapd %xmm3,nb134_ixM(%esp)
        movapd %xmm4,nb134_iyM(%esp)
        movapd %xmm5,nb134_izM(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb134_vctot(%esp)
        movapd %xmm4,nb134_Vvdwtot(%esp)
        movapd %xmm4,nb134_fixO(%esp)
        movapd %xmm4,nb134_fiyO(%esp)
        movapd %xmm4,nb134_fizO(%esp)
        movapd %xmm4,nb134_fixH1(%esp)
        movapd %xmm4,nb134_fiyH1(%esp)
        movapd %xmm4,nb134_fizH1(%esp)
        movapd %xmm4,nb134_fixH2(%esp)
        movapd %xmm4,nb134_fiyH2(%esp)
        movapd %xmm4,nb134_fizH2(%esp)
        movapd %xmm4,nb134_fixM(%esp)
        movapd %xmm4,nb134_fiyM(%esp)
        movapd %xmm4,nb134_fizM(%esp)

        movl  nb134_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms