nb_kernel301_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,022 行 · 第 1/5 页

##
## $Id: nb_kernel301_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##


.globl nb_kernel301_ia32_sse2
.globl _nb_kernel301_ia32_sse2
nb_kernel301_ia32_sse2: 
_nb_kernel301_ia32_sse2:        
.set nb301_p_nri, 8
.set nb301_iinr, 12
.set nb301_jindex, 16
.set nb301_jjnr, 20
.set nb301_shift, 24
.set nb301_shiftvec, 28
.set nb301_fshift, 32
.set nb301_gid, 36
.set nb301_pos, 40
.set nb301_faction, 44
.set nb301_charge, 48
.set nb301_p_facel, 52
.set nb301_argkrf, 56
.set nb301_argcrf, 60
.set nb301_Vc, 64
.set nb301_type, 68
.set nb301_p_ntype, 72
.set nb301_vdwparam, 76
.set nb301_Vvdw, 80
.set nb301_p_tabscale, 84
.set nb301_VFtab, 88
.set nb301_invsqrta, 92
.set nb301_dvda, 96
.set nb301_p_gbtabscale, 100
.set nb301_GBtab, 104
.set nb301_p_nthreads, 108
.set nb301_count, 112
.set nb301_mtx, 116
.set nb301_outeriter, 120
.set nb301_inneriter, 124
.set nb301_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb301_ixO, 0
.set nb301_iyO, 16
.set nb301_izO, 32
.set nb301_ixH1, 48
.set nb301_iyH1, 64
.set nb301_izH1, 80
.set nb301_ixH2, 96
.set nb301_iyH2, 112
.set nb301_izH2, 128
.set nb301_iqO, 144
.set nb301_iqH, 160
.set nb301_dxO, 176
.set nb301_dyO, 192
.set nb301_dzO, 208
.set nb301_dxH1, 224
.set nb301_dyH1, 240
.set nb301_dzH1, 256
.set nb301_dxH2, 272
.set nb301_dyH2, 288
.set nb301_dzH2, 304
.set nb301_qqO, 320
.set nb301_qqH, 336
.set nb301_rinvO, 352
.set nb301_rinvH1, 368
.set nb301_rinvH2, 384
.set nb301_rO, 400
.set nb301_rH1, 416
.set nb301_rH2, 432
.set nb301_tsc, 448
.set nb301_two, 464
.set nb301_vctot, 480
.set nb301_fixO, 496
.set nb301_fiyO, 512
.set nb301_fizO, 528
.set nb301_fixH1, 544
.set nb301_fiyH1, 560
.set nb301_fizH1, 576
.set nb301_fixH2, 592
.set nb301_fiyH2, 608
.set nb301_fizH2, 624
.set nb301_fjx, 640
.set nb301_fjy, 656
.set nb301_fjz, 672
.set nb301_half, 688
.set nb301_three, 704
.set nb301_is3, 720
.set nb301_ii3, 724
.set nb301_innerjjnr, 728
.set nb301_innerk, 732
.set nb301_n, 736
.set nb301_nn1, 740
.set nb301_nri, 744
.set nb301_nouter, 748
.set nb301_ninner, 752
.set nb301_salign, 756
        pushl %ebp
        movl %esp,%ebp
    pushl %eax
    pushl %ebx
    pushl %ecx
    pushl %edx
        pushl %esi
        pushl %edi
        subl $760,%esp          ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb301_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb301_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb301_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb301_nouter(%esp)
        movl %eax,nb301_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb301_half(%esp)
        movl %ebx,nb301_half+4(%esp)
        movsd nb301_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm1,nb301_half(%esp)
        movapd %xmm2,nb301_two(%esp)
        movapd %xmm3,nb301_three(%esp)

        movl nb301_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3
        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb301_tsc(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb301_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb301_charge(%ebp),%edx
        movsd (%edx,%ebx,8),%xmm3
        movsd 8(%edx,%ebx,8),%xmm4
        movl nb301_p_facel(%ebp),%esi
        movsd (%esi),%xmm5
        mulsd  %xmm5,%xmm3
        mulsd  %xmm5,%xmm4

        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        movapd %xmm3,nb301_iqO(%esp)
        movapd %xmm4,nb301_iqH(%esp)

_nb_kernel301_ia32_sse2.nb301_threadloop: 
        movl  nb301_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel301_ia32_sse2.nb301_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel301_ia32_sse2.nb301_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb301_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb301_n(%esp)
        movl %ebx,nb301_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel301_ia32_sse2.nb301_outerstart
        jmp _nb_kernel301_ia32_sse2.nb301_end

_nb_kernel301_ia32_sse2.nb301_outerstart: 
        ## ebx contains number of outer iterations
        addl nb301_nouter(%esp),%ebx
        movl %ebx,nb301_nouter(%esp)

_nb_kernel301_ia32_sse2.nb301_outer: 
        movl  nb301_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb301_is3(%esp)      ## store is3 

        movl  nb301_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb301_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb301_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb301_ii3(%esp)

        addsd (%eax,%ebx,8),%xmm3
        addsd 8(%eax,%ebx,8),%xmm4
        addsd 16(%eax,%ebx,8),%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb301_ixO(%esp)
        movapd %xmm4,nb301_iyO(%esp)
        movapd %xmm5,nb301_izO(%esp)

        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 24(%eax,%ebx,8),%xmm0
        addsd 32(%eax,%ebx,8),%xmm1
        addsd 40(%eax,%ebx,8),%xmm2
        addsd 48(%eax,%ebx,8),%xmm3
        addsd 56(%eax,%ebx,8),%xmm4
        addsd 64(%eax,%ebx,8),%xmm5

        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm0,nb301_ixH1(%esp)
        movapd %xmm1,nb301_iyH1(%esp)
        movapd %xmm2,nb301_izH1(%esp)
        movapd %xmm3,nb301_ixH2(%esp)
        movapd %xmm4,nb301_iyH2(%esp)
        movapd %xmm5,nb301_izH2(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb301_vctot(%esp)
        movapd %xmm4,nb301_fixO(%esp)
        movapd %xmm4,nb301_fiyO(%esp)
        movapd %xmm4,nb301_fizO(%esp)
        movapd %xmm4,nb301_fixH1(%esp)
        movapd %xmm4,nb301_fiyH1(%esp)
        movapd %xmm4,nb301_fizH1(%esp)
        movapd %xmm4,nb301_fixH2(%esp)
        movapd %xmm4,nb301_fiyH2(%esp)
        movapd %xmm4,nb301_fizH2(%esp)

        movl  nb301_jindex(%ebp),%eax
        movl  (%eax,%esi,4),%ecx             ## jindex[n] 
        movl  4(%eax,%esi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movl  nb301_pos(%ebp),%esi
        movl  nb301_faction(%ebp),%edi
        movl  nb301_jjnr(%ebp),%eax
        shll  $2,%ecx
        addl  %ecx,%eax
        movl  %eax,nb301_innerjjnr(%esp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $2,%edx
        addl  nb301_ninner(%esp),%ecx
        movl  %ecx,nb301_ninner(%esp)
        addl  $0,%edx
        movl  %edx,nb301_innerk(%esp)      ## number of innerloop atoms 
        jge   _nb_kernel301_ia32_sse2.nb301_unroll_loop
        jmp   _nb_kernel301_ia32_sse2.nb301_checksingle
_nb_kernel301_ia32_sse2.nb301_unroll_loop: 
        ## twice unrolled innerloop here 
        movl  nb301_innerjjnr(%esp),%edx       ## pointer to jjnr[k] 
        movl  (%edx),%eax
        movl  4(%edx),%ebx

        addl $8,nb301_innerjjnr(%esp)                   ## advance pointer (unrolled 2) 
        movl nb301_charge(%ebp),%esi     ## base of charge[] 

        movlpd (%esi,%eax,8),%xmm3
        movhpd (%esi,%ebx,8),%xmm3
        movapd %xmm3,%xmm4
        mulpd  nb301_iqO(%esp),%xmm3
        mulpd  nb301_iqH(%esp),%xmm4

        movapd  %xmm3,nb301_qqO(%esp)
        movapd  %xmm4,nb301_qqH(%esp)

        movl nb301_pos(%ebp),%esi        ## base of pos[] 

        leal  (%eax,%eax,2),%eax     ## replace jnr with j3 
        leal  (%ebx,%ebx,2),%ebx

        ## move two coordinates to xmm0-xmm2    
        movlpd (%esi,%eax,8),%xmm0
        movlpd 8(%esi,%eax,8),%xmm1
        movlpd 16(%esi,%eax,8),%xmm2
        movhpd (%esi,%ebx,8),%xmm0
        movhpd 8(%esi,%ebx,8),%xmm1
        movhpd 16(%esi,%ebx,8),%xmm2

        ## move ixO-izO to xmm4-xmm6 
        movapd nb301_ixO(%esp),%xmm4
        movapd nb301_iyO(%esp),%xmm5
        movapd nb301_izO(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb301_dxO(%esp)
        movapd %xmm5,nb301_dyO(%esp)
        movapd %xmm6,nb301_dzO(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm4
        addpd %xmm6,%xmm4
        movapd %xmm4,%xmm7
        ## rsqO in xmm7 

        ## move ixH1-izH1 to xmm4-xmm6 
        movapd nb301_ixH1(%esp),%xmm4
        movapd nb301_iyH1(%esp),%xmm5
        movapd nb301_izH1(%esp),%xmm6

        ## calc dr 
        subpd %xmm0,%xmm4
        subpd %xmm1,%xmm5
        subpd %xmm2,%xmm6

        ## store dr 
        movapd %xmm4,nb301_dxH1(%esp)
        movapd %xmm5,nb301_dyH1(%esp)
        movapd %xmm6,nb301_dzH1(%esp)
        ## square it 
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        mulpd %xmm6,%xmm6
        addpd %xmm5,%xmm6
        addpd %xmm4,%xmm6
        ## rsqH1 in xmm6 

        ## move ixH2-izH2 to xmm3-xmm5  
        movapd nb301_ixH2(%esp),%xmm3
        movapd nb301_iyH2(%esp),%xmm4
        movapd nb301_izH2(%esp),%xmm5

        ## calc dr 
        subpd %xmm0,%xmm3
        subpd %xmm1,%xmm4
        subpd %xmm2,%xmm5

        ## store dr 
        movapd %xmm3,nb301_dxH2(%esp)
        movapd %xmm4,nb301_dyH2(%esp)
        movapd %xmm5,nb301_dzH2(%esp)
        ## square it 
        mulpd %xmm3,%xmm3
        mulpd %xmm4,%xmm4
        mulpd %xmm5,%xmm5
        addpd %xmm4,%xmm5
        addpd %xmm3,%xmm5
        ## rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7 

        ## start with rsqO - put seed in xmm2 
        cvtpd2ps %xmm7,%xmm2
        rsqrtps %xmm2,%xmm2
        cvtps2pd %xmm2,%xmm2

        movapd  %xmm2,%xmm3
        mulpd   %xmm2,%xmm2
        movapd  nb301_three(%esp),%xmm4
        mulpd   %xmm7,%xmm2     ## rsq*lu*lu 
        subpd   %xmm2,%xmm4     ## 30-rsq*lu*lu