nb_kernel400_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,289 行 · 第 1/3 页

	movsd  [esi + ecx*8], xmm6
	movsd  [esi + edx*8], xmm7
	
	xorpd  xmm4, xmm4

	mulpd xmm3, xmm0
	subpd  xmm4, xmm3

	movapd xmm0, [esp + nb400_dx]
	movapd xmm1, [esp + nb400_dy]
	movapd xmm2, [esp + nb400_dz]

	movd eax, mm0	
	movd ebx, mm1

	mov    edi, [ebp + nb400_faction]
	mulpd  xmm0, xmm4
	mulpd  xmm1, xmm4
	mulpd  xmm2, xmm4
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movapd xmm3, [esp + nb400_fix]
	movapd xmm4, [esp + nb400_fiy]
	movapd xmm5, [esp + nb400_fiz]
	addpd  xmm3, xmm0
	addpd  xmm4, xmm1
	addpd  xmm5, xmm2
	movapd [esp + nb400_fix], xmm3
	movapd [esp + nb400_fiy], xmm4
	movapd [esp + nb400_fiz], xmm5
	;# the fj's - start by accumulating forces from memory 
	movlpd xmm3, [edi + eax*8]
	movlpd xmm4, [edi + eax*8 + 8]
	movlpd xmm5, [edi + eax*8 + 16]
	movhpd xmm3, [edi + ebx*8]
	movhpd xmm4, [edi + ebx*8 + 8]
	movhpd xmm5, [edi + ebx*8 + 16]
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2
	movlpd [edi + eax*8], xmm3
	movlpd [edi + eax*8 + 8], xmm4
	movlpd [edi + eax*8 + 16], xmm5
	movhpd [edi + ebx*8], xmm3
	movhpd [edi + ebx*8 + 8], xmm4
	movhpd [edi + ebx*8 + 16], xmm5
		
	;# should we do one more iteration? 
	sub dword ptr [esp + nb400_innerk],  2
	jl    .nb400_checksingle
	jmp   .nb400_unroll_loop
.nb400_checksingle:
	mov   edx, [esp + nb400_innerk]
	and   edx, 1
	jnz    .nb400_dosingle
	jmp    .nb400_updateouterdata
.nb400_dosingle:
	mov esi, [ebp + nb400_charge]
	mov edx, [ebp + nb400_invsqrta]
	mov edi, [ebp + nb400_pos]
	mov   ecx, [esp + nb400_innerjjnr]
	mov   eax, [ecx]	
	xorpd  xmm6, xmm6
	movapd xmm7, xmm6
	movsd  xmm7, [edx + eax*8]
	movlpd xmm6, [esi + eax*8]	;# xmm6(0) has the charge
	mulsd  xmm7, [esp + nb400_isai]
	movapd [esp + nb400_isaprod], xmm7
	movapd xmm1, xmm7
	mulpd xmm1, [esp + nb400_gbtsc]
	movapd [esp + nb400_gbscale], xmm1
	
	mulsd  xmm7, [esp + nb400_iq]
	mulsd  xmm6, xmm7
	movapd [esp + nb400_qq], xmm6

	movd  mm2, eax
	lea   eax, [eax + eax*2]
	
	;# move coordinates to xmm0-xmm2 
	movlpd xmm0, [edi + eax*8]
	movlpd xmm1, [edi + eax*8 + 8]
	movlpd xmm2, [edi + eax*8 + 16]

	;# move nb400_ix-iz to xmm4-xmm6 
	movapd xmm4, [esp + nb400_ix]
	movapd xmm5, [esp + nb400_iy]
	movapd xmm6, [esp + nb400_iz]

	;# calc dr 
	subsd xmm4, xmm0
	subsd xmm5, xmm1
	subsd xmm6, xmm2

	;# store dr 
	movapd [esp + nb400_dx], xmm4
	movapd [esp + nb400_dy], xmm5
	movapd [esp + nb400_dz], xmm6
	;# square it 
	mulsd xmm4,xmm4
	mulsd xmm5,xmm5
	mulsd xmm6,xmm6
	addsd xmm4, xmm5
	addsd xmm4, xmm6
	;# rsq in xmm4 

	cvtsd2ss xmm5, xmm4	
	rsqrtss xmm5, xmm5
	cvtss2sd xmm2, xmm5	;# lu in low xmm2 

	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulsd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [esp + nb400_three]
	mulsd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb400_half]
	subsd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulsd xmm1, xmm5	
	mulsd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulsd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [esp + nb400_three]
	mulsd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb400_half]
	subsd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulsd xmm2, xmm5	
	mulsd xmm0, xmm2	;# xmm0=iter2 of rinv (new lu) 
	
	mulsd xmm4, xmm0	;# xmm4=r 
	movapd [esp + nb400_r], xmm4
	mulsd xmm4, [esp + nb400_gbscale]
	
	movd mm0, eax	

	cvttsd2si eax, xmm4	;# mm6 = lu idx 
	cvtsi2sd xmm5, eax
	subsd xmm4, xmm5
	movapd xmm1, xmm4	;# xmm1=eps 
	movapd xmm2, xmm1	
	mulsd  xmm2, xmm2	;# xmm2=eps2 
	
	shl eax, 2		;# idx *= 4 
	
	mov  esi, [ebp + nb400_GBtab]

	;# Coulomb 
	movapd xmm4, [esi + eax*8]	;# Y1 F1 
	xorpd xmm3, xmm3
	movapd xmm5, xmm4
	unpcklpd xmm4, xmm3	;# Y1  
	unpckhpd xmm5, xmm3	;# F1  

	movapd xmm6, [esi + eax*8 + 16]	;# G1 H1 
	xorpd xmm3, xmm3
	movapd xmm7, xmm6
	unpcklpd xmm6, xmm3	;# G1  
	unpckhpd xmm7, xmm3	;# H1  	
	;# table ready in xmm4-xmm7 

	mulsd  xmm6, xmm1	;# xmm6=Geps 
	mulsd  xmm7, xmm2	;# xmm7=Heps2 
	addsd  xmm5, xmm6
	addsd  xmm5, xmm7	;# xmm5=Fp 	
	mulsd  xmm7, [esp + nb400_two]	;# two*Heps2 
	movapd xmm3, [esp + nb400_qq]
	addsd  xmm7, xmm6
	addsd  xmm7, xmm5 ;# xmm7=FF 
	mulsd  xmm5, xmm1 ;# xmm5=eps*Fp 
	addsd  xmm5, xmm4 ;# xmm5=VV 
	mulsd  xmm5, xmm3 ;# vcoul=qq*VV  
	mulsd  xmm3, xmm7 ;# fijC=FF*qq
	;# get jnr from regs
	movd ebx, mm2
	mov esi, [ebp + nb400_dvda]
	
	;# Calculate dVda
	mulsd xmm3, [esp + nb400_gbscale]
	movsd xmm6, xmm3
	mulsd  xmm6, [esp + nb400_r]
	addsd  xmm6, xmm5
	addsd  xmm5, [esp + nb400_vctot]
	movsd [esp + nb400_vctot], xmm5 

	;# xmm6=(vcoul+fijC*r)
	subpd  xmm7, xmm6
	movsd xmm6, xmm7
	
	;# update dvdasum
	addsd  xmm7, [esp + nb400_dvdasum]
	movsd [esp + nb400_dvdasum], xmm7 

	;# update j atoms dvdaj
	addsd  xmm6, [esi + ebx*8]
	movsd  [esi + ebx*8], xmm6
	
	xorpd xmm4, xmm4
	movd eax, mm0

	mulsd xmm3, xmm0
	subsd  xmm4, xmm3
	mov    edi, [ebp + nb400_faction]

	movsd xmm0, [esp + nb400_dx]
	movsd xmm1, [esp + nb400_dy]
	movsd xmm2, [esp + nb400_dz]

	mulsd  xmm0, xmm4
	mulsd  xmm1, xmm4
	mulsd  xmm2, xmm4
	;# xmm0-xmm2 contains tx-tz (partial force) 
	;# now update f_i 
	movsd xmm3, [esp + nb400_fix]
	movsd xmm4, [esp + nb400_fiy]
	movsd xmm5, [esp + nb400_fiz]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movlpd [esp + nb400_fix], xmm3
	movlpd [esp + nb400_fiy], xmm4
	movlpd [esp + nb400_fiz], xmm5
	;# update fj 
	movlpd xmm3, [edi + eax*8]
	movlpd xmm4, [edi + eax*8 + 8]
	movlpd xmm5, [edi + eax*8 + 16]
	subsd xmm3, xmm0
	subsd xmm4, xmm1
	subsd xmm5, xmm2
	movlpd [edi + eax*8], xmm3
	movlpd [edi + eax*8 + 8], xmm4
	movlpd [edi + eax*8 + 16], xmm5

.nb400_updateouterdata:
	mov   ecx, [esp + nb400_ii3]
	mov   edi, [ebp + nb400_faction]
	mov   esi, [ebp + nb400_fshift]
	mov   edx, [esp + nb400_is3]

	;# accumulate i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb400_fix]
	movapd xmm1, [esp + nb400_fiy]
	movapd xmm2, [esp + nb400_fiz]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8]
	movsd  xmm4, [edi + ecx*8 + 8]
	movsd  xmm5, [edi + ecx*8 + 16]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8],     xmm3
	movsd  [edi + ecx*8 + 8], xmm4
	movsd  [edi + ecx*8 + 16], xmm5

	;# increment fshift force  
	movsd  xmm3, [esi + edx*8]
	movsd  xmm4, [esi + edx*8 + 8]
	movsd  xmm5, [esi + edx*8 + 16]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [esi + edx*8],     xmm3
	movsd  [esi + edx*8 + 8], xmm4
	movsd  [esi + edx*8 + 16], xmm5

	;# get n from stack
	mov esi, [esp + nb400_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb400_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [esp + nb400_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb400_Vc]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
	;# accumulate dVda and update it 
	movapd xmm7, [esp + nb400_dvdasum]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 
	
	mov edx, [esp + nb400_ii]
	mov eax, [ebp + nb400_dvda]
	addsd xmm7, [eax + edx*8]
	movsd [eax + edx*8], xmm7
	
        ;# finish if last 
        mov ecx, [esp + nb400_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb400_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb400_n], esi
        jmp .nb400_outer
.nb400_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb400_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb400_end
        ;# non-zero, do one more workunit
        jmp   .nb400_threadloop
.nb400_end:
	emms

	mov eax, [esp + nb400_nouter]
	mov ebx, [esp + nb400_ninner]
	mov ecx, [ebp + nb400_outeriter]
	mov edx, [ebp + nb400_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb400_salign]
	add esp, eax
	add esp, 388
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret






.globl nb_kernel400nf_ia32_sse2
.globl _nb_kernel400nf_ia32_sse2
nb_kernel400nf_ia32_sse2:	
_nb_kernel400nf_ia32_sse2:	
.equiv          nb400nf_p_nri,          8
.equiv          nb400nf_iinr,           12
.equiv          nb400nf_jindex,         16
.equiv          nb400nf_jjnr,           20
.equiv          nb400nf_shift,          24
.equiv          nb400nf_shiftvec,       28
.equiv          nb400nf_fshift,         32
.equiv          nb400nf_gid,            36
.equiv          nb400nf_pos,            40
.equiv          nb400nf_faction,        44
.equiv          nb400nf_charge,         48
.equiv          nb400nf_p_facel,        52
.equiv          nb400nf_argkrf,         56
.equiv          nb400nf_argcrf,         60
.equiv          nb400nf_Vc,             64
.equiv          nb400nf_type,           68
.equiv          nb400nf_p_ntype,        72
.equiv          nb400nf_vdwparam,       76
.equiv          nb400nf_Vvdw,           80
.equiv          nb400nf_p_tabscale,     84
.equiv          nb400nf_VFtab,          88
.equiv          nb400nf_invsqrta,       92
.equiv          nb400nf_dvda,           96
.equiv          nb400nf_p_gbtabscale,   100
.equiv          nb400nf_GBtab,          104
.equiv          nb400nf_p_nthreads,     108
.equiv          nb400nf_count,          112
.equiv          nb400nf_mtx,            116
.equiv          nb400nf_outeriter,      120
.equiv          nb400nf_inneriter,      124
.equiv          nb400nf_work,           128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb400nf_ix,             0
.equiv          nb400nf_iy,             16
.equiv          nb400nf_iz,             32
.equiv          nb400nf_iq,             48
.equiv          nb400nf_gbtsc,          64
.equiv          nb400nf_qq,             80
.equiv          nb400nf_vctot,          96
.equiv          nb400nf_half,           112
.equiv          nb400nf_three,          128
.equiv          nb400nf_isai,           144
.equiv          nb400nf_isaprod,        160
.equiv          nb400nf_gbscale,        176
.equiv          nb400nf_is3,            192
.equiv          nb400nf_ii3,            196
.equiv          nb400nf_innerjjnr,      200
.equiv          nb400nf_innerk,         204
.equiv          nb400nf_n,              208
.equiv          nb400nf_nn1,            212
.equiv          nb400nf_nri,            216
.equiv          nb400nf_facel,          224   ;# uses 8 bytes
.equiv          nb400nf_nouter,         232
.equiv          nb400nf_ninner,         236
.equiv          nb400nf_salign,         240
	push ebp
	mov ebp,esp	
	push eax
	push ebx
	push ecx
	push edx
	push esi
	push edi
	sub esp, 244		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb400nf_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb400nf_p_nri]
	mov esi, [ebp + nb400nf_p_facel]
	mov ecx, [ecx]
	movsd xmm7, [esi]
	mov [esp + nb400nf_nri], ecx
	movsd [esp + nb400nf_facel], xmm7