nb_kernel132_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,944 行 · 第 1/5 页

##
## $Id: nb_kernel132_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel132_ia32_sse2
.globl _nb_kernel132_ia32_sse2
nb_kernel132_ia32_sse2: 
_nb_kernel132_ia32_sse2:        
.set nb132_p_nri, 8
.set nb132_iinr, 12
.set nb132_jindex, 16
.set nb132_jjnr, 20
.set nb132_shift, 24
.set nb132_shiftvec, 28
.set nb132_fshift, 32
.set nb132_gid, 36
.set nb132_pos, 40
.set nb132_faction, 44
.set nb132_charge, 48
.set nb132_p_facel, 52
.set nb132_argkrf, 56
.set nb132_argcrf, 60
.set nb132_Vc, 64
.set nb132_type, 68
.set nb132_p_ntype, 72
.set nb132_vdwparam, 76
.set nb132_Vvdw, 80
.set nb132_p_tabscale, 84
.set nb132_VFtab, 88
.set nb132_invsqrta, 92
.set nb132_dvda, 96
.set nb132_p_gbtabscale, 100
.set nb132_GBtab, 104
.set nb132_p_nthreads, 108
.set nb132_count, 112
.set nb132_mtx, 116
.set nb132_outeriter, 120
.set nb132_inneriter, 124
.set nb132_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb132_ixO, 0
.set nb132_iyO, 16
.set nb132_izO, 32
.set nb132_ixH1, 48
.set nb132_iyH1, 64
.set nb132_izH1, 80
.set nb132_ixH2, 96
.set nb132_iyH2, 112
.set nb132_izH2, 128
.set nb132_jxO, 144
.set nb132_jyO, 160
.set nb132_jzO, 176
.set nb132_jxH1, 192
.set nb132_jyH1, 208
.set nb132_jzH1, 224
.set nb132_jxH2, 240
.set nb132_jyH2, 256
.set nb132_jzH2, 272
.set nb132_dxOO, 288
.set nb132_dyOO, 304
.set nb132_dzOO, 320
.set nb132_dxOH1, 336
.set nb132_dyOH1, 352
.set nb132_dzOH1, 368
.set nb132_dxOH2, 384
.set nb132_dyOH2, 400
.set nb132_dzOH2, 416
.set nb132_dxH1O, 432
.set nb132_dyH1O, 448
.set nb132_dzH1O, 464
.set nb132_dxH1H1, 480
.set nb132_dyH1H1, 496
.set nb132_dzH1H1, 512
.set nb132_dxH1H2, 528
.set nb132_dyH1H2, 544
.set nb132_dzH1H2, 560
.set nb132_dxH2O, 576
.set nb132_dyH2O, 592
.set nb132_dzH2O, 608
.set nb132_dxH2H1, 624
.set nb132_dyH2H1, 640
.set nb132_dzH2H1, 656
.set nb132_dxH2H2, 672
.set nb132_dyH2H2, 688
.set nb132_dzH2H2, 704
.set nb132_qqOO, 720
.set nb132_qqOH, 736
.set nb132_qqHH, 752
.set nb132_c6, 768
.set nb132_c12, 784
.set nb132_tsc, 800
.set nb132_fstmp, 816
.set nb132_vctot, 832
.set nb132_Vvdwtot, 848
.set nb132_fixO, 864
.set nb132_fiyO, 880
.set nb132_fizO, 896
.set nb132_fixH1, 912
.set nb132_fiyH1, 928
.set nb132_fizH1, 944
.set nb132_fixH2, 960
.set nb132_fiyH2, 976
.set nb132_fizH2, 992
.set nb132_fjxO, 1008
.set nb132_fjyO, 1024
.set nb132_fjzO, 1040
.set nb132_fjxH1, 1056
.set nb132_fjyH1, 1072
.set nb132_fjzH1, 1088
.set nb132_fjxH2, 1104
.set nb132_fjyH2, 1120
.set nb132_fjzH2, 1136
.set nb132_half, 1152
.set nb132_three, 1168
.set nb132_rsqOO, 1184
.set nb132_rsqOH1, 1200
.set nb132_rsqOH2, 1216
.set nb132_rsqH1O, 1232
.set nb132_rsqH1H1, 1248
.set nb132_rsqH1H2, 1264
.set nb132_rsqH2O, 1280
.set nb132_rsqH2H1, 1296
.set nb132_rsqH2H2, 1312
.set nb132_rinvOO, 1328
.set nb132_rinvOH1, 1344
.set nb132_rinvOH2, 1360
.set nb132_rinvH1O, 1376
.set nb132_rinvH1H1, 1392
.set nb132_rinvH1H2, 1408
.set nb132_rinvH2O, 1424
.set nb132_rinvH2H1, 1440
.set nb132_rinvH2H2, 1456
.set nb132_two, 1472
.set nb132_is3, 1520
.set nb132_ii3, 1524
.set nb132_innerjjnr, 1528
.set nb132_innerk, 1532
.set nb132_n, 1536
.set nb132_nn1, 1540
.set nb132_nri, 1544
.set nb132_nouter, 1548
.set nb132_ninner, 1552
.set nb132_salign, 1556
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $1560,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb132_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb132_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb132_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb132_nouter(%esp)
        movl %eax,nb132_ninner(%esp)

        movl nb132_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb132_tsc(%esp)

        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb132_half(%esp)
        movl %ebx,nb132_half+4(%esp)
        movsd nb132_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb132_half(%esp)
        movapd %xmm2,nb132_two(%esp)
        movapd %xmm3,nb132_three(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb132_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb132_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb132_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb132_qqOO(%esp)
        movapd %xmm4,nb132_qqOH(%esp)
        movapd %xmm5,nb132_qqHH(%esp)

        xorpd %xmm0,%xmm0
        movl  nb132_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb132_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb132_vdwparam(%ebp),%eax
        movlpd (%eax,%edx,8),%xmm0
        movhpd 8(%eax,%edx,8),%xmm0
        movhlps %xmm0,%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb132_c6(%esp)
        movapd %xmm1,nb132_c12(%esp)

_nb_kernel132_ia32_sse2.nb132_threadloop: 
        movl  nb132_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel132_ia32_sse2.nb132_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel132_ia32_sse2.nb132_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb132_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb132_n(%esp)
        movl %ebx,nb132_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel132_ia32_sse2.nb132_outerstart
        jmp _nb_kernel132_ia32_sse2.nb132_end

_nb_kernel132_ia32_sse2.nb132_outerstart: 
        ## ebx contains number of outer iterations
        addl nb132_nouter(%esp),%ebx
        movl %ebx,nb132_nouter(%esp)

_nb_kernel132_ia32_sse2.nb132_outer: 
        movl  nb132_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx                ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb132_is3(%esp)      ## store is3 

        movl  nb132_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movlpd (%eax,%ebx,8),%xmm0
        movlpd 8(%eax,%ebx,8),%xmm1
        movlpd 16(%eax,%ebx,8),%xmm2

        movl  nb132_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx            ## ebx =ii 

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb132_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb132_ii3(%esp)

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        addsd (%eax,%ebx,8),%xmm3
        addsd 8(%eax,%ebx,8),%xmm4
        addsd 16(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb132_ixO(%esp)
        movapd %xmm4,nb132_iyO(%esp)
        movapd %xmm5,nb132_izO(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm0
        addsd 32(%eax,%ebx,8),%xmm1
        addsd 40(%eax,%ebx,8),%xmm2
        addsd 48(%eax,%ebx,8),%xmm3
        addsd 56(%eax,%ebx,8),%xmm4
        addsd 64(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb132_ixH1(%esp)
        movapd %xmm1,nb132_iyH1(%esp)
        movapd %xmm2,nb132_izH1(%esp)
        movapd %xmm3,nb132_ixH2(%esp)
        movapd %xmm4,nb132_iyH2(%esp)
        movapd %xmm5,nb132_izH2(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb132_vctot(%esp)
        movapd %xmm4,nb132_Vvdwtot(%esp)
        movapd %xmm4,nb132_fixO(%esp)
        movapd %xmm4,nb132_fiyO(%esp)
        movapd %xmm4,nb132_fizO(%esp)
        movapd %xmm4,nb132_fixH1(%esp)
        movapd %xmm4,nb132_fiyH1(%esp)
        movapd %xmm4,nb132_fizH1(%esp)
        movapd %xmm4,nb132_fixH2(%esp)
        movapd %xmm4,nb132_fiyH2(%esp)
        movapd %xmm4,nb132_fizH2(%esp)

        movl  nb132_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb132_pos(%ebp),%esi
        movl  nb132_faction(%ebp),%edi
        movl  nb132_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb132_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb132_ninner(%esp),%ecx
        movl  %ecx,nb132_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb132_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel132_ia32_sse2.nb132_unroll_loop
        jmp   _nb_kernel132_ia32_sse2.nb132_checksingle
_nb_kernel132_ia32_sse2.nb132_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb132_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb132_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 

        movl nb132_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move j coordinates to local temp variables 
        movlpd (%esi,%eax,8),%xmm2
        movlpd 8(%esi,%eax,8),%xmm3
        movlpd 16(%esi,%eax,8),%xmm4
        movlpd 24(%esi,%eax,8),%xmm5
        movlpd 32(%esi,%eax,8),%xmm6
        movlpd 40(%esi,%eax,8),%xmm7
        movhpd (%esi,%ebx,8),%xmm2