nb_kernel210_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,237 行 · 第 1/3 页

;#
;# $Id: nb_kernel210_ia32_sse2.intel_syntax.s,v 1.1.2.2 2007/11/28 18:35:34 spoel Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as



.globl nb_kernel210_ia32_sse2
.globl _nb_kernel210_ia32_sse2
nb_kernel210_ia32_sse2:	
_nb_kernel210_ia32_sse2:	
.equiv          nb210_p_nri,            8
.equiv          nb210_iinr,             12
.equiv          nb210_jindex,           16
.equiv          nb210_jjnr,             20
.equiv          nb210_shift,            24
.equiv          nb210_shiftvec,         28
.equiv          nb210_fshift,           32
.equiv          nb210_gid,              36
.equiv          nb210_pos,              40
.equiv          nb210_faction,          44
.equiv          nb210_charge,           48
.equiv          nb210_p_facel,          52
.equiv          nb210_argkrf,           56
.equiv          nb210_argcrf,           60
.equiv          nb210_Vc,               64
.equiv          nb210_type,             68
.equiv          nb210_p_ntype,          72
.equiv          nb210_vdwparam,         76
.equiv          nb210_Vvdw,             80
.equiv          nb210_p_tabscale,       84
.equiv          nb210_VFtab,            88
.equiv          nb210_invsqrta,         92
.equiv          nb210_dvda,             96
.equiv          nb210_p_gbtabscale,     100
.equiv          nb210_GBtab,            104
.equiv          nb210_p_nthreads,       108
.equiv          nb210_count,            112
.equiv          nb210_mtx,              116
.equiv          nb210_outeriter,        120
.equiv          nb210_inneriter,        124
.equiv          nb210_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb210_ix,               0
.equiv          nb210_iy,               16
.equiv          nb210_iz,               32
.equiv          nb210_iq,               48
.equiv          nb210_dx,               64
.equiv          nb210_dy,               80
.equiv          nb210_dz,               96
.equiv          nb210_c6,               112
.equiv          nb210_c12,              128
.equiv          nb210_six,              144
.equiv          nb210_twelve,           160
.equiv          nb210_vctot,            176
.equiv          nb210_Vvdwtot,          192
.equiv          nb210_fix,              208
.equiv          nb210_fiy,              224
.equiv          nb210_fiz,              240
.equiv          nb210_half,             256
.equiv          nb210_three,            272
.equiv          nb210_two,              288
.equiv          nb210_krf,              304
.equiv          nb210_crf,              320
.equiv          nb210_facel,            336 ;# uses 8 bytes
.equiv          nb210_is3,              344
.equiv          nb210_ii3,              348
.equiv          nb210_ntia,             352
.equiv          nb210_innerjjnr,        356
.equiv          nb210_innerk,           360
.equiv          nb210_n,                364
.equiv          nb210_nn1,              368
.equiv          nb210_nri,              372
.equiv          nb210_ntype,            376
.equiv          nb210_nouter,           380
.equiv          nb210_ninner,           384
.equiv          nb210_salign,           388
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp,  392		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb210_salign], eax

	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb210_p_nri]
	mov esi, [ebp + nb210_p_facel]
	mov edi, [ebp + nb210_p_ntype]
	mov ecx, [ecx]
	movsd xmm7, [esi]
	mov edi, [edi]
	mov [esp + nb210_nri], ecx
	movsd [esp + nb210_facel], xmm7
	mov [esp + nb210_ntype], edi

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb210_nouter], eax
	mov [esp + nb210_ninner], eax


	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb210_half], eax
	mov [esp + nb210_half+4], ebx
	movsd xmm1, [esp + nb210_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd xmm4, xmm3
	addpd  xmm4, xmm4       ;# 6.0
	movapd xmm5, xmm4
	addpd  xmm5, xmm5       ;# 12.0
	movapd [esp + nb210_half], xmm1
	movapd [esp + nb210_two], xmm2
	movapd [esp + nb210_three], xmm3
	movapd [esp + nb210_six], xmm4
	movapd [esp + nb210_twelve], xmm5

	mov esi, [ebp + nb210_argkrf]
	mov edi, [ebp + nb210_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb210_krf], xmm5
	movapd [esp + nb210_crf], xmm6

.nb210_threadloop:
        mov   esi, [ebp + nb210_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb210_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb210_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb210_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb210_n], eax
        mov [esp + nb210_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb210_outerstart
        jmp .nb210_end

.nb210_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb210_nouter]
	mov [esp + nb210_nouter], ebx

.nb210_outer:
	mov   eax, [ebp + nb210_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb210_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb210_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb210_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	mov   edx, [ebp + nb210_charge]
	movsd xmm3, [edx + ebx*8]	
	mulsd xmm3, [esp + nb210_facel]
	shufpd xmm3, xmm3, 0

    	mov   edx, [ebp + nb210_type] 
    	mov   edx, [edx + ebx*4]
    	imul  edx, [esp + nb210_ntype]
    	shl   edx, 1
    	mov   [esp + nb210_ntia], edx
		
	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb210_pos]    ;# eax = base of pos[]  

	addsd xmm0, [eax + ebx*8]
	addsd xmm1, [eax + ebx*8 + 8]
	addsd xmm2, [eax + ebx*8 + 16]

	movapd [esp + nb210_iq], xmm3
	
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0

	movapd [esp + nb210_ix], xmm0
	movapd [esp + nb210_iy], xmm1
	movapd [esp + nb210_iz], xmm2

	mov   [esp + nb210_ii3], ebx
	
	;# clear vctot and i forces 
	xorpd xmm4, xmm4
	movapd [esp + nb210_vctot], xmm4
	movapd [esp + nb210_Vvdwtot], xmm4
	movapd [esp + nb210_fix], xmm4
	movapd [esp + nb210_fiy], xmm4
	movapd [esp + nb210_fiz], xmm4
	
	mov   eax, [ebp + nb210_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb210_pos]
	mov   edi, [ebp + nb210_faction]	
	mov   eax, [ebp + nb210_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb210_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb210_ninner]
	mov   [esp + nb210_ninner], ecx
	add   edx, 0
	mov   [esp + nb210_innerk], edx    ;# number of innerloop atoms 
	jge   .nb210_unroll_loop
	jmp   .nb210_checksingle
.nb210_unroll_loop:	
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb210_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]              
	add dword ptr [esp + nb210_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb210_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]

	movapd xmm5, [esp + nb210_iq]
	mulpd xmm3, xmm5		;# qq 
	
	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx
	
	mov esi, [ebp + nb210_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb210_vdwparam]
	shl eax, 1
	shl ebx, 1
	mov edi, [esp + nb210_ntia]
	add eax, edi
	add ebx, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movlpd xmm7, [esi + ebx*8]	;# c6b
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	movhpd xmm7, [esi + ebx*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0		
	movd  ebx, mm1
	movapd [esp + nb210_c6], xmm4
	movapd [esp + nb210_c12], xmm6
	
	mov esi, [ebp + nb210_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 	
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]
	movhpd xmm2, [esi + ebx*8 + 16]		
	
	;# move ix-iz to xmm4-xmm6 
	movapd xmm4, [esp + nb210_ix]
	movapd xmm5, [esp + nb210_iy]
	movapd xmm6, [esp + nb210_iz]

	;# calc dr 
	subpd xmm4, xmm0
	subpd xmm5, xmm1
	subpd xmm6, xmm2

	;# store dr 
	movapd [esp + nb210_dx], xmm4
	movapd [esp + nb210_dy], xmm5
	movapd [esp + nb210_dz], xmm6
	;# square it 
	mulpd xmm4,xmm4
	mulpd xmm5,xmm5
	mulpd xmm6,xmm6
	addpd xmm4, xmm5
	addpd xmm4, xmm6
	;# rsq in xmm4 

	cvtpd2ps xmm5, xmm4	
	rsqrtps xmm5, xmm5
	cvtps2pd xmm2, xmm5	;# lu in low xmm2 

	movapd xmm7, [esp + nb210_krf]	
	;# lookup seed in xmm2 
	movapd xmm5, xmm2	;# copy of lu 
	mulpd xmm2, xmm2	;# lu*lu 
	movapd xmm1, [esp + nb210_three]
	mulpd xmm7, xmm4	;# krsq 
	mulpd xmm2, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb210_half]
	subpd xmm1, xmm2	;# 30-rsq*lu*lu 
	mulpd xmm1, xmm5	
	mulpd xmm1, xmm0	;# xmm0=iter1 of rinv (new lu) 

	movapd xmm5, xmm1	;# copy of lu 
	mulpd xmm1, xmm1	;# lu*lu 
	movapd xmm2, [esp + nb210_three]
	mulpd xmm1, xmm4	;# rsq*lu*lu 			
	movapd xmm0, [esp + nb210_half]
	subpd xmm2, xmm1	;# 30-rsq*lu*lu 
	mulpd xmm2, xmm5	
	mulpd xmm0, xmm2	;# xmm0=rinv 
	movapd xmm4, xmm0
	mulpd  xmm4, xmm4	;# xmm4=rinvsq 
	movapd xmm6, xmm0
	addpd  xmm6, xmm7	;# xmm6=rinv+ krsq 
	movapd xmm1, xmm4
	subpd  xmm6, [esp + nb210_crf]
	mulpd  xmm1, xmm4
	mulpd  xmm1, xmm4	;# xmm1=rinvsix 
	movapd xmm2, xmm1
	mulpd  xmm2, xmm2	;# xmm2=rinvtwelve 
	mulpd  xmm6, xmm3	;# xmm6=vcoul=qq*(rinv+ krsq) 
	mulpd  xmm7, [esp + nb210_two]
	mulpd  xmm1, [esp + nb210_c6]
	mulpd  xmm2, [esp + nb210_c12]
	movapd xmm5, xmm2
	subpd  xmm5, xmm1	;# Vvdw=Vvdw12-Vvdw6 
	addpd  xmm5, [esp + nb210_Vvdwtot]
	mulpd  xmm1, [esp + nb210_six]
	mulpd  xmm2, [esp + nb210_twelve]
	subpd  xmm2, xmm1
	subpd  xmm0, xmm7
	mulpd  xmm3, xmm0
	addpd  xmm2, xmm3
	mulpd  xmm4, xmm2	;# xmm4=total fscal 
	addpd  xmm6, [esp + nb210_vctot]