nb_kernel400_ia64_single.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,021 行 · 第 1/2 页

		nop				0x0
	}	
	{ .mmi
	(pCont) ld4			II = [iinrPtr], 4
			nop			0x0
	(pLast)	mov			NN1 = NRI
	} ;;
//  12 bundles in thread prologue - still aligned





outerLoop:
	//	At this point in the outer loop, the following values are ready
	//
	//		FActII		Pointer to FACTION XYZ for II
	//		FShiftIS	Pointer to FSHIFT XYZ for IS
	//		shiftVPtr	Pointer to current shift XYZ values
	//		posPtr		Pointer to current XYZ position
	//		chargePtr	Pointer to current atom charge
	//		ggid		Index for Vc array
	//		jjnr		Pointer to next neighbor index
	//		jnr			Current jnr value
	//		NJ0, NJ1	Bounds of current neighbor list
	//
	//	Load up all the floating-point values (yes, McKinley can do 4 FP loads
	//	per cycle) and initialize the loop counters and predicates. Compute
	//	the initial position <x, y, z> and charge. If this isn't the last time
	//	through the loop, start loading the next value for NJ1 - we already
	//	moved the previous NJ1 -> NJ0.
//	OUTER PROLOGUE 1
	{	.mfi						
		nop 		0x0
		mov			FIX = f0
		add		Nouter = 1, Nouter
	}
	{	.mmf
		ldfs		shX = [shiftVPtr], 4
		ldfs		PosX = [posPtr], 4
		mov			FIY = f0
	} ;;
//	OUTER PROLOGUE 2
	{	.mmf
		nop			0x0
		ldfs		shY = [shiftVPtr], 4
		nop			0x0
	}
	{	.mfi
		ldfs		PosY = [posPtr], 4
		nop			0x0
		nop			0x0		
	} ;;

	{	.mmf						
		ldfs		shZ = [shiftVPtr]
		ldfs		PosZ = [posPtr]
		mov			FIZ = f0
	}
	{	.mmi
		ldfs		FShiftX = [FShiftIS], 4
		ldfs		FActIX = [FActII], 4
		nop			0x0
	} ;;
//	OUTER PROLOGUE 4
	{	.mmf	
		ldfs		FShiftY = [FShiftIS], 4
		ldfs		FActIY = [FActII], 4
		nop			0x0
	}
	{ 	.mmi
		sub			InnerCnt = NJ1, NJ0, 1
		ldfs		dVdASum = [dVdAIPtr]
		shladd		VCPtr = ggid, 2, VC
	} ;;
//	OUTER PROLOGUE 5
	{	.mmi
		ldfs		FActIZ = [FActII], -8
		ldfs		FShiftZ = [FShiftIS], -8
		mov			NJ0 = NJ1
	} ;;
//	OUTER PROLOGUE 6
	{	.mmf		
		ldfs		ICharge = [chargePtr], 4
		nop			0x0
		fadd		IX = shX, PosX
	} ;;
//	OUTER PROLOGUE 7
	{	.mfi
		ldfs		VCTotal = [VCPtr]
		fadd		IY = shY, PosY
		add			NN0 = 1, NN0
	}
	{	.mmi
	(pCont)	ld4		NJ1 = [jindexPtr], 4
		ldfs		isaI = [isaPtr], 4

		//	This may seem strange, but we set the first stage of the
		//	pipe to execute this way because setting pr.rot doesn't take
		//	into account how much the predicates have rotated. If this is
		//	the first time through, we cleared all the pipeline predicates
		//	in the initialization. If not, flushing the pipeline set all
		//	the pipeline predicates to 0

		cmp.eq		pPipe[0], p0 = zero, zero
	} ;;
//	OUTER PROLOGUE 8
	{	.mfi		
		cmp.lt		pCont, pDone = NN0, NN1
		fadd		IZ = shZ, PosZ
		mov		    ar.lc = InnerCnt
	} ;;
//	OUTER PROLOGUE 9
	{	.mfi		
		nop			0x0
		fmpy		IQ = ICharge, Facel
		mov			ar.ec = PIPE_DEPTH
	} ;;
// 14 bundles in outer loop - still aligned.

	//	The inner loop is a 6-stage pipeline. The serial sequence of float ops
	//	is folded into a 17-cycle loop (17 * 2 = 34 float ops, one empty), 
    //  then divided
	//	into 5 stages.



innerLoop:
//	INNER LOOP 1
	{	.mfi	
	(pPipe[0])	shladd	chargePtr = jnr, 2, CHARGE
	(pPipe[5])	fma     Y[2] = eps[1], F[2], Y[2]
	(pPipe[0])	shladd	jnr3 = jnr, 1, jnr
	}

	//	We march through jjnr[] sequentially, so it's usually a good idea
	//	to preload the next value. However, we don't want to do this if
	//	(1) we're in the epilogue or (2) this is the last time through and
	//	there are no more atoms to inspect. Thus, we keep track of the loop
	//	trip and use the logic below to see if we should load ahead

	.pred.rel "mutex", pCont, pDone

	{	.mfi
	(pCont)		cmp.ge	pJJNR, p0 = InnerCnt, zero
	(pPipe[5])	fma		F[2] = eps[1], G[2], F[2]
	(pDone)		cmp.gt	pJJNR, p0 = InnerCnt, zero
	} ;;
//	INNER LOOP 2
	{	.mfi	
				nop		0x0
	(pPipe[1])	fmpy	RSqr[0] = DX[1], DX[1]
	(pPipe[0])	shladd	isaPtr = jnr, 2, INVSQRTA
	}
	{	.mfi
	(pPipe[0])	shladd	posPtr = jnr3, 2, POSITION
	(pPipe[2])	fmpy	Charge[2] = Charge[2], isaJ[2]
	(pPipe[0])	shladd	FActPtr[0] = jnr3, 2, FACTION
	} ;;
//	INNER LOOP 3
	{	.mfi									
	(pPipe[0])	ldfs	JX = [posPtr], 4
	(pPipe[2])	fnma	RInvErr[1] = RInvErr[1], RInv[1], fOne
	(pPipe[0])	add	Ninner = 1, Ninner
	}
	{  	.mfi
				nop		0x0
	(pPipe[4])	fsub	eps[0] = RT[2], n0[1]
	(pPipe[0])	shladd  dVdAPtr[0] = jnr, 2, DVDA
	} ;;
//	INNER LOOP 4
	{	.mfi	
	(pPipe[0])	ldfs	JY = [posPtr], 4
	(pPipe[1])	fmpy	isaJ[1] = isaJ[1], isaI
				nop		0x0
	}
	{	.mfi
	(pJJNR)		ld4		jnr = [jjnrPtr], 4
	(pPipe[3])	fcvt.fx.trunc n0[0] = RT[1]
	(pPipe[0])	add		InnerCnt = -1, InnerCnt

	} ;;
//	INNER LOOP 5
	{	.mfi									
	(pPipe[0])	ldfs	JZ = [posPtr], 4
	(pPipe[5])	fma		dVdATmp = F[2], RT[3], Y[2]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fnma	F[2] = F[2], RInv[4], fZero
				nop		0x0
	} ;;
//	INNER LOOP 6
	{	.mfi									
	(pPipe[0])	ldfs	isaJ[0] = [isaPtr]
	(pPipe[1])	fma		RSqr[0] = DY[1], DY[1], RSqr[0]
	(pJJNR)     add     jjnrPtr = JJNR_PREFETCH_DISTANCE, jjnrPtr
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fmpy	isaJ[2] = isaJ[2], GBTabscale
				nop		0x0
	} ;;
//	INNER LOOP 7
	{	.mfi									
	(pPipe[0])	ldfs	Charge[0] = [chargePtr]						
	(pPipe[2])	fma		RInvT[0] = RInvErr[1], f3_8, fHALF
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[2])	fmpy	RInvU[0] = RInv[1], RInvErr[1]
				nop		0x0
	} ;;
//	INNER LOOP 8
	{	.mfi									
	(pPipe[3])	ldfs	FActX[0] = [FActPtr[3]], 4
	(pPipe[5])	fma		VCTotal = Y[2], Charge[5], VCTotal
				nop		0x0
	}
	{	.mfi
	(pPipe[3])	getf.sig nnn = n0[0]
	(pPipe[3])	fcvt.xf n0[0] = n0[0]
				nop		0x0
	} ;;
//	INNER LOOP 9
	{	.mfi									
	(pPipe[3])	ldfs	FActY[0] = [FActPtr[3]], 4
	(pPipe[4])	fmpy	RInv[3] = RInv[3], Charge[4]
				nop		0x0
	}
	{	.mfi
	(pJJNR)     lfetch.nta  [jjnrPtr]
	(pPipe[5])	fnma.s	FActX[2] = F[2], DX[5], FActX[2]
				nop		0x0
	} ;;
//	INNER LOOP 10
	{	.mfi									
	(pPipe[3])	ldfs	FActZ[0] = [FActPtr[3]], -8
	(pPipe[1])	fma		RSqr[0] = DZ[1], DZ[1], RSqr[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fnma.s	FActY[2] = F[2], DY[5], FActY[2]
	(pJJNR)     add     jjnrPtr = -JJNR_PREFETCH_DISTANCE, jjnrPtr
	} ;;
//	INNER LOOP 11
	{	.mfi				
	(pPipe[0])	ldfs	dVdAJ[0] = [dVdAPtr[0]]		
	(pPipe[2])	fma		RInv[1] = RInvU[0], RInvT[0], RInv[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fnma.s	FActZ[2] = F[2], DZ[5], FActZ[2]
				nop		0x0
	} ;;
//	INNER LOOP 12
	{	.mfi									
				nop		0x0
	(pPipe[4])	fma		G[1] = eps[0], H[1], G[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fnma.s	dVdAJ[5] = Charge[5], dVdATmp, dVdAJ[5]
				nop		0x0
	} ;;
//	INNER LOOP 13
	{	.mfi										
				nop		0x0
	(pPipe[5])	fma 	FIX = DX[5], F[2], FIX
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fma 	FIY = DY[5], F[2], FIY
				nop		0x0
	} ;;
//	INNER LOOP 14
	{	.mfi									
				nop		0x0
	(pPipe[1])	frsqrta RInv[0], p0 = RSqr[0]
	(pPipe[3])	shladd	nnn = nnn, 4, GBTab
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fma 	FIZ = DZ[5], F[2], FIZ
				nop		0x0
	} ;;
//	INNER LOOP 15
	{	.mfi									
	(pPipe[3])	ldfps	Y[0], F[0] = [nnn], 8
	(pPipe[2])	fmpy	RInv[1] = RInv[1], isaJ[2]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[5])	fnma	dVdASum = Charge[5], dVdATmp, dVdASum
				nop		0x0
	} ;;
//	INNER LOOP 16
	{	.mfi									
	(pPipe[3])	ldfps	G[0], H[0] = [nnn]
	(pPipe[4])	fma		F[1] = eps[0], G[1], F[1]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[4])	fma		G[1] = eps[0], H[1], G[1]
				nop		0x0
	} ;;
//	INNER LOOP 17
	{	.mfi									
	(pPipe[5])	stfs	[dVdAPtr[5]] = dVdAJ[5]	
	(pPipe[0])	fsub	DX[0] = IX, DX[0]
				nop		0x0
	}
	{	.mfi
	(pPipe[5])	stfs	[FActPtr[5]] = FActX[2], 4		
	(pPipe[3])	fmpy	Charge[3] = IQ, Charge[3]
				nop		0x0
	} ;;
//	INNER LOOP 18
	{	.mfi								
	(pPipe[5])	stfs	[FActPtr[5]] = FActY[2], 4				
	(pPipe[0])	fsub	DY[0] = IY, DY[0]
				nop		0x0
	}
	{	.mfi
				nop		0x0
	(pPipe[1])	fmpy	RInvErr[0] = RInv[0], RSqr[0]
				nop		0x0
	} ;;
//	INNER LOOP 19
	{	.mfi									
	(pPipe[5])	stfs	[FActPtr[5]] = FActZ[2]
	(pPipe[0])	fsub	DZ[0] = IZ, DZ[0]
				nop		0x0
	}
	{	.mfb
				nop		0x0
	(pPipe[2])	fmpy	RT[0] =  RSqr[1], RInv[1] 
		br.ctop.sptk.many	innerLoop
	} ;;

// 	End of modulo-scheduled inner loop


	//	Having finshed the loop, we now compute various quantities to
	//	store. In paralllel, start computing computing some of the values
	//	for the next loop trip, if we're going there.

//	OUTER EPILOGUE 1
    {   .mfi
			nop		0x0
	    fnorm.s 	VCTotal = VCTotal
	(pCont)	shladd	II3 = II, 1, II
    }
	{	.mfi								
	(pCont)	shladd	chargePtr = II, 2, CHARGE
	    	nop		0x0
	(pCont)	shladd	IS3 = IS, 1, IS
    } ;;
//	OUTER EPILOGUE 2
	{	.mfi
		nop			0x0
		fnorm.s		dVdASum = dVdASum
		nop			0x0
	} ;;
//	OUTER  EPILOGUE 3
    {   .mfi
	(pCont)	ld4		IS = [shiftPtr], 4
			fadd.s	FActIX = FActIX, FIX
	(pCont)	shladd 	isaPtr = II, 2, INVSQRTA
	}
    {   .mmf
			nop		0x0
			nop		0x0
			fadd.s	FShiftX = FShiftX, FIX
	} ;;
// 	OUTER EPILOGUE 4
    {   .mfi
			nop		0x0
			fadd.s	FActIY = FActIY, FIY
	(pCont)	shladd	shiftVPtr = IS3, 2, SHIFTVEC						
	} 
    {   .mfi
			nop 	0x0
			fadd.s	FShiftY = FShiftY, FIY
	(pCont)	shladd	posPtr = II3, 2, POSITION
	} ;;
//	OUTER EPILOGUE 5
    {   .mfi
			nop 	0x0
			fadd.s	FActIZ = FActIZ, FIZ
			nop 	0x0
	} 
    {   .mfi
			nop 	0x0
			fadd.s	FShiftZ = FShiftZ, FIZ		
			nop 	0x0
	} ;;
//	OUTER EPILOGUE 6
	{	.mmi
			stfs	[FActII] = FActIX, 4
			stfs	[FShiftIS] = FShiftX, 4
			nop 	0x0
	}
    {   .mmi
			stfs    [VCPtr] = VCTotal
	(pCont)	ld4     ggid = [gidPtr], 4 
			nop 	0x0
	} ;;
//	OUTER EPILOGUE 7
	{	.mmi
			stfs	[dVdAIPtr] = dVdASum
			stfs	[FActII] = FActIY, 4
			shladd	dVdAIPtr = II, 2, DVDA
	} 
	{	.mmi
			stfs	[FShiftIS] = FShiftY, 4
	(pCont)	ld4		II = [iinrPtr] ,4
			nop		0x0
	} ;;
//	OUTER EPILOGUE 8
	{	.mmi
			stfs	[FActII] = FActIZ
			nop		0x0
	(pCont)	shladd	FActII = II3, 2, FACTION
	}
	{	.mib
		stfs	[FShiftIS] = FShiftZ
	(pCont)	shladd	FShiftIS = IS3, 2, FSHIFT
	(pCont)	br.cond.sptk.many	outerLoop
	} ;;



	// Finish if this was the last chunk, or do another thread-loop iteration
//  THREAD EPILOGUE 1
	{ .mib				
		nop				0x0
		nop				0x0
	(pMore) br.cond.sptk.many threadLoop
	} ;;
	


	//	Ready to exit - restore the floating-point registers we saved, the
	//	loop counter, and the predicates, then we're done. Note that the
	//	stack pointer has the address of the last saved FP register.

finish:
//  EXIT 1
	{	.mmi
		mov			fillP0 = sp
		add			fillP1 = 16, sp
		nop			0x0
	} 
	{	.mmi
		st4			[OuterIter] = Nouter
		st4			[InnerIter] = Ninner
		nop			0x0
	}  ;;
//  EXIT 2
	{	.mmi
		ldf.fill		fs10 = [fillP0], 32
		ldf.fill		fs9 = [fillP1], 32
		nop				0x0
	} ;;
//  EXIT 3
	{	.mmi
		ldf.fill		fs8 = [fillP0], 32
		ldf.fill		fs7 = [fillP1], 32
		nop				0x0
	} ;;
//  EXIT 4
	{	.mmi
		ldf.fill		fs6 = [fillP0], 32
		ldf.fill		fs5 = [fillP1], 32
		add				sp = 10 * 16, sp
	} ;;
//  EXIT 5
	{	.mmi
		ldf.fill		fs4 = [fillP0], 32
		ldf.fill		fs3 = [fillP1], 32
		mov				ar.lc = LCSave
	} ;;
//  EXIT 6
	{	.mmi
		ldf.fill		fs2 = [fillP0], 32
		ldf.fill		fs1 = [fillP1], 32
		mov				pr = PRSave, 0x1ffff
	} ;;
//  EXIT 7
	{	.mmb
		ldf.fill		fs0 = [fillP0]
		nop				0x0
		br.ret.sptk.few	rp
	} ;;

	.endp	 nb_kernel400_ia64_single