nb_kernel314_ia32_sse2.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,922 行 · 第 1/5 页

##
## $Id: nb_kernel314_ia32_sse2.s,v 1.2.2.2 2007/11/28 18:35:36 spoel Exp $
##
## Gromacs 4.0                         Copyright (c) 1991-2003 
## David van der Spoel, Erik Lindahl
##
## This program is free software; you can redistribute it and/or
## modify it under the terms of the GNU General Public License
## as published by the Free Software Foundation; either version 2
## of the License, or (at your option) any later version.
##
## To help us fund GROMACS development, we humbly ask that you cite
## the research papers on the package. Check out http://www.gromacs.org
## 
## And Hey:
## Gnomes, ROck Monsters And Chili Sauce
##



.globl nb_kernel314_ia32_sse2
.globl _nb_kernel314_ia32_sse2
nb_kernel314_ia32_sse2: 
_nb_kernel314_ia32_sse2:        
.set nb314_p_nri, 8
.set nb314_iinr, 12
.set nb314_jindex, 16
.set nb314_jjnr, 20
.set nb314_shift, 24
.set nb314_shiftvec, 28
.set nb314_fshift, 32
.set nb314_gid, 36
.set nb314_pos, 40
.set nb314_faction, 44
.set nb314_charge, 48
.set nb314_p_facel, 52
.set nb314_argkrf, 56
.set nb314_argcrf, 60
.set nb314_Vc, 64
.set nb314_type, 68
.set nb314_p_ntype, 72
.set nb314_vdwparam, 76
.set nb314_Vvdw, 80
.set nb314_p_tabscale, 84
.set nb314_VFtab, 88
.set nb314_invsqrta, 92
.set nb314_dvda, 96
.set nb314_p_gbtabscale, 100
.set nb314_GBtab, 104
.set nb314_p_nthreads, 108
.set nb314_count, 112
.set nb314_mtx, 116
.set nb314_outeriter, 120
.set nb314_inneriter, 124
.set nb314_work, 128
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse2 use 
.set nb314_ixO, 0
.set nb314_iyO, 16
.set nb314_izO, 32
.set nb314_ixH1, 48
.set nb314_iyH1, 64
.set nb314_izH1, 80
.set nb314_ixH2, 96
.set nb314_iyH2, 112
.set nb314_izH2, 128
.set nb314_ixM, 144
.set nb314_iyM, 160
.set nb314_izM, 176
.set nb314_jxO, 192
.set nb314_jyO, 208
.set nb314_jzO, 224
.set nb314_jxH1, 240
.set nb314_jyH1, 256
.set nb314_jzH1, 272
.set nb314_jxH2, 288
.set nb314_jyH2, 304
.set nb314_jzH2, 320
.set nb314_jxM, 336
.set nb314_jyM, 352
.set nb314_jzM, 368
.set nb314_dxOO, 384
.set nb314_dyOO, 400
.set nb314_dzOO, 416
.set nb314_dxH1H1, 432
.set nb314_dyH1H1, 448
.set nb314_dzH1H1, 464
.set nb314_dxH1H2, 480
.set nb314_dyH1H2, 496
.set nb314_dzH1H2, 512
.set nb314_dxH1M, 528
.set nb314_dyH1M, 544
.set nb314_dzH1M, 560
.set nb314_dxH2H1, 576
.set nb314_dyH2H1, 592
.set nb314_dzH2H1, 608
.set nb314_dxH2H2, 624
.set nb314_dyH2H2, 640
.set nb314_dzH2H2, 656
.set nb314_dxH2M, 672
.set nb314_dyH2M, 688
.set nb314_dzH2M, 704
.set nb314_dxMH1, 720
.set nb314_dyMH1, 736
.set nb314_dzMH1, 752
.set nb314_dxMH2, 768
.set nb314_dyMH2, 784
.set nb314_dzMH2, 800
.set nb314_dxMM, 816
.set nb314_dyMM, 832
.set nb314_dzMM, 848
.set nb314_qqMM, 864
.set nb314_qqMH, 880
.set nb314_qqHH, 896
.set nb314_two, 912
.set nb314_tsc, 928
.set nb314_c6, 944
.set nb314_c12, 960
.set nb314_vctot, 976
.set nb314_Vvdwtot, 992
.set nb314_fixO, 1008
.set nb314_fiyO, 1024
.set nb314_fizO, 1040
.set nb314_fixH1, 1056
.set nb314_fiyH1, 1072
.set nb314_fizH1, 1088
.set nb314_fixH2, 1104
.set nb314_fiyH2, 1120
.set nb314_fizH2, 1136
.set nb314_fixM, 1152
.set nb314_fiyM, 1168
.set nb314_fizM, 1184
.set nb314_fjxO, 1200
.set nb314_fjyO, 1216
.set nb314_fjzO, 1232
.set nb314_fjxH1, 1248
.set nb314_fjyH1, 1264
.set nb314_fjzH1, 1280
.set nb314_fjxH2, 1296
.set nb314_fjyH2, 1312
.set nb314_fjzH2, 1328
.set nb314_fjxM, 1344
.set nb314_fjyM, 1360
.set nb314_fjzM, 1376
.set nb314_half, 1392
.set nb314_three, 1408
.set nb314_six, 1424
.set nb314_twelve, 1440
.set nb314_rsqOO, 1456
.set nb314_rsqH1H1, 1472
.set nb314_rsqH1H2, 1488
.set nb314_rsqH1M, 1504
.set nb314_rsqH2H1, 1520
.set nb314_rsqH2H2, 1536
.set nb314_rsqH2M, 1552
.set nb314_rsqMH1, 1568
.set nb314_rsqMH2, 1584
.set nb314_rsqMM, 1600
.set nb314_rinvsqOO, 1616
.set nb314_rinvH1H1, 1632
.set nb314_rinvH1H2, 1648
.set nb314_rinvH1M, 1664
.set nb314_rinvH2H1, 1680
.set nb314_rinvH2H2, 1696
.set nb314_rinvH2M, 1712
.set nb314_rinvMH1, 1728
.set nb314_rinvMH2, 1744
.set nb314_rinvMM, 1760
.set nb314_is3, 1776
.set nb314_ii3, 1780
.set nb314_innerjjnr, 1784
.set nb314_innerk, 1788
.set nb314_n, 1792
.set nb314_nn1, 1796
.set nb314_nri, 1800
.set nb314_nouter, 1804
.set nb314_ninner, 1808
.set nb314_salign, 1812
        pushl %ebp
        movl %esp,%ebp
        pushl %eax
        pushl %ebx
        pushl %ecx
        pushl %edx
        pushl %esi
        pushl %edi
        subl $1816,%esp         ## local stack space 
        movl %esp,%eax
        andl $0xf,%eax
        subl %eax,%esp
        movl %eax,nb314_salign(%esp)

        emms

        ## Move args passed by reference to stack
        movl nb314_p_nri(%ebp),%ecx
        movl (%ecx),%ecx
        movl %ecx,nb314_nri(%esp)

        ## zero iteration counters
        movl $0,%eax
        movl %eax,nb314_nouter(%esp)
        movl %eax,nb314_ninner(%esp)


        ## create constant floating-point factors on stack
        movl $0x00000000,%eax   ## lower half of double 0.5 IEEE (hex)
        movl $0x3fe00000,%ebx
        movl %eax,nb314_half(%esp)
        movl %ebx,nb314_half+4(%esp)
        movsd nb314_half(%esp),%xmm1
        shufpd $0,%xmm1,%xmm1  ## splat to all elements
        movapd %xmm1,%xmm3
        addpd  %xmm3,%xmm3      ## 1.0
        movapd %xmm3,%xmm2
        addpd  %xmm2,%xmm2      ## 2.0
        addpd  %xmm2,%xmm3      ## 3.0
        movapd %xmm3,%xmm4
        addpd  %xmm4,%xmm4      ## 6.0
        movapd %xmm4,%xmm5
        addpd  %xmm5,%xmm5      ## 12.0
        movapd %xmm1,nb314_half(%esp)
        movapd %xmm2,nb314_two(%esp)
        movapd %xmm3,nb314_three(%esp)
        movapd %xmm4,nb314_six(%esp)
        movapd %xmm5,nb314_twelve(%esp)
        movl nb314_p_tabscale(%ebp),%eax
        movsd (%eax),%xmm3

        shufpd $0,%xmm3,%xmm3
        movapd %xmm3,nb314_tsc(%esp)

        ## assume we have at least one i particle - start directly 
        movl  nb314_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx),%ebx           ## ebx =ii 

        movl  nb314_charge(%ebp),%edx
        movsd 24(%edx,%ebx,8),%xmm3
        movsd %xmm3,%xmm4
        movsd 8(%edx,%ebx,8),%xmm5
        movl nb314_p_facel(%ebp),%esi
        movsd (%esi),%xmm6
        mulsd  %xmm3,%xmm3
        mulsd  %xmm5,%xmm4
        mulsd  %xmm5,%xmm5
        mulsd  %xmm6,%xmm3
        mulsd  %xmm6,%xmm4
        mulsd  %xmm6,%xmm5
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm3,nb314_qqMM(%esp)
        movapd %xmm4,nb314_qqMH(%esp)
        movapd %xmm5,nb314_qqHH(%esp)

        xorpd %xmm0,%xmm0
        movl  nb314_type(%ebp),%edx
        movl  (%edx,%ebx,4),%ecx
        shll  %ecx
        movl  %ecx,%edx
        movl nb314_p_ntype(%ebp),%edi
        imull (%edi),%ecx     ## ecx = ntia = 2*ntype*type[ii0] 
        addl  %ecx,%edx
        movl  nb314_vdwparam(%ebp),%eax
        movlpd (%eax,%edx,8),%xmm0
        movlpd 8(%eax,%edx,8),%xmm1
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        movapd %xmm0,nb314_c6(%esp)
        movapd %xmm1,nb314_c12(%esp)

_nb_kernel314_ia32_sse2.nb314_threadloop: 
        movl  nb314_count(%ebp),%esi            ## pointer to sync counter
        movl  (%esi),%eax
_nb_kernel314_ia32_sse2.nb314_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%esi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel314_ia32_sse2.nb314_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb314_nri(%esp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb314_n(%esp)
        movl %ebx,nb314_nn1(%esp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel314_ia32_sse2.nb314_outerstart
        jmp _nb_kernel314_ia32_sse2.nb314_end

_nb_kernel314_ia32_sse2.nb314_outerstart: 
        ## ebx contains number of outer iterations
        addl nb314_nouter(%esp),%ebx
        movl %ebx,nb314_nouter(%esp)

_nb_kernel314_ia32_sse2.nb314_outer: 
        movl  nb314_shift(%ebp),%eax        ## eax = pointer into shift[] 
        movl  (%eax,%esi,4),%ebx        ## ebx=shift[n] 

        leal  (%ebx,%ebx,2),%ebx    ## ebx=3*is 
        movl  %ebx,nb314_is3(%esp)      ## store is3 

        movl  nb314_shiftvec(%ebp),%eax     ## eax = base of shiftvec[] 

        movsd (%eax,%ebx,8),%xmm0
        movsd 8(%eax,%ebx,8),%xmm1
        movsd 16(%eax,%ebx,8),%xmm2

        movl  nb314_iinr(%ebp),%ecx         ## ecx = pointer into iinr[]        
        movl  (%ecx,%esi,4),%ebx    ## ebx =ii 

        movapd %xmm0,%xmm3
        movapd %xmm1,%xmm4
        movapd %xmm2,%xmm5
        movapd %xmm0,%xmm6
        movapd %xmm1,%xmm7

        leal  (%ebx,%ebx,2),%ebx        ## ebx = 3*ii=ii3 
        movl  nb314_pos(%ebp),%eax      ## eax = base of pos[]  
        movl  %ebx,nb314_ii3(%esp)

        addsd (%eax,%ebx,8),%xmm3       ## ox
        addsd 8(%eax,%ebx,8),%xmm4      ## oy
        addsd 16(%eax,%ebx,8),%xmm5     ## oz   
        addsd 24(%eax,%ebx,8),%xmm6     ## h1x
        addsd 32(%eax,%ebx,8),%xmm7     ## h1y
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm7,%xmm7
        movapd %xmm3,nb314_ixO(%esp)
        movapd %xmm4,nb314_iyO(%esp)
        movapd %xmm5,nb314_izO(%esp)
        movapd %xmm6,nb314_ixH1(%esp)
        movapd %xmm7,nb314_iyH1(%esp)

        movsd %xmm2,%xmm6
        movsd %xmm0,%xmm3
        movsd %xmm1,%xmm4
        movsd %xmm2,%xmm5
        addsd 40(%eax,%ebx,8),%xmm6    ## h1z
        addsd 48(%eax,%ebx,8),%xmm0    ## h2x
        addsd 56(%eax,%ebx,8),%xmm1    ## h2y
        addsd 64(%eax,%ebx,8),%xmm2    ## h2z
        addsd 72(%eax,%ebx,8),%xmm3    ## mx
        addsd 80(%eax,%ebx,8),%xmm4    ## my
        addsd 88(%eax,%ebx,8),%xmm5    ## mz

        shufpd $0,%xmm6,%xmm6
        shufpd $0,%xmm0,%xmm0
        shufpd $0,%xmm1,%xmm1
        shufpd $0,%xmm2,%xmm2
        shufpd $0,%xmm3,%xmm3
        shufpd $0,%xmm4,%xmm4
        shufpd $0,%xmm5,%xmm5
        movapd %xmm6,nb314_izH1(%esp)
        movapd %xmm0,nb314_ixH2(%esp)
        movapd %xmm1,nb314_iyH2(%esp)
        movapd %xmm2,nb314_izH2(%esp)
        movapd %xmm3,nb314_ixM(%esp)
        movapd %xmm4,nb314_iyM(%esp)
        movapd %xmm5,nb314_izM(%esp)

        ## clear vctot and i forces 
        xorpd %xmm4,%xmm4
        movapd %xmm4,nb314_vctot(%esp)
        movapd %xmm4,nb314_Vvdwtot(%esp)
        movapd %xmm4,nb314_fixO(%esp)
        movapd %xmm4,nb314_fiyO(%esp)
        movapd %xmm4,nb314_fizO(%esp)
        movapd %xmm4,nb314_fixH1(%esp)
        movapd %xmm4,nb314_fiyH1(%esp)
        movapd %xmm4,nb314_fizH1(%esp)
        movapd %xmm4,nb314_fixH2(%esp)
        movapd %xmm4,nb314_fiyH2(%esp)
        movapd %xmm4,nb314_fizH2(%esp)