nb_kernel214_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,874 行 · 第 1/5 页

##
## $Id: nb_kernel214_ia32_sse2.s,v 1.1.2.2 2007/11/28 18:35:35 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel214_ia32_sse2
.globl _nb_kernel214_ia32_sse2
nb_kernel214_ia32_sse2: 
_nb_kernel214_ia32_sse2:        
.set nb214_p_nri, 8
.set nb214_iinr, 12
.set nb214_jindex, 16
.set nb214_jjnr, 20
.set nb214_shift, 24
.set nb214_shiftvec, 28
.set nb214_fshift, 32
.set nb214_gid, 36
.set nb214_pos, 40
.set nb214_faction, 44
.set nb214_charge, 48
.set nb214_p_facel, 52
.set nb214_argkrf, 56
.set nb214_argcrf, 60
.set nb214_Vc, 64
.set nb214_type, 68
.set nb214_p_ntype, 72
.set nb214_vdwparam, 76
.set nb214_Vvdw, 80
.set nb214_p_tabscale, 84
.set nb214_VFtab, 88
.set nb214_invsqrta, 92
.set nb214_dvda, 96
.set nb214_p_gbtabscale, 100
.set nb214_GBtab, 104
.set nb214_p_nthreads, 108
.set nb214_count, 112
.set nb214_mtx, 116
.set nb214_outeriter, 120
.set nb214_inneriter, 124
.set nb214_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb214_ixO, 0
.set nb214_iyO, 16
.set nb214_izO, 32
.set nb214_ixH1, 48
.set nb214_iyH1, 64
.set nb214_izH1, 80
.set nb214_ixH2, 96
.set nb214_iyH2, 112
.set nb214_izH2, 128
.set nb214_ixM, 144
.set nb214_iyM, 160
.set nb214_izM, 176
.set nb214_jxO, 192
.set nb214_jyO, 208
.set nb214_jzO, 224
.set nb214_jxH1, 240
.set nb214_jyH1, 256
.set nb214_jzH1, 272
.set nb214_jxH2, 288
.set nb214_jyH2, 304
.set nb214_jzH2, 320
.set nb214_jxM, 336
.set nb214_jyM, 352
.set nb214_jzM, 368
.set nb214_dxOO, 384
.set nb214_dyOO, 400
.set nb214_dzOO, 416
.set nb214_dxH1H1, 432
.set nb214_dyH1H1, 448
.set nb214_dzH1H1, 464
.set nb214_dxH1H2, 480
.set nb214_dyH1H2, 496
.set nb214_dzH1H2, 512
.set nb214_dxH1M, 528
.set nb214_dyH1M, 544
.set nb214_dzH1M, 560
.set nb214_dxH2H1, 576
.set nb214_dyH2H1, 592
.set nb214_dzH2H1, 608
.set nb214_dxH2H2, 624
.set nb214_dyH2H2, 640
.set nb214_dzH2H2, 656
.set nb214_dxH2M, 672
.set nb214_dyH2M, 688
.set nb214_dzH2M, 704
.set nb214_dxMH1, 720
.set nb214_dyMH1, 736
.set nb214_dzMH1, 752
.set nb214_dxMH2, 768
.set nb214_dyMH2, 784
.set nb214_dzMH2, 800
.set nb214_dxMM, 816
.set nb214_dyMM, 832
.set nb214_dzMM, 848
.set nb214_qqMM, 864
.set nb214_qqMH, 880
.set nb214_qqHH, 896
.set nb214_two, 912
.set nb214_c6, 944
.set nb214_c12, 960
.set nb214_vctot, 976
.set nb214_Vvdwtot, 992
.set nb214_fixO, 1008
.set nb214_fiyO, 1024
.set nb214_fizO, 1040
.set nb214_fixH1, 1056
.set nb214_fiyH1, 1072
.set nb214_fizH1, 1088
.set nb214_fixH2, 1104
.set nb214_fiyH2, 1120
.set nb214_fizH2, 1136
.set nb214_fixM, 1152
.set nb214_fiyM, 1168
.set nb214_fizM, 1184
.set nb214_fjxO, 1200
.set nb214_fjyO, 1216
.set nb214_fjzO, 1232
.set nb214_fjxH1, 1248
.set nb214_fjyH1, 1264
.set nb214_fjzH1, 1280
.set nb214_fjxH2, 1296
.set nb214_fjyH2, 1312
.set nb214_fjzH2, 1328
.set nb214_fjxM, 1344
.set nb214_fjyM, 1360
.set nb214_fjzM, 1376
.set nb214_half, 1392
.set nb214_three, 1408
.set nb214_six, 1424
.set nb214_twelve, 1440
.set nb214_rsqOO, 1456
.set nb214_rsqH1H1, 1472
.set nb214_rsqH1H2, 1488
.set nb214_rsqH1M, 1504
.set nb214_rsqH2H1, 1520
.set nb214_rsqH2H2, 1536
.set nb214_rsqH2M, 1552
.set nb214_rsqMH1, 1568
.set nb214_rsqMH2, 1584
.set nb214_rsqMM, 1600
.set nb214_rinvsqOO, 1616
.set nb214_rinvH1H1, 1632
.set nb214_rinvH1H2, 1648
.set nb214_rinvH1M, 1664
.set nb214_rinvH2H1, 1680
.set nb214_rinvH2H2, 1696
.set nb214_rinvH2M, 1712
.set nb214_rinvMH1, 1728
.set nb214_rinvMH2, 1744
.set nb214_rinvMM, 1760
.set nb214_krf, 1776
.set nb214_crf, 1792
.set nb214_is3, 1808
.set nb214_ii3, 1812
.set nb214_innerjjnr, 1816
.set nb214_innerk, 1820
.set nb214_n, 1824
.set nb214_nn1, 1828
.set nb214_nri, 1832
.set nb214_nouter, 1836
.set nb214_ninner, 1840
.set nb214_salign, 1844
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1848,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb214_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb214_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb214_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb214_nouter(%esp)
        movl %eax,nb214_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb214_half(%esp)
        movl %ebx,nb214_half+4(%esp)
        movsd nb214_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## 6.0
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## 12.0
        movapd %xmm1,nb214_half(%esp)
        movapd %xmm2,nb214_two(%esp)
        movapd %xmm3,nb214_three(%esp)
        movapd %xmm4,nb214_six(%esp)
        movapd %xmm5,nb214_twelve(%esp)

        movl nb214_argkrf(%ebp),%esi
        movl nb214_argcrf(%ebp),%edi
        movsd (%esi),%xmm5
        movsd (%edi),%xmm6
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        movapd %xmm5,nb214_krf(%esp)
        movapd %xmm6,nb214_crf(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb214_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb214_charge(%ebp),%edx
        movsd 24(%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb214_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb214_qqMM(%esp)
        movapd %xmm4,nb214_qqMH(%esp)
        movapd %xmm5,nb214_qqHH(%esp)

        xorpd %xmm0,%xmm0
        movl  nb214_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb214_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb214_vdwparam(%ebp),%eax
        movlpd (%eax,%edx,8),%xmm0
        movhpd 8(%eax,%edx,8),%xmm0
        movhlps %xmm0,%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb214_c6(%esp)
        movapd %xmm1,nb214_c12(%esp)

_nb_kernel214_ia32_sse2.nb214_threadloop: 
        movl  nb214_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel214_ia32_sse2.nb214_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel214_ia32_sse2.nb214_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb214_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb214_n(%esp)
        movl %ebx,nb214_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel214_ia32_sse2.nb214_outerstart
        jmp _nb_kernel214_ia32_sse2.nb214_end

_nb_kernel214_ia32_sse2.nb214_outerstart: 
        ## ebx contains number of outer iterations
        addl nb214_nouter(%esp),%ebx
        movl %ebx,nb214_nouter(%esp)

_nb_kernel214_ia32_sse2.nb214_outer: 
        movl  nb214_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb214_is3(%esp)      ## store is3 

        movl  nb214_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb214_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb214_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb214_ii3(%esp)

        addsd (%eax,%ebx,8),%xmm3       ## ox
        addsd 8(%eax,%ebx,8),%xmm4      ## oy
        addsd 16(%eax,%ebx,8),%xmm5     ## oz   
        addsd 24(%eax,%ebx,8),%xmm6     ## h1x
        addsd 32(%eax,%ebx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb214_ixO(%esp)
        movapd %xmm4,nb214_iyO(%esp)
        movapd %xmm5,nb214_izO(%esp)
        movapd %xmm6,nb214_ixH1(%esp)
        movapd %xmm7,nb214_iyH1(%esp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%eax,%ebx,8),%xmm6    ## h1z
        addsd 48(%eax,%ebx,8),%xmm0    ## h2x
        addsd 56(%eax,%ebx,8),%xmm1    ## h2y
        addsd 64(%eax,%ebx,8),%xmm2    ## h2z
        addsd 72(%eax,%ebx,8),%xmm3    ## mx
        addsd 80(%eax,%ebx,8),%xmm4    ## my
        addsd 88(%eax,%ebx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb214_izH1(%esp)
        movapd %xmm0,nb214_ixH2(%esp)
        movapd %xmm1,nb214_iyH2(%esp)
        movapd %xmm2,nb214_izH2(%esp)
        movapd %xmm3,nb214_ixM(%esp)