nb_kernel104_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,152 行 · 第 1/5 页

	movapd xmm0, [esp + nb104_fixH2]
	movapd xmm1, [esp + nb104_fiyH2]
	movapd xmm2, [esp + nb104_fizH2]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 48]
	movsd  xmm4, [edi + ecx*8 + 56]
	movsd  xmm5, [edi + ecx*8 + 64]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 48], xmm3
	movsd  [edi + ecx*8 + 56], xmm4
	movsd  [edi + ecx*8 + 64], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# accumulate H2i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb104_fixM]
	movapd xmm1, [esp + nb104_fiyM]
	movapd xmm2, [esp + nb104_fizM]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	movapd xmm3, xmm0	
	movapd xmm4, xmm1	
	movapd xmm5, xmm2	

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 72]
	movsd  xmm4, [edi + ecx*8 + 80]
	movsd  xmm5, [edi + ecx*8 + 88]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 72], xmm3
	movsd  [edi + ecx*8 + 80], xmm4
	movsd  [edi + ecx*8 + 88], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# increment fshift force 
	movlpd xmm3, [esi + edx*8]
	movhpd xmm3, [esi + edx*8 + 8]
	movsd  xmm4, [esi + edx*8 + 16]
	addpd  xmm3, xmm6
	addsd  xmm4, xmm7
	movlpd [esi + edx*8],      xmm3
	movhpd [esi + edx*8 + 8],  xmm3
	movsd  [esi + edx*8 + 16], xmm4

	;# get n from stack
	mov esi, [esp + nb104_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb104_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [esp + nb104_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# pos 0-1 in xmm7 have the sum now 
	        
	;# add earlier value from mem 
	mov   eax, [ebp + nb104_Vc]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 	
	
        ;# finish if last 
        mov ecx, [esp + nb104_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb104_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb104_n], esi
        jmp .nb104_outer
.nb104_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb104_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb104_end
        ;# non-zero, do one more workunit
        jmp   .nb104_threadloop
.nb104_end:
	emms

	mov eax, [esp + nb104_nouter]
	mov ebx, [esp + nb104_ninner]
	mov ecx, [ebp + nb104_outeriter]
	mov edx, [ebp + nb104_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb104_salign]
	add esp, eax
	add esp, 1432
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret


	
.globl nb_kernel104nf_ia32_sse2
.globl _nb_kernel104nf_ia32_sse2
nb_kernel104nf_ia32_sse2:	
_nb_kernel104nf_ia32_sse2:	
.equiv          nb104nf_p_nri,          8
.equiv          nb104nf_iinr,           12
.equiv          nb104nf_jindex,         16
.equiv          nb104nf_jjnr,           20
.equiv          nb104nf_shift,          24
.equiv          nb104nf_shiftvec,       28
.equiv          nb104nf_fshift,         32
.equiv          nb104nf_gid,            36
.equiv          nb104nf_pos,            40
.equiv          nb104nf_faction,        44
.equiv          nb104nf_charge,         48
.equiv          nb104nf_p_facel,        52
.equiv          nb104nf_argkrf,         56
.equiv          nb104nf_argcrf,         60
.equiv          nb104nf_Vc,             64
.equiv          nb104nf_type,           68
.equiv          nb104nf_p_ntype,        72
.equiv          nb104nf_vdwparam,       76
.equiv          nb104nf_Vvdw,           80
.equiv          nb104nf_p_tabscale,     84
.equiv          nb104nf_VFtab,          88
.equiv          nb104nf_invsqrta,       92
.equiv          nb104nf_dvda,           96
.equiv          nb104nf_p_gbtabscale,   100
.equiv          nb104nf_GBtab,          104
.equiv          nb104nf_p_nthreads,     108
.equiv          nb104nf_count,          112
.equiv          nb104nf_mtx,            116
.equiv          nb104nf_outeriter,      120
.equiv          nb104nf_inneriter,      124
.equiv          nb104nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb104nf_ixM,            0
.equiv          nb104nf_iyM,            16
.equiv          nb104nf_izM,            32
.equiv          nb104nf_ixH1,           48
.equiv          nb104nf_iyH1,           64
.equiv          nb104nf_izH1,           80
.equiv          nb104nf_ixH2,           96
.equiv          nb104nf_iyH2,           112
.equiv          nb104nf_izH2,           128
.equiv          nb104nf_jxM,            144
.equiv          nb104nf_jyM,            160
.equiv          nb104nf_jzM,            176
.equiv          nb104nf_jxH1,           192
.equiv          nb104nf_jyH1,           208
.equiv          nb104nf_jzH1,           224
.equiv          nb104nf_jxH2,           240
.equiv          nb104nf_jyH2,           256
.equiv          nb104nf_jzH2,           272
.equiv          nb104nf_qqMM,           288
.equiv          nb104nf_qqMH,           304
.equiv          nb104nf_qqHH,           320
.equiv          nb104nf_vctot,          336
.equiv          nb104nf_half,           352
.equiv          nb104nf_three,          368
.equiv          nb104nf_rsqMM,          384
.equiv          nb104nf_rsqMH1,         400
.equiv          nb104nf_rsqMH2,         416
.equiv          nb104nf_rsqH1M,         432
.equiv          nb104nf_rsqH1H1,        448
.equiv          nb104nf_rsqH1H2,        464
.equiv          nb104nf_rsqH2M,         480
.equiv          nb104nf_rsqH2H1,        496
.equiv          nb104nf_rsqH2H2,        512
.equiv          nb104nf_rinvMM,         528
.equiv          nb104nf_rinvMH1,        544
.equiv          nb104nf_rinvMH2,        560
.equiv          nb104nf_rinvH1M,        576
.equiv          nb104nf_rinvH1H1,       592
.equiv          nb104nf_rinvH1H2,       608
.equiv          nb104nf_rinvH2M,        624
.equiv          nb104nf_rinvH2H1,       640
.equiv          nb104nf_rinvH2H2,       656
.equiv          nb104nf_is3,            672
.equiv          nb104nf_ii3,            676
.equiv          nb104nf_innerjjnr,      680
.equiv          nb104nf_innerk,         684
.equiv          nb104nf_n,              688
.equiv          nb104nf_nn1,            692
.equiv          nb104nf_nri,            696
.equiv          nb104nf_nouter,         700
.equiv          nb104nf_ninner,         704
.equiv          nb104nf_salign,         708
	push ebp
	mov ebp,esp	
    push eax
    push ebx
    push ecx
    push edx
	push esi
	push edi
	sub esp, 712		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb104nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb104nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb104nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb104nf_nouter], eax
	mov [esp + nb104nf_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb104nf_half], eax
	mov [esp + nb104nf_half+4], ebx
	movsd xmm1, [esp + nb104nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb104nf_half], xmm1
	movapd [esp + nb104nf_three], xmm3
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb104nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb104nf_charge]
	movsd xmm3, [edx + ebx*8 + 24]	;# qM 
	movsd xmm4, xmm3		;# qM 
	movsd xmm5, [edx + ebx*8 + 8]	;# qH 
	mov esi, [ebp + nb104nf_p_facel]
	movsd xmm6, [esi]	;# facel 
	mulsd  xmm3, xmm3		;# qM*qM 
	mulsd  xmm4, xmm5		;# qM*qH 
	mulsd  xmm5, xmm5		;# qH*qH 
	mulsd  xmm3, xmm6
	mulsd  xmm4, xmm6
	mulsd  xmm5, xmm6
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb104nf_qqMM], xmm3
	movapd [esp + nb104nf_qqMH], xmm4
	movapd [esp + nb104nf_qqHH], xmm5

.nb104nf_threadloop:
        mov   esi, [ebp + nb104nf_count]        ;# pointer to sync counter
        mov   eax, [esi]
.nb104nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           	;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb104nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb104nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb104nf_n], eax
        mov [esp + nb104nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb104nf_outerstart
        jmp .nb104nf_end

.nb104nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb104nf_nouter]
	mov [esp + nb104nf_nouter], ebx

.nb104nf_outer:
	mov   eax, [ebp + nb104nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 

	mov   eax, [ebp + nb104nf_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb104nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb104nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb104nf_ii3], ebx	
	
	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	addsd xmm3, [eax + ebx*8 + 24]
	addsd xmm4, [eax + ebx*8 + 32]
	addsd xmm5, [eax + ebx*8 + 40]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb104nf_ixH1], xmm3
	movapd [esp + nb104nf_iyH1], xmm4
	movapd [esp + nb104nf_izH1], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 48]
	addsd xmm1, [eax + ebx*8 + 56]
	addsd xmm2, [eax + ebx*8 + 64]		
	addsd xmm3, [eax + ebx*8 + 72]
	addsd xmm4, [eax + ebx*8 + 80]
	addsd xmm5, [eax + ebx*8 + 88]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb104nf_ixH2], xmm0
	movapd [esp + nb104nf_iyH2], xmm1
	movapd [esp + nb104nf_izH2], xmm2
	movapd [esp + nb104nf_ixM], xmm3
	movapd [esp + nb104nf_iyM], xmm4
	movapd [esp + nb104nf_izM], xmm5

	;# clear vctot 
	xorpd xmm4, xmm4
	movapd [esp + nb104nf_vctot], xmm4
	
	mov   eax, [ebp + nb104nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb104nf_pos]
	mov   eax, [ebp + nb104nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb104nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb104nf_ninner]
	mov   [esp + nb104nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb104nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb104nf_unroll_loop
	jmp   .nb104nf_checksingle
.nb104nf_unroll_loop:	
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb104nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4] 
	
	add dword ptr [esp + nb104nf_innerjjnr], 8 ;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb104nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	
	
	;# move j coordinates to local temp variables 
	movlpd xmm2, [esi + eax*8 + 24]
	movlpd xmm3, [esi + eax*8 + 32]
	movlpd xmm4, [esi + eax*8 + 40]
	movlpd xmm5, [esi + eax*8 + 48]
	movlpd xmm6, [esi + eax*8 + 56]
	movlpd xmm7, [esi + eax*8 + 64]
	movhpd xmm2, [esi + ebx*8 + 24]
	movhpd xmm3, [esi + ebx*8 + 32]
	movhpd xmm4, [esi + ebx*8 + 40]
	movhpd xmm5, [esi + ebx*8 + 48]
	movhpd xmm6, [esi + ebx*8 + 56]
	movhpd xmm7, [esi + ebx*8 + 64]
	movapd 	[esp + nb104nf_jxH1], xmm2
	movapd 	[esp + nb104nf_jyH1], xmm3
	movapd 	[esp + nb104nf_jzH1], xmm4
	movapd 	[esp + nb104nf_jxH2], xmm5
	movapd 	[esp + nb104nf_jyH2], xmm6
	movapd 	[esp + nb104nf_jzH2], xmm7
	movlpd xmm2, [esi + eax*8 + 72]
	movlpd xmm3, [esi + eax*8 + 80]
	movlpd xmm4, [esi + eax*8 + 88]
	movhpd xmm2,