nb_kernel231_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,366 行 · 第 1/5 页

;#
;# $Id: nb_kernel231_ia32_sse2.intel_syntax.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel231_ia32_sse2
.globl _nb_kernel231_ia32_sse2
nb_kernel231_ia32_sse2:	
_nb_kernel231_ia32_sse2:	
.equiv          nb231_p_nri,            8
.equiv          nb231_iinr,             12
.equiv          nb231_jindex,           16
.equiv          nb231_jjnr,             20
.equiv          nb231_shift,            24
.equiv          nb231_shiftvec,         28
.equiv          nb231_fshift,           32
.equiv          nb231_gid,              36
.equiv          nb231_pos,              40
.equiv          nb231_faction,          44
.equiv          nb231_charge,           48
.equiv          nb231_p_facel,          52
.equiv          nb231_argkrf,           56
.equiv          nb231_argcrf,           60
.equiv          nb231_Vc,               64
.equiv          nb231_type,             68
.equiv          nb231_p_ntype,          72
.equiv          nb231_vdwparam,         76
.equiv          nb231_Vvdw,             80
.equiv          nb231_p_tabscale,       84
.equiv          nb231_VFtab,            88
.equiv          nb231_invsqrta,         92
.equiv          nb231_dvda,             96
.equiv          nb231_p_gbtabscale,     100
.equiv          nb231_GBtab,            104
.equiv          nb231_p_nthreads,       108
.equiv          nb231_count,            112
.equiv          nb231_mtx,              116
.equiv          nb231_outeriter,        120
.equiv          nb231_inneriter,        124
.equiv          nb231_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb231_ixO,              0
.equiv          nb231_iyO,              16
.equiv          nb231_izO,              32
.equiv          nb231_ixH1,             48
.equiv          nb231_iyH1,             64
.equiv          nb231_izH1,             80
.equiv          nb231_ixH2,             96
.equiv          nb231_iyH2,             112
.equiv          nb231_izH2,             128
.equiv          nb231_iqO,              144
.equiv          nb231_iqH,              160
.equiv          nb231_dxO,              176
.equiv          nb231_dyO,              192
.equiv          nb231_dzO,              208
.equiv          nb231_dxH1,             224
.equiv          nb231_dyH1,             240
.equiv          nb231_dzH1,             256
.equiv          nb231_dxH2,             272
.equiv          nb231_dyH2,             288
.equiv          nb231_dzH2,             304
.equiv          nb231_qqO,              320
.equiv          nb231_qqH,              336
.equiv          nb231_c6,               352
.equiv          nb231_c12,              368
.equiv          nb231_tsc,              384
.equiv          nb231_fstmp,            400
.equiv          nb231_vctot,            416
.equiv          nb231_Vvdwtot,          432
.equiv          nb231_fixO,             448
.equiv          nb231_fiyO,             464
.equiv          nb231_fizO,             480
.equiv          nb231_fixH1,            496
.equiv          nb231_fiyH1,            512
.equiv          nb231_fizH1,            528
.equiv          nb231_fixH2,            544
.equiv          nb231_fiyH2,            560
.equiv          nb231_fizH2,            576
.equiv          nb231_fjx,              592
.equiv          nb231_fjy,              608
.equiv          nb231_fjz,              624
.equiv          nb231_half,             640
.equiv          nb231_three,            656
.equiv          nb231_two,              672
.equiv          nb231_krf,              688
.equiv          nb231_crf,              704
.equiv          nb231_krsqO,            720
.equiv          nb231_krsqH1,           736
.equiv          nb231_krsqH2,           752
.equiv          nb231_rsqO,             768
.equiv          nb231_rinvH1,           784
.equiv          nb231_rinvH2,           800
.equiv          nb231_is3,              816
.equiv          nb231_ii3,              820
.equiv          nb231_ntia,             824
.equiv          nb231_innerjjnr,        828
.equiv          nb231_innerk,           832
.equiv          nb231_n,                836
.equiv          nb231_nn1,              840
.equiv          nb231_nri,              844
.equiv          nb231_nouter,           848
.equiv          nb231_ninner,           852
.equiv          nb231_salign,           856
	push ebp
	mov ebp,esp	
    push eax
    push ebx
    push ecx
    push edx
	push esi
	push edi
	sub esp, 860		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb231_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb231_p_nri]
	mov ecx, [ecx]
	mov [esp + nb231_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb231_nouter], eax
	mov [esp + nb231_ninner], eax

	mov eax, [ebp + nb231_p_tabscale]
	movsd xmm3, [eax]
	shufpd xmm3, xmm3, 0
	movapd [esp + nb231_tsc], xmm3

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb231_half], eax
	mov [esp + nb231_half+4], ebx
	movsd xmm1, [esp + nb231_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb231_half], xmm1
	movapd [esp + nb231_two], xmm2
	movapd [esp + nb231_three], xmm3

	mov esi, [ebp + nb231_argkrf]
	mov edi, [ebp + nb231_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb231_krf], xmm5
	movapd [esp + nb231_crf], xmm6
	
	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb231_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb231_charge]
	movsd xmm3, [edx + ebx*8]	
	movsd xmm4, [edx + ebx*8 + 8]	
	mov esi, [ebp + nb231_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb231_iqO], xmm3
	movapd [esp + nb231_iqH], xmm4
	
	mov   edx, [ebp + nb231_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb231_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb231_ntia], ecx		
.nb231_threadloop:
        mov   esi, [ebp + nb231_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb231_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb231_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb231_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb231_n], eax
        mov [esp + nb231_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb231_outerstart
        jmp .nb231_end

.nb231_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb231_nouter]
	mov [esp + nb231_nouter], ebx

.nb231_outer:
	mov   eax, [ebp + nb231_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb231_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb231_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb231_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb231_pos]    ;# eax = base of pos[]  
	mov   [esp + nb231_ii3], ebx

	addsd xmm3, [eax + ebx*8]
	addsd xmm4, [eax + ebx*8 + 8]
	addsd xmm5, [eax + ebx*8 + 16]		
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb231_ixO], xmm3
	movapd [esp + nb231_iyO], xmm4
	movapd [esp + nb231_izO], xmm5

	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm0, [eax + ebx*8 + 24]
	addsd xmm1, [eax + ebx*8 + 32]
	addsd xmm2, [eax + ebx*8 + 40]		
	addsd xmm3, [eax + ebx*8 + 48]
	addsd xmm4, [eax + ebx*8 + 56]
	addsd xmm5, [eax + ebx*8 + 64]		

	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb231_ixH1], xmm0
	movapd [esp + nb231_iyH1], xmm1
	movapd [esp + nb231_izH1], xmm2
	movapd [esp + nb231_ixH2], xmm3
	movapd [esp + nb231_iyH2], xmm4
	movapd [esp + nb231_izH2], xmm5
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [esp + nb231_vctot], xmm4
	movapd [esp + nb231_Vvdwtot], xmm4
	movapd [esp + nb231_fixO], xmm4
	movapd [esp + nb231_fiyO], xmm4
	movapd [esp + nb231_fizO], xmm4
	movapd [esp + nb231_fixH1], xmm4
	movapd [esp + nb231_fiyH1], xmm4
	movapd [esp + nb231_fizH1], xmm4
	movapd [esp + nb231_fixH2], xmm4
	movapd [esp + nb231_fiyH2], xmm4
	movapd [esp + nb231_fizH2], xmm4
	
	mov   eax, [ebp + nb231_jindex]
	mov   ecx, [eax+esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb231_pos]
	mov   edi, [ebp + nb231_faction]	
	mov   eax, [ebp + nb231_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb231_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb231_ninner]
	mov   [esp + nb231_ninner], ecx
	add   edx, 0
	mov   [esp + nb231_innerk], edx    ;# number of innerloop atoms 
	jge   .nb231_unroll_loop
	jmp   .nb231_checksingle
.nb231_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb231_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb231_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb231_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb231_iqO]
	mulpd  xmm4, [esp + nb231_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx

	movapd  [esp + nb231_qqO], xmm3
	movapd  [esp + nb231_qqH], xmm4
	
	mov esi, [ebp + nb231_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb231_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	mov edi, [esp + nb231_ntia]
	add eax, edi
	add ebx, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movlpd xmm7, [esi + ebx*8]	;# c6b
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	movhpd xmm7, [esi + ebx*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0
	movd  ebx, mm1
	movapd [esp + nb231_c6], xmm4
	movapd [esp + nb231_c12], xmm6
	
	mov esi, [ebp + nb231_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		

	;# move ixO-izO to xmm4-xmm6 
	movapd xmm4, [esp + nb231_ixO]
	movapd xmm5, [esp + nb231_iyO]
	movapd xmm6, [esp + nb231_izO]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb231_dxO], xmm4
	movapd [esp + nb231_dyO], xmm5
	movapd [esp + nb231_dzO], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	movapd xmm7, xmm4
	;# rsqO in xmm7 
	movapd [esp + nb231_rsqO], xmm7
	
	;# move ixH1-izH1 to xmm4-xmm6 
	movapd xmm4, [esp + nb231_ixH1]
	movapd xmm5, [esp + nb231_iyH1]
	movapd xmm6, [esp + nb231_izH1]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb231_dxH1], xmm4
	movapd [esp + nb231_dyH1], xmm5
	movapd [esp + nb231_dzH1], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm6, xmm5
	addpd xmm6, xmm4
	;# rsqH1 in xmm6 

	;# move ixH2-izH2 to xmm3-xmm5  
	movapd xmm3, [esp + nb231_ixH2]
	movapd xmm4, [esp + nb231_iyH2]
	movapd xmm5, [esp + nb231_izH2]

	;# calc dr 
	subpd xmm3, xmm0
	subpd xmm4, xmm1
	subpd xmm5, xmm2

	;# store dr 
	movapd [esp + nb231_dxH2], xmm3
	movapd [esp + nb231_dyH2], xmm4
	movapd [esp + nb231_dzH2], xmm5
	;# square it 
	mulpd xmm3,xmm3
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	addpd xmm5, xmm4
	addpd xmm5, xmm3
	;# rsqH2 in xmm5, rsqH1 in xmm6, rsqO in xmm7