nb_kernel233_ia32_sse2.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,397 行 · 第 1/5 页

	;# accumulate H2i forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb233_fixH2]
	movapd xmm1, [esp + nb233_fiyH2]
	movapd xmm2, [esp + nb233_fizH2]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 48]
	movsd  xmm4, [edi + ecx*8 + 56]
	movsd  xmm5, [edi + ecx*8 + 64]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 48], xmm3
	movsd  [edi + ecx*8 + 56], xmm4
	movsd  [edi + ecx*8 + 64], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# accumulate Mi forces in xmm0, xmm1, xmm2 
	movapd xmm0, [esp + nb233_fixM]
	movapd xmm1, [esp + nb233_fiyM]
	movapd xmm2, [esp + nb233_fizM]

	movhlps xmm3, xmm0
	movhlps xmm4, xmm1
	movhlps xmm5, xmm2
	addsd  xmm0, xmm3
	addsd  xmm1, xmm4
	addsd  xmm2, xmm5 ;# sum is in low xmm0-xmm2 

	;# increment i force 
	movsd  xmm3, [edi + ecx*8 + 72]
	movsd  xmm4, [edi + ecx*8 + 80]
	movsd  xmm5, [edi + ecx*8 + 88]
	addsd  xmm3, xmm0
	addsd  xmm4, xmm1
	addsd  xmm5, xmm2
	movsd  [edi + ecx*8 + 72], xmm3
	movsd  [edi + ecx*8 + 80], xmm4
	movsd  [edi + ecx*8 + 88], xmm5

	;# accumulate force in xmm6/xmm7 for fshift 
	addsd xmm7, xmm2
	unpcklpd xmm0, xmm1
	addpd xmm6, xmm0

	;# increment fshift force 
	movlpd xmm3, [esi + edx*8]
	movhpd xmm3, [esi + edx*8 + 8]
	movsd  xmm4, [esi + edx*8 + 16]
	addpd  xmm3, xmm6
	addsd  xmm4, xmm7
	movlpd [esi + edx*8],      xmm3
	movhpd [esi + edx*8 + 8],  xmm3
	movsd  [esi + edx*8 + 16], xmm4

	;# get n from stack
	mov esi, [esp + nb233_n]
        ;# get group index for i particle 
        mov   edx, [ebp + nb233_gid]      	;# base of gid[]
        mov   edx, [edx + esi*4]		;# ggid=gid[n]

	;# accumulate total potential energy and update it 
	movapd xmm7, [esp + nb233_vctot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 
        
	;# add earlier value from mem 
	mov   eax, [ebp + nb233_Vc]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
	;# accumulate total lj energy and update it 
	movapd xmm7, [esp + nb233_Vvdwtot]
	;# accumulate 
	movhlps xmm6, xmm7
	addsd  xmm7, xmm6	;# low xmm7 has the sum now 

	;# add earlier value from mem 
	mov   eax, [ebp + nb233_Vvdw]
	addsd xmm7, [eax + edx*8] 
	;# move back to mem 
	movsd [eax + edx*8], xmm7 
	
       ;# finish if last 
        mov ecx, [esp + nb233_nn1]
	;# esi already loaded with n
	inc esi
        sub ecx, esi
        jz .nb233_outerend

        ;# not last, iterate outer loop once more!  
        mov [esp + nb233_n], esi
        jmp .nb233_outer
.nb233_outerend:
        ;# check if more outer neighborlists remain
        mov   ecx, [esp + nb233_nri]
	;# esi already loaded with n above
        sub   ecx, esi
        jz .nb233_end
        ;# non-zero, do one more workunit
        jmp   .nb233_threadloop
.nb233_end:
	emms

	mov eax, [esp + nb233_nouter]
	mov ebx, [esp + nb233_ninner]
	mov ecx, [ebp + nb233_outeriter]
	mov edx, [ebp + nb233_inneriter]
	mov [ecx], eax
	mov [edx], ebx

	mov eax, [esp + nb233_salign]
	add esp, eax
	add esp, 1020
	pop edi
	pop esi
    	pop edx
    	pop ecx
    	pop ebx
    	pop eax
	leave
	ret




.globl nb_kernel233nf_ia32_sse2
.globl _nb_kernel233nf_ia32_sse2
nb_kernel233nf_ia32_sse2:	
_nb_kernel233nf_ia32_sse2:	
.equiv          nb233nf_p_nri,            8
.equiv          nb233nf_iinr,             12
.equiv          nb233nf_jindex,           16
.equiv          nb233nf_jjnr,             20
.equiv          nb233nf_shift,            24
.equiv          nb233nf_shiftvec,         28
.equiv          nb233nf_fshift,           32
.equiv          nb233nf_gid,              36
.equiv          nb233nf_pos,              40
.equiv          nb233nf_faction,          44
.equiv          nb233nf_charge,           48
.equiv          nb233nf_p_facel,          52
.equiv          nb233nf_argkrf,           56
.equiv          nb233nf_argcrf,           60
.equiv          nb233nf_Vc,               64
.equiv          nb233nf_type,             68
.equiv          nb233nf_p_ntype,          72
.equiv          nb233nf_vdwparam,         76
.equiv          nb233nf_Vvdw,             80
.equiv          nb233nf_p_tabscale,       84
.equiv          nb233nf_VFtab,            88
.equiv          nb233nf_invsqrta,         92
.equiv          nb233nf_dvda,             96
.equiv          nb233nf_p_gbtabscale,     100
.equiv          nb233nf_GBtab,            104
.equiv          nb233nf_p_nthreads,       108
.equiv          nb233nf_count,            112
.equiv          nb233nf_mtx,              116
.equiv          nb233nf_outeriter,        120
.equiv          nb233nf_inneriter,        124
.equiv          nb233nf_work,             128
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse2 use 
.equiv          nb233nf_ixO,              0
.equiv          nb233nf_iyO,              16
.equiv          nb233nf_izO,              32
.equiv          nb233nf_ixH1,             48
.equiv          nb233nf_iyH1,             64
.equiv          nb233nf_izH1,             80
.equiv          nb233nf_ixH2,             96
.equiv          nb233nf_iyH2,             112
.equiv          nb233nf_izH2,             128
.equiv          nb233nf_ixM,              144
.equiv          nb233nf_iyM,              160
.equiv          nb233nf_izM,              176
.equiv          nb233nf_iqH,              192
.equiv          nb233nf_iqM,              208
.equiv          nb233nf_qqH,              416
.equiv          nb233nf_qqM,              432
.equiv          nb233nf_c6,               448
.equiv          nb233nf_c12,              464
.equiv          nb233nf_tsc,              480
.equiv          nb233nf_vctot,            512
.equiv          nb233nf_Vvdwtot,          528
.equiv          nb233nf_half,             784
.equiv          nb233nf_three,            800
.equiv          nb233nf_two,              816
.equiv          nb233nf_rinvH1,           832
.equiv          nb233nf_rinvH2,           848
.equiv          nb233nf_rinvM,            864
.equiv          nb233nf_krsqH1,           880
.equiv          nb233nf_krsqH2,           896
.equiv          nb233nf_krsqM,            912
.equiv          nb233nf_krf,              928
.equiv          nb233nf_crf,              944
.equiv          nb233nf_rsqO,             960
.equiv          nb233nf_is3,              976
.equiv          nb233nf_ii3,              980
.equiv          nb233nf_ntia,             984
.equiv          nb233nf_innerjjnr,        988
.equiv          nb233nf_innerk,           992
.equiv          nb233nf_n,                996
.equiv          nb233nf_nn1,              1000
.equiv          nb233nf_nri,              1004
.equiv          nb233nf_nouter,           1008
.equiv          nb233nf_ninner,           1012
.equiv          nb233nf_salign,           1016
	push ebp
	mov ebp,esp	
    	push eax
    	push ebx
    	push ecx
    	push edx
	push esi
	push edi
	sub esp, 1020		;# local stack space 
	mov  eax, esp
	and  eax, 0xf
	sub esp, eax
	mov [esp + nb233nf_salign], eax
	emms

	;# Move args passed by reference to stack
	mov ecx, [ebp + nb233nf_p_nri]
	mov ecx, [ecx]
	mov [esp + nb233nf_nri], ecx

	;# zero iteration counters
	mov eax, 0
	mov [esp + nb233nf_nouter], eax
	mov [esp + nb233nf_ninner], eax

	mov eax, [ebp + nb233nf_p_tabscale]
	movsd xmm3, [eax]
	shufpd xmm3, xmm3, 0
	movapd [esp + nb233nf_tsc], xmm3

	mov esi, [ebp + nb233nf_argkrf]
	mov edi, [ebp + nb233nf_argcrf]
	movsd xmm5, [esi]
	movsd xmm6, [edi]
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	movapd [esp + nb233nf_krf], xmm5
	movapd [esp + nb233nf_crf], xmm6

	;# create constant floating-point factors on stack
	mov eax, 0x00000000     ;# lower half of double 0.5 IEEE (hex)
	mov ebx, 0x3fe00000
	mov [esp + nb233nf_half], eax
	mov [esp + nb233nf_half+4], ebx
	movsd xmm1, [esp + nb233nf_half]
	shufpd xmm1, xmm1, 0    ;# splat to all elements
	movapd xmm3, xmm1
	addpd  xmm3, xmm3       ;# 1.0
	movapd xmm2, xmm3
	addpd  xmm2, xmm2       ;# 2.0
	addpd  xmm3, xmm2	;# 3.0
	movapd [esp + nb233nf_half], xmm1
	movapd [esp + nb233nf_two], xmm2
	movapd [esp + nb233nf_three], xmm3

	;# assume we have at least one i particle - start directly 
	mov   ecx, [ebp + nb233nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx]	    ;# ebx =ii 

	mov   edx, [ebp + nb233nf_charge]
	movsd xmm3, [edx + ebx*8 + 8]	
	movsd xmm4, [edx + ebx*8 + 24]	
	mov esi, [ebp + nb233nf_p_facel]
	movsd xmm5, [esi]
	mulsd  xmm3, xmm5
	mulsd  xmm4, xmm5

	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	movapd [esp + nb233nf_iqH], xmm3
	movapd [esp + nb233nf_iqM], xmm4
	
	mov   edx, [ebp + nb233nf_type]
	mov   ecx, [edx + ebx*4]
	shl   ecx, 1
	mov edi, [ebp + nb233nf_p_ntype]
	imul  ecx, [edi]      ;# ecx = ntia = 2*ntype*type[ii0] 
	mov   [esp + nb233nf_ntia], ecx		
.nb233nf_threadloop:
        mov   esi, [ebp + nb233nf_count]          ;# pointer to sync counter
        mov   eax, [esi]
.nb233nf_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb233nf_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [esp + nb233nf_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [esp + nb233nf_n], eax
        mov [esp + nb233nf_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb233nf_outerstart
        jmp .nb233nf_end

.nb233nf_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [esp + nb233nf_nouter]
	mov [esp + nb233nf_nouter], ebx

.nb233nf_outer:
	mov   eax, [ebp + nb233nf_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [eax+esi*4]		;# ebx=shift[n] 
	
	lea   ebx, [ebx + ebx*2]    ;# ebx=3*is 
	mov   [esp + nb233nf_is3],ebx    	;# store is3 

	mov   eax, [ebp + nb233nf_shiftvec]   ;# eax = base of shiftvec[] 

	movsd xmm0, [eax + ebx*8]
	movsd xmm1, [eax + ebx*8 + 8]
	movsd xmm2, [eax + ebx*8 + 16] 

	mov   ecx, [ebp + nb233nf_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [ecx+esi*4]	    ;# ebx =ii 

	movapd xmm3, xmm0
	movapd xmm4, xmm1
	movapd xmm5, xmm2
	movapd xmm6, xmm0
	movapd xmm7, xmm1

	lea   ebx, [ebx + ebx*2]	;# ebx = 3*ii=ii3 
	mov   eax, [ebp + nb233nf_pos]    ;# eax = base of pos[]  
	mov   [esp + nb233nf_ii3], ebx

	addsd xmm3, [eax + ebx*8] 	;# ox
	addsd xmm4, [eax + ebx*8 + 8] 	;# oy
	addsd xmm5, [eax + ebx*8 + 16]	;# oz	
	addsd xmm6, [eax + ebx*8 + 24] 	;# h1x
	addsd xmm7, [eax + ebx*8 + 32] 	;# h1y
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	shufpd xmm6, xmm6, 0
	shufpd xmm7, xmm7, 0
	movapd [esp + nb233nf_ixO], xmm3
	movapd [esp + nb233nf_iyO], xmm4
	movapd [esp + nb233nf_izO], xmm5
	movapd [esp + nb233nf_ixH1], xmm6
	movapd [esp + nb233nf_iyH1], xmm7

	movsd xmm6, xmm2
	movsd xmm3, xmm0
	movsd xmm4, xmm1
	movsd xmm5, xmm2
	addsd xmm6, [eax + ebx*8 + 40] ;# h1z
	addsd xmm0, [eax + ebx*8 + 48] ;# h2x
	addsd xmm1, [eax + ebx*8 + 56] ;# h2y
	addsd xmm2, [eax + ebx*8 + 64] ;# h2z
	addsd xmm3, [eax + ebx*8 + 72] ;# mx
	addsd xmm4, [eax + ebx*8 + 80] ;# my
	addsd xmm5, [eax + ebx*8 + 88] ;# mz

	shufpd xmm6, xmm6, 0
	shufpd xmm0, xmm0, 0
	shufpd xmm1, xmm1, 0
	shufpd xmm2, xmm2, 0
	shufpd xmm3, xmm3, 0
	shufpd xmm4, xmm4, 0
	shufpd xmm5, xmm5, 0
	movapd [esp + nb233nf_izH1], xmm6
	movapd [esp + nb233nf_ixH2], xmm0
	movapd [esp + nb233nf_iyH2], xmm1
	movapd [esp + nb233nf_izH2], xmm2
	movapd [esp + nb233nf_ixM], xmm3
	movapd [esp + nb233nf_iyM], xmm4
	movapd [esp + nb233nf_izM], xmm5

	;# clear vctot 
	xorpd xmm4, xmm4
	movapd [esp + nb233nf_vctot], xmm4
	movapd [esp + nb233nf_Vvdwtot], xmm4
	
	mov   eax, [ebp + nb233nf_jindex]
	mov   ecx, [eax + esi*4]	     ;# jindex[n] 
	mov   edx, [eax + esi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   esi, [ebp + nb233nf_pos]
	mov   edi, [ebp + nb233nf_faction]	
	mov   eax, [ebp + nb233nf_jjnr]
	shl   ecx, 2
	add   eax, ecx
	mov   [esp + nb233nf_innerjjnr], eax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  2
	add   ecx, [esp + nb233nf_ninner]
	mov   [esp + nb233nf_ninner], ecx
	add   edx, 0
	mov   [esp + nb233nf_innerk], edx    ;# number of innerloop atoms 
	jge   .nb233nf_unroll_loop
	jmp   .nb233nf_checksingle
.nb233nf_unroll_loop:
	;# twice unrolled innerloop here 
	mov   edx, [esp + nb233nf_innerjjnr]     ;# pointer to jjnr[k] 
	mov   eax, [edx]	
	mov   ebx, [edx + 4]

	add dword ptr [esp + nb233nf_innerjjnr],  8	;# advance pointer (unrolled 2) 

	mov esi, [ebp + nb233nf_charge]    ;# base of charge[] 
	
	movlpd xmm3, [esi + eax*8]
	movhpd xmm3, [esi + ebx*8]
	movapd xmm4, xmm3
	mulpd  xmm3, [esp + nb233nf_iqM]
	mulpd  xmm4, [esp + nb233nf_iqH]

	movd  mm0, eax		;# use mmx registers as temp storage 
	movd  mm1, ebx

	movapd  [esp + nb233nf_qqM], xmm3
	movapd  [esp + nb233nf_qqH], xmm4
	
	mov esi, [ebp + nb233nf_type]
	mov eax, [esi + eax*4]
	mov ebx, [esi + ebx*4]
	mov esi, [ebp + nb233nf_vdwparam]
	shl eax, 1	
	shl ebx, 1	
	mov edi, [esp + nb233nf_ntia]
	add eax, edi
	add ebx, edi

	movlpd xmm6, [esi + eax*8]	;# c6a
	movlpd xmm7, [esi + ebx*8]	;# c6b
	movhpd xmm6, [esi + eax*8 + 8]	;# c6a c12a 
	movhpd xmm7, [esi + ebx*8 + 8]	;# c6b c12b 
	movapd xmm4, xmm6
	unpcklpd xmm4, xmm7
	unpckhpd xmm6, xmm7
	
	movd  eax, mm0
	movd  ebx, mm1
	movapd [esp + nb233nf_c6], xmm4
	movapd [esp + nb233nf_c12], xmm6
	
	mov esi, [ebp + nb233nf_pos]       ;# base of pos[] 

	lea   eax, [eax + eax*2]     ;# replace jnr with j3 
	lea   ebx, [ebx + ebx*2]	

	;# move two coordinates to xmm0-xmm2 
	movlpd xmm0, [esi + eax*8]
	movlpd xmm1, [esi + eax*8 + 8]
	movlpd xmm2, [esi + eax*8 + 16]
	movhpd xmm0, [esi + ebx*8]
	movhpd xmm1, [esi + ebx*8 + 8]