nb_kernel230_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,518 行 · 第 1/4 页

##
## $Id: nb_kernel230_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel230_ia32_sse2
.globl _nb_kernel230_ia32_sse2
nb_kernel230_ia32_sse2: 
_nb_kernel230_ia32_sse2:        
.set nb230_p_nri, 8
.set nb230_iinr, 12
.set nb230_jindex, 16
.set nb230_jjnr, 20
.set nb230_shift, 24
.set nb230_shiftvec, 28
.set nb230_fshift, 32
.set nb230_gid, 36
.set nb230_pos, 40
.set nb230_faction, 44
.set nb230_charge, 48
.set nb230_p_facel, 52
.set nb230_argkrf, 56
.set nb230_argcrf, 60
.set nb230_Vc, 64
.set nb230_type, 68
.set nb230_p_ntype, 72
.set nb230_vdwparam, 76
.set nb230_Vvdw, 80
.set nb230_p_tabscale, 84
.set nb230_VFtab, 88
.set nb230_invsqrta, 92
.set nb230_dvda, 96
.set nb230_p_gbtabscale, 100
.set nb230_GBtab, 104
.set nb230_p_nthreads, 108
.set nb230_count, 112
.set nb230_mtx, 116
.set nb230_outeriter, 120
.set nb230_inneriter, 124
.set nb230_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb230_ix, 0
.set nb230_iy, 16
.set nb230_iz, 32
.set nb230_iq, 48
.set nb230_dx, 64
.set nb230_dy, 80
.set nb230_dz, 96
.set nb230_c6, 112
.set nb230_c12, 128
.set nb230_tsc, 144
.set nb230_fstmp, 160
.set nb230_vctot, 176
.set nb230_Vvdwtot, 192
.set nb230_fix, 208
.set nb230_fiy, 224
.set nb230_fiz, 240
.set nb230_half, 256
.set nb230_three, 272
.set nb230_two, 288
.set nb230_krf, 304
.set nb230_crf, 320
.set nb230_is3, 336
.set nb230_ii3, 340
.set nb230_ntia, 344
.set nb230_innerjjnr, 348
.set nb230_innerk, 352
.set nb230_n, 356
.set nb230_nn1, 360
.set nb230_nri, 364
.set nb230_facel, 368                         ## uses 8 bytes
.set nb230_ntype, 376
.set nb230_nouter, 380
.set nb230_ninner, 384
.set nb230_salign, 388
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $392,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb230_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb230_p_nri(%ebp),%ecx
        movl nb230_p_facel(%ebp),%esi
        movl nb230_p_ntype(%ebp),%edi
        movl (%ecx),%ecx
        movsd (%esi),%xmm7
        movl (%edi),%edi
        movl %ecx,nb230_nri(%esp)
        movsd %xmm7,nb230_facel(%esp)
        movl %edi,nb230_ntype(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb230_nouter(%esp)
        movl %eax,nb230_ninner(%esp)

        movl nb230_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb230_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb230_half(%esp)
        movl %ebx,nb230_half+4(%esp)
        movsd nb230_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb230_half(%esp)
        movapd %xmm2,nb230_two(%esp)
        movapd %xmm3,nb230_three(%esp)

        movl nb230_argkrf(%ebp),%esi
        movl nb230_argcrf(%ebp),%edi
        movsd (%esi),%xmm5
        movsd (%edi),%xmm6
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        movapd %xmm5,nb230_krf(%esp)
        movapd %xmm6,nb230_crf(%esp)

_nb_kernel230_ia32_sse2.nb230_threadloop: 
        movl  nb230_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel230_ia32_sse2.nb230_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel230_ia32_sse2.nb230_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb230_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb230_n(%esp)
        movl %ebx,nb230_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel230_ia32_sse2.nb230_outerstart
        jmp _nb_kernel230_ia32_sse2.nb230_end

_nb_kernel230_ia32_sse2.nb230_outerstart: 
        ## ebx contains number of outer iterations
        addl nb230_nouter(%esp),%ebx
        movl %ebx,nb230_nouter(%esp)

_nb_kernel230_ia32_sse2.nb230_outer: 
        movl  nb230_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb230_is3(%esp)      ## store is3 

        movl  nb230_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb230_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movl  nb230_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        mulsd nb230_facel(%esp),%xmm3
        shufpd $0,%xmm3,%xmm3

        movl  nb230_type(%ebp),%edx
        movl  (%edx,%ebx,4),%edx
        imull nb230_ntype(%esp),%edx
        shll  %edx
        movl  %edx,nb230_ntia(%esp)

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb230_pos(%ebp),%eax      ## eax = base of pos[]  

        addsd (%eax,%ebx,8),%xmm0
        addsd 8(%eax,%ebx,8),%xmm1
        addsd 16(%eax,%ebx,8),%xmm2

        movapd %xmm3,nb230_iq(%esp)

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2

        movapd %xmm0,nb230_ix(%esp)
        movapd %xmm1,nb230_iy(%esp)
        movapd %xmm2,nb230_iz(%esp)

        movl  %ebx,nb230_ii3(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb230_vctot(%esp)
        movapd %xmm4,nb230_Vvdwtot(%esp)
        movapd %xmm4,nb230_fix(%esp)
        movapd %xmm4,nb230_fiy(%esp)
        movapd %xmm4,nb230_fiz(%esp)

        movl  nb230_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb230_pos(%ebp),%esi
        movl  nb230_faction(%ebp),%edi
        movl  nb230_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb230_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb230_ninner(%esp),%ecx
        movl  %ecx,nb230_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb230_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel230_ia32_sse2.nb230_unroll_loop
        jmp   _nb_kernel230_ia32_sse2.nb230_checksingle
_nb_kernel230_ia32_sse2.nb230_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb230_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx
        addl $8,nb230_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 

        movl nb230_charge(%ebp),%esi     ## base of charge[] 

        movlpd (%esi,%eax,8),%xmm3
        movhpd (%esi,%ebx,8),%xmm3

        movapd nb230_iq(%esp),%xmm5
        mulpd %xmm5,%xmm3               ## qq 

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1

        movl nb230_type(%ebp),%esi
        movl (%esi,%eax,4),%eax
        movl (%esi,%ebx,4),%ebx
        movl nb230_vdwparam(%ebp),%esi
        shll %eax
        shll %ebx
        movl nb230_ntia(%esp),%edi
        addl %edi,%eax
        addl %edi,%ebx

        movlpd (%esi,%eax,8),%xmm6      ## c6a
        movlpd (%esi,%ebx,8),%xmm7      ## c6b
        movhpd 8(%esi,%eax,8),%xmm6     ## c6a c12a 
        movhpd 8(%esi,%ebx,8),%xmm7     ## c6b c12b 
        movapd %xmm6,%xmm4
        unpcklpd %xmm7,%xmm4
        unpckhpd %xmm7,%xmm6

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movapd %xmm4,nb230_c6(%esp)
        movapd %xmm6,nb230_c12(%esp)

        movl nb230_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move two coordinates to xmm0-xmm2    
        movlpd (%esi,%eax,8),%xmm0
        movlpd 8(%esi,%eax,8),%xmm1
        movlpd 16(%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm0
        movhpd 8(%esi,%ebx,8),%xmm1
        movhpd 16(%esi,%ebx,8),%xmm2

        ## move ix-iz to xmm4-xmm6 
        movapd nb230_ix(%esp),%xmm4
        movapd nb230_iy(%esp),%xmm5
        movapd nb230_iz(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb230_dx(%esp)
        movapd %xmm5,nb230_dy(%esp)
        movapd %xmm6,nb230_dz(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        ## rsq in xmm4 

        cvtpd2ps %xmm4,%xmm5
        rsqrtps %xmm5,%xmm5
        cvtps2pd %xmm5,%xmm2    ## lu in low xmm2 

        movapd nb230_krf(%esp),%xmm7
        ## lookup seed in xmm2 
        movapd %xmm2,%xmm5      ## copy of lu 
        mulpd %xmm2,%xmm2       ## lu*lu 
        movapd nb230_three(%esp),%xmm1
        mulpd %xmm4,%xmm7       ## krsq 
        mulpd %xmm4,%xmm2       ## rsq*lu*lu                    
        movapd nb230_half(%esp),%xmm0
        subpd %xmm2,%xmm1       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm1
        mulpd %xmm0,%xmm1       ## xmm0=iter1 of rinv (new lu) 

        movapd %xmm1,%xmm5      ## copy of lu 
        mulpd %xmm1,%xmm1       ## lu*lu 
        movapd nb230_three(%esp),%xmm2
        mulpd %xmm4,%xmm1       ## rsq*lu*lu                    
        movapd nb230_half(%esp),%xmm0
        subpd %xmm1,%xmm2       ## 30-rsq*lu*lu 
        mulpd %xmm5,%xmm2
        mulpd %xmm2,%xmm0       ## xmm0=rinv 
        movapd %xmm0,%xmm6
        addpd  %xmm7,%xmm6      ## xmm6=rinv+ krsq 
        movapd %xmm4,%xmm1
        subpd  nb230_crf(%esp),%xmm6
        mulpd  %xmm3,%xmm6
        mulpd  nb230_two(%esp),%xmm7
        movapd %xmm0,%xmm1
        subpd  %xmm7,%xmm1  ## rinv-2*krsq
        mulpd  %xmm0,%xmm1  ## (rinv-2*krsq)*rinv
        mulpd  %xmm3,%xmm1  ## qq*(rinv-2*krsq)*rinv

        movapd %xmm1,nb230_fstmp(%esp)

        addpd  nb230_vctot(%esp),%xmm6
        movapd %xmm6,nb230_vctot(%esp)

        ## LJ table interaction. xmm0=rinv, xmm4=rsq

        mulpd %xmm0,%xmm4       ## xmm4=r 
        mulpd nb230_tsc(%esp),%xmm4

        cvttpd2pi %xmm4,%mm6    ## mm6 = lu idx