nb_kernel213_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,246 行 · 第 1/5 页

;#
;# $Id: nb_kernel213_ia32_sse2.intel_syntax.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel213_ia32_sse2
.globl _nb_kernel213_ia32_sse2
nb_kernel213_ia32_sse2:	
_nb_kernel213_ia32_sse2:	
.equiv          nb213_p_nri,            8
.equiv          nb213_iinr,             12
.equiv          nb213_jindex,           16
.equiv          nb213_jjnr,             20
.equiv          nb213_shift,            24
.equiv          nb213_shiftvec,         28
.equiv          nb213_fshift,           32
.equiv          nb213_gid,              36
.equiv          nb213_pos,              40
.equiv          nb213_faction,          44
.equiv          nb213_charge,           48
.equiv          nb213_p_facel,          52
.equiv          nb213_argkrf,           56
.equiv          nb213_argcrf,           60
.equiv          nb213_Vc,               64
.equiv          nb213_type,             68
.equiv          nb213_p_ntype,          72
.equiv          nb213_vdwparam,         76
.equiv          nb213_Vvdw,             80
.equiv          nb213_p_tabscale,       84
.equiv          nb213_VFtab,            88
.equiv          nb213_invsqrta,         92
.equiv          nb213_dvda,             96
.equiv          nb213_p_gbtabscale,     100
.equiv          nb213_GBtab,            104
.equiv          nb213_p_nthreads,       108
.equiv          nb213_count,            112
.equiv          nb213_mtx,              116
.equiv          nb213_outeriter,        120
.equiv          nb213_inneriter,        124
.equiv          nb213_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb213_ixO,              0
.equiv          nb213_iyO,              16
.equiv          nb213_izO,              32
.equiv          nb213_ixH1,             48
.equiv          nb213_iyH1,             64
.equiv          nb213_izH1,             80
.equiv          nb213_ixH2,             96
.equiv          nb213_iyH2,             112
.equiv          nb213_izH2,             128
.equiv          nb213_ixM,              144
.equiv          nb213_iyM,              160
.equiv          nb213_izM,              176
.equiv          nb213_iqH,              192
.equiv          nb213_iqM,              208
.equiv          nb213_dxO,              224
.equiv          nb213_dyO,              240
.equiv          nb213_dzO,              256
.equiv          nb213_dxH1,             272
.equiv          nb213_dyH1,             288
.equiv          nb213_dzH1,             304
.equiv          nb213_dxH2,             320
.equiv          nb213_dyH2,             336
.equiv          nb213_dzH2,             352
.equiv          nb213_dxM,              368
.equiv          nb213_dyM,              384
.equiv          nb213_dzM,              400
.equiv          nb213_qqH,              416
.equiv          nb213_qqM,              432
.equiv          nb213_c6,               448
.equiv          nb213_c12,              464
.equiv          nb213_six,              480
.equiv          nb213_twelve,           496
.equiv          nb213_vctot,            512
.equiv          nb213_Vvdwtot,          528
.equiv          nb213_fixO,             544
.equiv          nb213_fiyO,             560
.equiv          nb213_fizO,             576
.equiv          nb213_fixH1,            592
.equiv          nb213_fiyH1,            608
.equiv          nb213_fizH1,            624
.equiv          nb213_fixH2,            640
.equiv          nb213_fiyH2,            656
.equiv          nb213_fizH2,            672
.equiv          nb213_fixM,             688
.equiv          nb213_fiyM,             704
.equiv          nb213_fizM,             720
.equiv          nb213_fjx,              736
.equiv          nb213_fjy,              752
.equiv          nb213_fjz,              768
.equiv          nb213_half,             784
.equiv          nb213_three,            800
.equiv          nb213_two,              816
.equiv          nb213_rinvH1,           832
.equiv          nb213_rinvH2,           848
.equiv          nb213_rinvM,            864
.equiv          nb213_krsqH1,           880
.equiv          nb213_krsqH2,           896
.equiv          nb213_krsqM,            912
.equiv          nb213_krf,              928
.equiv          nb213_crf,              944
.equiv          nb213_is3,              960
.equiv          nb213_ii3,              964
.equiv          nb213_ntia,             968
.equiv          nb213_innerjjnr,        972
.equiv          nb213_innerk,           976
.equiv          nb213_n,                980
.equiv          nb213_nn1,              984
.equiv          nb213_nri,              988
.equiv          nb213_nouter,           992
.equiv          nb213_ninner,           996
.equiv          nb213_salign,           1000
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 1004		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb213_salign], eax
	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb213_p_nri]
	mov ecx, [ecx]
	mov [esp + nb213_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb213_nouter], eax
	mov [esp + nb213_ninner], eax


	mov esi, [ebp + nb213_argkrf]
	mov edi, [ebp + nb213_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb213_krf], xmm5
	movapd [esp + nb213_crf], xmm6

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb213_half], eax
	mov [esp + nb213_half+4], ebx
	movsd xmm1, [esp + nb213_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd xmm4, xmm3
	addpd  xmm4, xmm4       ;# 6.0
	movapd xmm5, xmm4
	addpd  xmm5, xmm5       ;# 12.0
	movapd [esp + nb213_half], xmm1
	movapd [esp + nb213_two], xmm2
	movapd [esp + nb213_three], xmm3
	movapd [esp + nb213_six], xmm4
	movapd [esp + nb213_twelve], xmm5

	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb213_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb213_charge]
	movsd xmm3, [edx + ebx*8 + 8]	
	movsd xmm4, [edx + ebx*8 + 24]	
	mov esi, [ebp + nb213_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb213_iqH], xmm3
	movapd [esp + nb213_iqM], xmm4
	
	mov   edx, [ebp + nb213_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb213_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb213_ntia], ecx		
.nb213_threadloop:
        mov   esi, [ebp + nb213_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb213_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb213_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb213_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb213_n], eax
        mov [esp + nb213_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb213_outerstart
        jmp .nb213_end

.nb213_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb213_nouter]
	mov [esp + nb213_nouter], ebx

.nb213_outer:
	mov   eax, [ebp + nb213_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb213_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb213_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb213_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	movapd xmm6, xmm0
	movapd xmm7, xmm1

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb213_pos]    ;# eax = base of pos[]  
	mov   [esp + nb213_ii3], ebx

	addsd xmm3, [eax + ebx*8] 	;# ox
	addsd xmm4, [eax + ebx*8 + 8] 	;# oy
	addsd xmm5, [eax + ebx*8 + 16]	;# oz	
	addsd xmm6, [eax + ebx*8 + 24] 	;# h1x
	addsd xmm7, [eax + ebx*8 + 32] 	;# h1y
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	shufpd xmm7, xmm7, 0
	movapd [esp + nb213_ixO], xmm3
	movapd [esp + nb213_iyO], xmm4
	movapd [esp + nb213_izO], xmm5
	movapd [esp + nb213_ixH1], xmm6
	movapd [esp + nb213_iyH1], xmm7

	movsd xmm6, xmm2
	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm6, [eax + ebx*8 + 40] ;# h1z
	addsd xmm0, [eax + ebx*8 + 48] ;# h2x
	addsd xmm1, [eax + ebx*8 + 56] ;# h2y
	addsd xmm2, [eax + ebx*8 + 64] ;# h2z
	addsd xmm3, [eax + ebx*8 + 72] ;# mx
	addsd xmm4, [eax + ebx*8 + 80] ;# my
	addsd xmm5, [eax + ebx*8 + 88] ;# mz

	shufpd xmm6, xmm6, 0
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb213_izH1], xmm6
	movapd [esp + nb213_ixH2], xmm0
	movapd [esp + nb213_iyH2], xmm1
	movapd [esp + nb213_izH2], xmm2
	movapd [esp + nb213_ixM], xmm3
	movapd [esp + nb213_iyM], xmm4
	movapd [esp + nb213_izM], xmm5

	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [esp + nb213_vctot], xmm4
	movapd [esp + nb213_Vvdwtot], xmm4
	movapd [esp + nb213_fixO], xmm4
	movapd [esp + nb213_fiyO], xmm4
	movapd [esp + nb213_fizO], xmm4
	movapd [esp + nb213_fixH1], xmm4
	movapd [esp + nb213_fiyH1], xmm4
	movapd [esp + nb213_fizH1], xmm4
	movapd [esp + nb213_fixH2], xmm4
	movapd [esp + nb213_fiyH2], xmm4
	movapd [esp + nb213_fizH2], xmm4
	movapd [esp + nb213_fixM], xmm4
	movapd [esp + nb213_fiyM], xmm4
	movapd [esp + nb213_fizM], xmm4
	
	mov   eax, [ebp + nb213_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb213_pos]
	mov   edi, [ebp + nb213_faction]	
	mov   eax, [ebp + nb213_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb213_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb213_ninner]
	mov   [esp + nb213_ninner], ecx
	add   edx, 0
	mov   [esp + nb213_innerk], edx    ;# number of innerloop atoms 
	jge   .nb213_unroll_loop
	jmp   .nb213_checksingle
.nb213_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb213_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb213_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb213_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb213_iqM]
	mulpd  xmm4, [esp + nb213_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx

	movapd  [esp + nb213_qqM], xmm3
	movapd  [esp + nb213_qqH], xmm4
	
	mov esi, [ebp + nb213_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb213_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	mov edi, [esp + nb213_ntia]
	add eax, edi
	add ebx, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movlpd xmm7, [esi + ebx*8]	;# c6b
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	movhpd xmm7, [esi + ebx*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0
	movd  ebx, mm1
	movapd [esp + nb213_c6], xmm4
	movapd [esp + nb213_c12], xmm6
	
	mov esi, [ebp + nb213_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		

	;# move ixO-izO to xmm4-xmm6 
	movapd xmm4, [esp + nb213_ixO]
	movapd xmm5, [esp + nb213_iyO]
	movapd xmm6, [esp + nb213_izO]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb213_dxO], xmm4
	movapd [esp + nb213_dyO], xmm5
	movapd [esp + nb213_dzO], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6