nb_kernel410_ia64_single.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,111 行 · 第 1/2 页

	//		NJ0, NJ1	Bounds of current neighbor list
	//
	//	Load up all the floating-point values (yes, McKinley can do 4 FP loads
	//	per cycle) and initialize the loop counters and predicates. Compute
	//	the initial position <x, y, z> and charge. If this isn't the last time
	//	through the loop, start loading the next value for NJ1 - we already
	//	moved the previous NJ1 -> NJ0.
//	OUTER PROLOGUE 1
	{	.mfi						
		nop 		0x0
		mov			FIX = f0
		add		Nouter = 1, Nouter
	}
	{	.mmf
		ldfs		shX = [shiftVPtr], 4
		ldfs		PosX = [posPtr], 4
		mov			FIY = f0
	} ;;
//	OUTER PROLOGUE 2
	{	.mmf
		setf.sig	f32 = NTI
		ldfs		shY = [shiftVPtr], 4
		nop			0x0
	}
	{	.mfi
		ldfs		PosY = [posPtr], 4
		nop			0x0
		nop			0x0		
	} ;;

	{	.mmf						
		ldfs		shZ = [shiftVPtr]
		ldfs		PosZ = [posPtr]
		mov			FIZ = f0
	}
	{	.mmi
		ldfs		FShiftX = [FShiftIS], 4
		ldfs		FActIX = [FActII], 4
		shladd		VNBPtr = ggid, 2, VNB
	} ;;
//	OUTER PROLOGUE 4
	{	.mmf	
		ldfs		FShiftY = [FShiftIS], 4
		ldfs		FActIY = [FActII], 4
		xma.l		f32 = f32, f33, fZero
	}
	{ 	.mmi
		sub			InnerCnt = NJ1, NJ0, 1
		ldfs		dVdASum = [dVdAIPtr]
		shladd		VCPtr = ggid, 2, VC
	} ;;
//	OUTER PROLOGUE 5
	{	.mmi
		ldfs		FActIZ = [FActII], -8
		ldfs		FShiftZ = [FShiftIS], -8
		mov			NJ0 = NJ1
	} ;;
//	OUTER PROLOGUE 6
	{	.mmf		
		ldfs		ICharge = [chargePtr], 4
		ldfs		VNBTotal = [VNBPtr]
		fadd		IX = shX, PosX
	} ;;
//	OUTER PROLOGUE 7
	{	.mfi
		ldfs		VCTotal = [VCPtr]
		fadd		IY = shY, PosY
		add			NN0 = 1, NN0
	}
	{	.mmi
	(pCont)	ld4		NJ1 = [jindexPtr], 4
		ldfs		isaI = [isaPtr], 4

		//	This may seem strange, but we set the first stage of the
		//	pipe to execute this way because setting pr.rot doesn't take
		//	into account how much the predicates have rotated. If this is
		//	the first time through, we cleared all the pipeline predicates
		//	in the initialization. If not, flushing the pipeline set all
		//	the pipeline predicates to 0

		cmp.eq		pPipe[0], p0 = zero, zero
	} ;;
//	OUTER PROLOGUE 8
	{	.mfi		
		cmp.lt		pCont, pDone = NN0, NN1
		fadd		IZ = shZ, PosZ
		mov		    ar.lc = InnerCnt
	} ;;
//	OUTER PROLOGUE 9
	{	.mfi		
		getf.sig	NTI = f32
		fmpy		IQ = ICharge, Facel
		mov			ar.ec = PIPE_DEPTH
	} ;;
// 14 bundles in outer loop - still aligned.

	//	The inner loop is a 6-stage pipeline. The serial sequence of float ops
	//	is folded into a 17-cycle loop (17 * 2 = 34 float ops, one empty), 
    //  then divided
	//	into 5 stages.



innerLoop:
//	INNER LOOP 1
	{	.mfi	
	(pPipe[0])	shladd	chargePtr = jnr, 2, CHARGE
	(pPipe[3])	fsub	VNBTotal = VNBTotal, C6[2]
	(pPipe[0])	shladd	jnr3 = jnr, 1, jnr
	}

	//	We march through jjnr[] sequentially, so it's usually a good idea
	//	to preload the next value. However, we don't want to do this if
	//	(1) we're in the epilogue or (2) this is the last time through and
	//	there are no more atoms to inspect. Thus, we keep track of the loop
	//	trip and use the logic below to see if we should load ahead

	.pred.rel "mutex", pCont, pDone
	{	.mfi
	(pCont)		cmp.ge	pJJNR, p0 = InnerCnt, zero
	(pPipe[4])	fma		F[2] = eps[1], G[2], F[2]
	(pDone)		cmp.gt	pJJNR, p0 = InnerCnt, zero
	} ;;
//	INNER LOOP 2
	{	.mfi	
				nop		0x0
	(pPipe[3])	fsub	eps[0] = RT[1], n0[1]
	(pPipe[0])	shladd	isaPtr = jnr, 2, INVSQRTA
	}
	{	.mfi
	(pPipe[0])	shladd	posPtr = jnr3, 2, POSITION
				nop		0x0
	(pPipe[0])	shladd	FActPtr[0] = jnr3, 2, FACTION
	} ;;
//	INNER LOOP 3
	{	.mfi									
	(pPipe[0])	ldfs	JX = [posPtr], 4
	(pPipe[2])	fmpy	RInv2[0] = RInv[1], RInv[1]
	(pPipe[0])	shladd  TypeJ[0] = jnr, 2, TYPE
	}
	{  	.mfi
				nop		0x0
	(pPipe[2])	fmpy	RInv[1] = RInv[1], isaJ[2]
	(pPipe[0])	shladd  dVdAPtr[0] = jnr, 2, DVDA
	} ;;
//	INNER LOOP 4
	{	.mfi	
	(pPipe[0])	ldfs	JY = [posPtr], 4
	(pPipe[1])	fma		RSqr[1] = DZ[1], DZ[1], RSqr[1]
	(pPipe[1])	add		TypeJ[1] = NTI, TypeJ[1]	
	}
	{	.mfi
	(pJJNR)		ld4		jnr = [jjnrPtr], 4
	(pPipe[3])	fnma	FScalar[0] = C6[2], fSIX, fZero
	(pPipe[0])	add		InnerCnt = -1, InnerCnt
	} ;;
//	INNER LOOP 5
	{	.mfi									
	(pPipe[0])	ldfs	JZ = [posPtr], 4
	(pPipe[4])	fmpy	FijGB[0] = Charge[4], F[2]
	(pPipe[0])	add	Ninner = 1, Ninner
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fma		dVdATmp = F[2], RT[2], Y[2]
				nop		0x0
	} ;;
//	INNER LOOP 6
	{	.mfi									
	(pPipe[0])	ldfs	isaJ[0] = [isaPtr]
	(pPipe[1])	fmpy	isaJ[1] = isaJ[1], isaI
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[3])	fadd	VNBTotal = VNBTotal, C12[2]
	(pJJNR)     add     jjnrPtr = JJNR_PREFETCH_DISTANCE, jjnrPtr
	} ;;
//	INNER LOOP 7
	{	.mfi									
	(pPipe[0])	ld4 	TypeJ[0] = [TypeJ[0]]			
	(pPipe[2])	fmpy	RT[0] =  RSqr[2], RInv[1] 
	(pPipe[1])	shladd	TypeJ[1] = TypeJ[1], 3, NBFP
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fmpy	RInv6[0] =  RInv2[0], RInv2[0] 
				nop		0x0
	} ;;
//	INNER LOOP 8
	{	.mfi									
	(pPipe[0])	ldfs	Charge[0] = [chargePtr]						
	(pPipe[1])	frsqrta RInv[0], p0 = RSqr[1]
				nop		0x0
	}
	{	.mfi
	(pJJNR)     lfetch.nta  [jjnrPtr]
	(pPipe[2])	fmpy	Charge[2] = IQ, Charge[2]
				nop		0x0
	} ;;
//	INNER LOOP 9
	{	.mfi									
	(pPipe[2])	ldfs	FActX[0] = [FActPtr[2]], 4
	(pPipe[3])	fma		FScalar[0] = C12[2], fTWELVE, FScalar[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fnma	FScalar[1] = FijGB[0], RInv[3], FScalar[1]
				nop		0x0
	} ;;
//	INNER LOOP 10
	{	.mfi									
	(pPipe[2])	ldfs	FActY[0] = [FActPtr[2]], 4
	(pPipe[4])	fnma.s	dVdAJ[2] = Charge[4], dVdATmp, dVdAJ[2]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fnma	dVdASum = Charge[4], dVdATmp, dVdASum
				nop		0x0
	} ;;
//	INNER LOOP 11
	{	.mfi									
	(pPipe[2])	ldfs	FActZ[0] = [FActPtr[2]], -8
	(pPipe[2])	fmpy	RInv6[0] =  RInv6[0], RInv2[0] 
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fcvt.fx.trunc n0[0] = RT[0]
	(pJJNR)     add     jjnrPtr = -JJNR_PREFETCH_DISTANCE, jjnrPtr
	} ;;
//	INNER LOOP 12
	{	.mfi									
	(pPipe[1])	ldfs	C6[0] = [TypeJ[1]], 4			
	(pPipe[1])	fmpy	RInvErr[0] = RInv[0], RSqr[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fma		VCTotal = Charge[4], Y[2], VCTotal	
				nop		0x0
	} ;;
//	INNER LOOP 13
	{	.mfi									
	(pPipe[1])	ldfs	C12[0] = [TypeJ[1]]
	(pPipe[1])	fmpy	Charge[1] = Charge[1], isaJ[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fnma.s	FActX[2] = FScalar[1], DX[4], FActX[2]	
				nop		0x0
	} ;;
//	INNER LOOP 14
	{	.mfi									
	(pPipe[2])	ldfs	dVdAJ[0] = [dVdAPtr[2]]		
	(pPipe[1])	fmpy	isaJ[1] = isaJ[1], GBTabscale
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fnma.s	FActY[2] = FScalar[1], DY[4], FActY[2]	
				nop		0x0
	} ;;
//	INNER LOOP 15
	{	.mfi									
				nop		0x0
	(pPipe[2])	fmpy	C6[1] = C6[1], RInv6[0]
				nop		0x0
	}
	{	.mfi
	(pPipe[2])	getf.sig nnn = n0[0]
	(pPipe[2])	fcvt.xf n0[0] = n0[0]
				nop		0x0
	} ;;

//	INNER LOOP 16
	{	.mfi									
	(pPipe[4])	stfs	[dVdAPtr[4]] = dVdAJ[2]		
	(pPipe[1])	fnma	RInvErr[0] = RInvErr[0], RInv[0], fOne
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fmpy	RInv6[0] =  RInv6[0], RInv6[0] 
				nop		0x0
	} ;;
//	INNER LOOP 17
	{	.mfi									
				nop		0x0
	(pPipe[0])	fsub	DX[0] = IX, DX[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[3])	fma		G[1] = eps[0], H[1], G[1]
				nop		0x0
	} ;;
//	INNER LOOP 18
	{	.mfi									
				nop		0x0
	(pPipe[0])	fsub	DY[0] = IY, DY[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fnma.s	FActZ[2] = FScalar[1], DZ[4], FActZ[2]	
				nop		0x0
	} ;;
//	INNER LOOP 19
	{	.mfi									
				nop		0x0
	(pPipe[0])	fsub	DZ[0] = IZ, DZ[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fma 	FIX = DX[4], FScalar[1], FIX
				nop		0x0
	} ;;
//	INNER LOOP 20
	{	.mfi									
				nop		0x0
	(pPipe[1])	fma		RInvT[0] = RInvErr[0], f3_8, fHALF
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[1])	fmpy	RInvU[0] = RInv[0], RInvErr[0]
				nop		0x0
	} ;;
//	INNER LOOP 21
	{	.mfi									
				nop		0x0
	(pPipe[0])	fmpy	RSqr[0] = DX[0], DX[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fmpy	C12[1] = C12[1], RInv6[0]
				nop		0x0
	} ;;
//	INNER LOOP 22
	{	.mfi									
				nop		0x0
	(pPipe[3])	fma		F[1] = eps[0], G[1], F[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[3])	fma		G[1] = eps[0], H[1], G[1]
				nop		0x0
	} ;;
//	INNER LOOP 23
	{	.mfi									
	(pPipe[4])	stfs	[FActPtr[4]] = FActX[2], 4				
	(pPipe[3])	fmpy	FScalar[0] = FScalar[0], RInv2[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fma 	FIY = DY[4], FScalar[1], FIY
	(pPipe[2])	shladd  nnn = nnn, 4, GBTab
	} ;;
//	INNER LOOP 24
	{	.mfi									
	(pPipe[4])	stfs	[FActPtr[4]] = FActY[2], 4							
	(pPipe[1])	fma		RInv[0] = RInvU[0], RInvT[0], RInv[0]		
				nop		0x0
	}
	{	.mfi
	(pPipe[2])	ldfps	Y[0], F[0] = [nnn], 8
	(pPipe[4])	fma 	FIZ = DZ[4], FScalar[1], FIZ
				nop		0x0
	} ;;
//	INNER LOOP 25
	{	.mfi									
	(pPipe[4])	stfs	[FActPtr[4]] = FActZ[2]
	(pPipe[0])	fma		RSqr[0] = DY[0], DY[0], RSqr[0]
				nop		0x0
	}
	{	.mfb
	(pPipe[2])	ldfps	G[0], H[0] = [nnn]
	(pPipe[3])	fma     Y[1] = eps[0], F[1], Y[1]
			br.ctop.sptk.many	innerLoop					
	} ;;

// 	End of modulo-scheduled inner loop

	//	Having finshed the loop, we now compute various quantities to
	//	store. In paralllel, start computing computing some of the values
	//	for the next loop trip, if we're going there.

//	OUTER EPILOGUE 1
    {   .mfi
	(pCont)	shladd		typePtr = II, 2, TYPE
	    fnorm.s 		VCTotal = VCTotal
	(pCont)	shladd		II3 = II, 1, II
    }
	{	.mfi								
	(pCont)	shladd		chargePtr = II, 2, CHARGE
	    fnorm.s 		VNBTotal = VNBTotal
	(pCont)	shladd		IS3 = IS, 1, IS
    } ;;
//	OUTER EPILOGUE 2
	{	.mfi
		nop				0x0
		fnorm.s			dVdASum = dVdASum
		nop				0x0
	} ;;
//	OUTER EPILOGUE 3
    {   .mfi
	(pCont)	ld4			IS = [shiftPtr], 4
			fadd.s		FActIX = FActIX, FIX
	(pCont)	shladd 		isaPtr = II, 2, INVSQRTA
	}
    {   .mmf
	(pCont)	setf.sig	f33 = NTYPE
			nop			0x0
			fadd.s		FShiftX = FShiftX, FIX
	} ;;
// 	OUTER EPILOGUE 4
    {   .mfi
	(pCont)	ld4				NTI = [typePtr]	  	
		fadd.s	FActIY = FActIY, FIY
	(pCont)	shladd	shiftVPtr = IS3, 2, SHIFTVEC						
	} 
    {   .mfi
		nop 0x0
		fadd.s	FShiftY = FShiftY, FIY
	(pCont)	shladd	posPtr = II3, 2, POSITION
	} ;;
//	OUTER EPILOGUE 5
    {   .mfi
		nop 	0x0
		fadd.s	FActIZ = FActIZ, FIZ
		nop 	0x0
	} 
    {   .mfi
		nop 	0x0
		fadd.s	FShiftZ = FShiftZ, FIZ		
		nop 	0x0
	} ;;
//	OUTER EPILOGUE 6
	{	.mmi
		stfs	[FActII] = FActIX, 4
		stfs	[FShiftIS] = FShiftX, 4
		nop 	0x0
	}
    {   .mmi
		stfs    [VCPtr] = VCTotal
	(pCont)		ld4     ggid = [gidPtr], 4 
		nop 	0x0
	} ;;
//	OUTER EPILOGUE 7
	{	.mmi
		stfs	[dVdAIPtr] = dVdASum
		stfs	[FActII] = FActIY, 4
		shladd	dVdAIPtr = II, 2, DVDA
	} 
	{	.mmi
		stfs	[FShiftIS] = FShiftY, 4
	(pCont)	ld4	II = [iinrPtr] ,4
		nop		0x0
	} ;;
//	OUTER EPILOGUE 8
	{	.mmi
		stfs	[FActII] = FActIZ
		stfs    [VNBPtr] = VNBTotal
	(pCont)	shladd	FActII = II3, 2, FACTION
	}
	{	.mib
		stfs	[FShiftIS] = FShiftZ
	(pCont)	shladd	FShiftIS = IS3, 2, FSHIFT
	(pCont)	br.cond.sptk.many	outerLoop
	} ;;



	// Finish if this was the last chunk, or do another thread-loop iteration
//  THREAD EPILOGUE 1
	{ .mib				
		nop				0x0
		nop				0x0
	(pMore) br.cond.sptk.many threadLoop
	} ;;
	


	//	Ready to exit - restore the floating-point registers we saved, the
	//	loop counter, and the predicates, then we're done. Note that the
	//	stack pointer has the address of the last saved FP register.

finish:
//  EXIT 1
	{	.mmi
		mov			fillP0 = sp
		add			fillP1 = 16, sp
		nop			0x0
	} 
	{	.mmi
		st4			[OuterIter] = Nouter
		st4			[InnerIter] = Ninner
		nop			0x0
	};;
//  EXIT 2
	{	.mmi
		ldf.fill		fs13 = [fillP0], 32
		ldf.fill		fs12 = [fillP1], 32
		nop				0x0
	} ;;
//  EXIT 3
	{	.mmi
		ldf.fill		fs11 = [fillP0], 32
		ldf.fill		fs10 = [fillP1], 32
		nop				0x0
	} ;;
//  EXIT 4
	{	.mmi
		ldf.fill		fs9 = [fillP0], 32
		ldf.fill		fs8 = [fillP1], 32
		nop				0x0
	} ;;
//  EXIT 5
	{	.mmi
		ldf.fill		fs7 = [fillP0], 32
		ldf.fill		fs6 = [fillP1], 32
		add				sp = 13 * 16, sp
	} ;;
//  EXIT 6
	{	.mmi
		ldf.fill		fs5 = [fillP0], 32
		ldf.fill		fs4 = [fillP1], 32
		mov				ar.lc = LCSave
	} ;;
//  EXIT 7
	{	.mmi
		ldf.fill		fs3 = [fillP0], 32
		ldf.fill		fs2 = [fillP1], 32
		mov				pr = PRSave, 0x1ffff
	} ;;
//  EXIT 8
	{	.mmb
		ldf.fill		fs1 = [fillP0], 32
		ldf.fill		fs0 = [fillP1], 32
		br.ret.sptk.few	rp
	} ;;

	.endp	 nb_kernel410_ia64_single