nb_kernel410_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,987 行 · 第 1/4 页

        ## xmm6=(vcoul+fijC*r)
        subss  %xmm6,%xmm7
        movaps %xmm7,%xmm6

    ## update dvdasum
    addss  nb410_dvdasum(%rsp),%xmm7
    movss %xmm7,nb410_dvdasum(%rsp)

        ## update j atoms dvdaj
        addss  (%rsi,%rax,4),%xmm6
        movss  %xmm6,(%rsi,%rax,4)

    subss  %xmm3,%xmm9
    mulss  %xmm0,%xmm9 ## fscal

    movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

    mulss   nb410_dx(%rsp),%xmm9
    mulss   nb410_dy(%rsp),%xmm10
    mulss   nb410_dz(%rsp),%xmm11

        ## accumulate i forces
    addss %xmm9,%xmm13
    addss %xmm10,%xmm14
    addss %xmm11,%xmm15

        movq nb410_faction(%rbp),%rsi
    ## add to j forces
    addss  (%rsi,%r8,4),%xmm9
    addss  4(%rsi,%r8,4),%xmm10
    addss  8(%rsi,%r8,4),%xmm11
    movss  %xmm9,(%rsi,%r8,4)
    movss  %xmm10,4(%rsi,%r8,4)
    movss  %xmm11,8(%rsi,%r8,4)

_nb_kernel410_x86_64_sse.nb410_updateouterdata: 
        movl  nb410_ii3(%rsp),%ecx
        movq  nb410_faction(%rbp),%rdi
        movq  nb410_fshift(%rbp),%rsi
        movl  nb410_is3(%rsp),%edx

        ## accumulate i forces in xmm13, xmm14, xmm15
        movhlps %xmm13,%xmm0
        movhlps %xmm14,%xmm1
        movhlps %xmm15,%xmm2
        addps  %xmm13,%xmm0
        addps  %xmm14,%xmm1
        addps  %xmm15,%xmm2
    movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 


        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## increment fshift force  
        movss  (%rsi,%rdx,4),%xmm3
        movss  4(%rsi,%rdx,4),%xmm4
        movss  8(%rsi,%rdx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,4(%rsi,%rdx,4)
        movss  %xmm5,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb410_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb410_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        ## accumulate 
        movhlps %xmm12,%xmm6
        addps  %xmm6,%xmm12     ## pos 0-1 in xmm12 have the sum now 
        movaps %xmm12,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm12

        ## add earlier value from mem 
        movq  nb410_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm12
        ## move back to mem 
        movss %xmm12,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb410_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb410_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate dVda and update it 
        movaps nb410_dvdasum(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        movl nb410_ii(%rsp),%edx
        movq nb410_dvda(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb410_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel410_x86_64_sse.nb410_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb410_n(%rsp)
        jmp _nb_kernel410_x86_64_sse.nb410_outer
_nb_kernel410_x86_64_sse.nb410_outerend: 
        ## check if more outer neighborlists remain
        movl  nb410_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel410_x86_64_sse.nb410_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel410_x86_64_sse.nb410_threadloop
_nb_kernel410_x86_64_sse.nb410_end: 

        movl nb410_nouter(%rsp),%eax
        movl nb410_ninner(%rsp),%ebx
        movq nb410_outeriter(%rbp),%rcx
        movq nb410_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $568,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret



.globl nb_kernel410nf_x86_64_sse
.globl _nb_kernel410nf_x86_64_sse
nb_kernel410nf_x86_64_sse:      
_nb_kernel410nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb410nf_fshift, 16
.set nb410nf_gid, 24
.set nb410nf_pos, 32
.set nb410nf_faction, 40
.set nb410nf_charge, 48
.set nb410nf_p_facel, 56
.set nb410nf_argkrf, 64
.set nb410nf_argcrf, 72
.set nb410nf_Vc, 80
.set nb410nf_type, 88
.set nb410nf_p_ntype, 96
.set nb410nf_vdwparam, 104
.set nb410nf_Vvdw, 112
.set nb410nf_p_tabscale, 120
.set nb410nf_VFtab, 128
.set nb410nf_invsqrta, 136
.set nb410nf_dvda, 144
.set nb410nf_p_gbtabscale, 152
.set nb410nf_GBtab, 160
.set nb410nf_p_nthreads, 168
.set nb410nf_count, 176
.set nb410nf_mtx, 184
.set nb410nf_outeriter, 192
.set nb410nf_inneriter, 200
.set nb410nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb410nf_ix, 0
.set nb410nf_iy, 16
.set nb410nf_iz, 32
.set nb410nf_iq, 48
.set nb410nf_gbtsc, 64
.set nb410nf_qq, 80
.set nb410nf_c6, 96
.set nb410nf_c12, 112
.set nb410nf_vctot, 128
.set nb410nf_Vvdwtot, 144
.set nb410nf_half, 160
.set nb410nf_three, 176
.set nb410nf_isai, 192
.set nb410nf_isaprod, 208
.set nb410nf_gbscale, 224
.set nb410nf_nri, 240
.set nb410nf_iinr, 248
.set nb410nf_jindex, 256
.set nb410nf_jjnr, 264
.set nb410nf_shift, 272
.set nb410nf_shiftvec, 280
.set nb410nf_facel, 288
.set nb410nf_innerjjnr, 296
.set nb410nf_is3, 304
.set nb410nf_ii3, 308
.set nb410nf_ntia, 312
.set nb410nf_innerk, 316
.set nb410nf_n, 320
.set nb410nf_nn1, 324
.set nb410nf_ntype, 328
.set nb410nf_nouter, 332
.set nb410nf_ninner, 336

        push %rbp
        movq %rsp,%rbp
        push %rbx


        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $360,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb410nf_nouter(%rsp)
        movl %eax,nb410nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb410nf_nri(%rsp)
        movq %rsi,nb410nf_iinr(%rsp)
        movq %rdx,nb410nf_jindex(%rsp)
        movq %rcx,nb410nf_jjnr(%rsp)
        movq %r8,nb410nf_shift(%rsp)
        movq %r9,nb410nf_shiftvec(%rsp)
        movq nb410nf_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb410nf_ntype(%rsp)
        movq nb410nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb410nf_facel(%rsp)

        movq nb410nf_p_gbtabscale(%rbp),%rbx
        movss (%rbx),%xmm4
        shufps $0,%xmm4,%xmm4
        movaps %xmm4,nb410nf_gbtsc(%rsp)


        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb410nf_half(%rsp)
        movss nb410nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb410nf_half(%rsp)
        movaps %xmm3,nb410nf_three(%rsp)

_nb_kernel410nf_x86_64_sse.nb410nf_threadloop: 
        movq  nb410nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel410nf_x86_64_sse.nb410nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel410nf_x86_64_sse.nb410nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb410nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb410nf_n(%rsp)
        movl %ebx,nb410nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel410nf_x86_64_sse.nb410nf_outerstart
        jmp _nb_kernel410nf_x86_64_sse.nb410nf_end

_nb_kernel410nf_x86_64_sse.nb410nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb410nf_nouter(%rsp),%ebx
        movl %ebx,nb410nf_nouter(%rsp)

_nb_kernel410nf_x86_64_sse.nb410nf_outer: 
        movq  nb410nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx        ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb410nf_is3(%rsp)            ## store is3 

        movq  nb410nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb410nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx,%rsi,4),%ebx            ## ebx =ii

        movq  nb410nf_charge(%rbp),%rdx
        movss (%rdx,%rbx,4),%xmm3
        mulss nb410nf_facel(%rsp),%xmm3
        shufps $0,%xmm3,%xmm3

        movq  nb410nf_invsqrta(%rbp),%rdx       ## load invsqrta[ii]
        movss (%rdx,%rbx,4),%xmm4
        shufps $0,%xmm4,%xmm4

        movq  nb410nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb410nf_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb410nf_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb410nf_pos(%rbp),%rax      ## rax = base of pos[]  

        addss (%rax,%rbx,4),%xmm0
        addss 4(%rax,%rbx,4),%xmm1
        addss 8(%rax,%rbx,4),%xmm2

        movaps %xmm3,nb410nf_iq(%rsp)
        movaps %xmm4,nb410nf_isai(%rsp)

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb410nf_ix(%rsp)
        movaps %xmm1,nb410nf_iy(%rsp)
        movaps %xmm2,nb410nf_iz(%rsp)

        movl  %ebx,nb410nf_ii3(%rsp)

        ## clear vctot
        xorps %xmm4,%xmm4
        movaps %xmm4,nb410nf_vctot(%rsp)
        movaps %xmm4,nb410nf_Vvdwtot(%rsp)

        movq  nb410nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx             ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx            ## jindex[n+1] 
        subl  %ecx,%edx              ## number of innerloop atoms 

        movq  nb410nf_pos(%rbp),%rsi
        movq  nb410nf_faction(%rbp),%rdi
        movq  nb410nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb410nf_innerjjnr(%rsp)       ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb410nf_ninner(%rsp),%ecx
        movl  %ecx,nb410nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb410nf_innerk(%rsp)      ## number of innerloop atoms 
        jge   _nb_kernel410nf_x86_64_sse.nb410nf_unroll_loop
        jmp   _nb_kernel410nf_x86_64_sse.nb410nf_finish_inner
_nb_kernel410nf_x86_64_sse.nb410nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb410nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 
        addq $16,nb410nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        ## load isa2
        movq nb410nf_invsqrta(%rbp),%rsi
        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7
        movaps nb410nf_isai(%rsp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        mulps  %xmm3,%xmm2

        movaps %xmm2,nb410nf_isaprod(%rsp)
        movaps %xmm2,%xmm1
        mulps nb410nf_gbtsc(%rsp),%xmm1
        movaps %xmm1,nb410nf_gbscale(%rsp)

        movq nb410nf_charge(%rbp),%rsi     ## base of charge[] 

        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7

        mulps nb410nf_iq(%rsp),%xmm2
        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        mulps  %xmm2,%xmm3
        movaps %xmm3,nb410nf_qq(%rsp)

        movd %eax,%mm0
        movd %ebx,%mm1
        movd %ecx,%mm2
        movd %edx,%mm3

        movq nb410nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movl (%rsi,%rcx,4),%ecx
        movl (%rsi,%rdx,4),%edx
        movq nb410nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb410nf_ntia(%rsp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%rsi,%rax,4),%xmm6
        movlps (%rsi,%rcx,4),%xmm7
        movhps (%rsi,%rbx,4),%xmm6
        movhps (%rsi,%rdx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $221,%xmm7,%xmm6 ## 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb410nf_c6(%rsp)
        movaps %xmm6,nb410nf_c12(%rsp)

        movq nb410nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move four coordinates to xmm0-xmm2   

        movlps (%rsi,%rax,4),%xmm4
        movlps (%rsi,%rcx,4),%xmm5
        movss 8(%rsi,%rax,4),%xmm2
        movss 8(%rsi,%rcx,4),%xmm6

        movhps (%rsi,%rbx,4),%xmm4
        movhps (%rsi,%rdx,4),%xmm5

        movss 8(%rsi,%rbx,4),%xmm0
        movss 8(%rsi,%rdx,4),%xmm1