nb_kernel313_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,144 行 · 第 1/5 页

        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,36(%rdi,%rcx,4)
        movss  %xmm4,40(%rdi,%rcx,4)
        movss  %xmm5,44(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%rsi,%rdx,4),%xmm3
        movss  8(%rsi,%rdx,4),%xmm4
        subps  %xmm6,%xmm3
        subss  %xmm7,%xmm4
        movlps  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb313_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb313_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb313_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb313_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## accumulate total lj energy and update it 
        movaps nb313_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb313_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb313_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel313_x86_64_sse.nb313_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb313_n(%rsp)
        jmp _nb_kernel313_x86_64_sse.nb313_outer
_nb_kernel313_x86_64_sse.nb313_outerend: 
        ## check if more outer neighborlists remain
        movl  nb313_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel313_x86_64_sse.nb313_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel313_x86_64_sse.nb313_threadloop
_nb_kernel313_x86_64_sse.nb313_end: 
        movl nb313_nouter(%rsp),%eax
        movl nb313_ninner(%rsp),%ebx
        movq nb313_outeriter(%rbp),%rcx
        movq nb313_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $1048,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret






.globl nb_kernel313nf_x86_64_sse
.globl _nb_kernel313nf_x86_64_sse
nb_kernel313nf_x86_64_sse:      
_nb_kernel313nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb313nf_fshift, 16
.set nb313nf_gid, 24
.set nb313nf_pos, 32
.set nb313nf_faction, 40
.set nb313nf_charge, 48
.set nb313nf_p_facel, 56
.set nb313nf_argkrf, 64
.set nb313nf_argcrf, 72
.set nb313nf_Vc, 80
.set nb313nf_type, 88
.set nb313nf_p_ntype, 96
.set nb313nf_vdwparam, 104
.set nb313nf_Vvdw, 112
.set nb313nf_p_tabscale, 120
.set nb313nf_VFtab, 128
.set nb313nf_invsqrta, 136
.set nb313nf_dvda, 144
.set nb313nf_p_gbtabscale, 152
.set nb313nf_GBtab, 160
.set nb313nf_p_nthreads, 168
.set nb313nf_count, 176
.set nb313nf_mtx, 184
.set nb313nf_outeriter, 192
.set nb313nf_inneriter, 200
.set nb313nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb313nf_ixO, 0
.set nb313nf_iyO, 16
.set nb313nf_izO, 32
.set nb313nf_ixH1, 48
.set nb313nf_iyH1, 64
.set nb313nf_izH1, 80
.set nb313nf_ixH2, 96
.set nb313nf_iyH2, 112
.set nb313nf_izH2, 128
.set nb313nf_ixM, 144
.set nb313nf_iyM, 160
.set nb313nf_izM, 176
.set nb313nf_iqM, 192
.set nb313nf_iqH, 208
.set nb313nf_qqM, 224
.set nb313nf_qqH, 240
.set nb313nf_rinvH1, 256
.set nb313nf_rinvH2, 272
.set nb313nf_rinvM, 288
.set nb313nf_rH1, 304
.set nb313nf_rH2, 320
.set nb313nf_rM, 336
.set nb313nf_tsc, 352
.set nb313nf_two, 368
.set nb313nf_c6, 384
.set nb313nf_c12, 400
.set nb313nf_vctot, 416
.set nb313nf_Vvdwtot, 432
.set nb313nf_half, 448
.set nb313nf_three, 464
.set nb313nf_is3, 480
.set nb313nf_ii3, 484
.set nb313nf_nri, 488
.set nb313nf_iinr, 496
.set nb313nf_jindex, 504
.set nb313nf_jjnr, 512
.set nb313nf_shift, 520
.set nb313nf_shiftvec, 528
.set nb313nf_facel, 536
.set nb313nf_innerjjnr, 544
.set nb313nf_ntia, 552
.set nb313nf_innerk, 556
.set nb313nf_n, 560
.set nb313nf_nn1, 564
.set nb313nf_nouter, 568
.set nb313nf_ninner, 572
        push %rbp
        movq %rsp,%rbp
        push %rbx

        emms

        push %r12
        push %r13
        push %r14
        push %r15

        subq $584,%rsp          ## local variable stack space (n*16+8)

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb313nf_nouter(%rsp)
        movl %eax,nb313nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb313nf_nri(%rsp)
        movq %rsi,nb313nf_iinr(%rsp)
        movq %rdx,nb313nf_jindex(%rsp)
        movq %rcx,nb313nf_jjnr(%rsp)
        movq %r8,nb313nf_shift(%rsp)
        movq %r9,nb313nf_shiftvec(%rsp)
        movq nb313nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb313nf_facel(%rsp)

        movq nb313nf_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb313nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb313nf_half(%rsp)
        movss nb313nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb313nf_half(%rsp)
        movaps %xmm2,nb313nf_two(%rsp)
        movaps %xmm3,nb313nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb313nf_iinr(%rsp),%rcx         ## rcx = pointer into iinr[]      
        movl  (%rcx),%ebx           ## ebx =ii 

        movq  nb313nf_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm4
        movss 12(%rdx,%rbx,4),%xmm3
        movq nb313nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb313nf_facel(%rsp),%xmm5
        mulss  %xmm5,%xmm3
        mulss  %xmm5,%xmm4

        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        movaps %xmm3,nb313nf_iqM(%rsp)
        movaps %xmm4,nb313nf_iqH(%rsp)

        movq  nb313nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%ecx
        shll  %ecx
        movq nb313nf_p_ntype(%rbp),%rdi
        imull (%rdi),%ecx     ## rcx = ntia = 2*ntype*type[ii0] 
        movl  %ecx,nb313nf_ntia(%rsp)
_nb_kernel313nf_x86_64_sse.nb313nf_threadloop: 
        movq  nb313nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel313nf_x86_64_sse.nb313nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel313nf_x86_64_sse.nb313nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb313nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb313nf_n(%rsp)
        movl %ebx,nb313nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel313nf_x86_64_sse.nb313nf_outerstart
        jmp _nb_kernel313nf_x86_64_sse.nb313nf_end

_nb_kernel313nf_x86_64_sse.nb313nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb313nf_nouter(%rsp),%ebx
        movl %ebx,nb313nf_nouter(%rsp)

_nb_kernel313nf_x86_64_sse.nb313nf_outer: 
        movq  nb313nf_shift(%rsp),%rax        ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb313nf_is3(%rsp)            ## store is3 

        movq  nb313nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb313nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        movaps %xmm0,%xmm6
        movaps %xmm1,%xmm7

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb313nf_pos(%rbp),%rax    ## rax = base of pos[]  
        movl  %ebx,nb313nf_ii3(%rsp)

        addss (%rax,%rbx,4),%xmm3       ## ox
        addss 4(%rax,%rbx,4),%xmm4     ## oy
        addss 8(%rax,%rbx,4),%xmm5     ## oz
        addss 12(%rax,%rbx,4),%xmm6    ## h1x
        addss 16(%rax,%rbx,4),%xmm7    ## h1y
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm7,%xmm7
        movaps %xmm3,nb313nf_ixO(%rsp)
        movaps %xmm4,nb313nf_iyO(%rsp)
        movaps %xmm5,nb313nf_izO(%rsp)
        movaps %xmm6,nb313nf_ixH1(%rsp)
        movaps %xmm7,nb313nf_iyH1(%rsp)

        movss %xmm2,%xmm6
        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 20(%rax,%rbx,4),%xmm6    ## h1z
        addss 24(%rax,%rbx,4),%xmm0    ## h2x
        addss 28(%rax,%rbx,4),%xmm1    ## h2y
        addss 32(%rax,%rbx,4),%xmm2    ## h2z
        addss 36(%rax,%rbx,4),%xmm3    ## mx
        addss 40(%rax,%rbx,4),%xmm4    ## my
        addss 44(%rax,%rbx,4),%xmm5    ## mz

        shufps $0,%xmm6,%xmm6
        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm6,nb313nf_izH1(%rsp)
        movaps %xmm0,nb313nf_ixH2(%rsp)
        movaps %xmm1,nb313nf_iyH2(%rsp)
        movaps %xmm2,nb313nf_izH2(%rsp)
        movaps %xmm3,nb313nf_ixM(%rsp)
        movaps %xmm4,nb313nf_iyM(%rsp)
        movaps %xmm5,nb313nf_izM(%rsp)

        ## clear vctot
        xorps %xmm4,%xmm4
        movaps %xmm4,nb313nf_vctot(%rsp)
        movaps %xmm4,nb313nf_Vvdwtot(%rsp)

        movq  nb313nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx                ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                 ## number of innerloop atoms 

        movq  nb313nf_pos(%rbp),%rsi
        movq  nb313nf_faction(%rbp),%rdi
        movq  nb313nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb313nf_innerjjnr(%rsp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb313nf_ninner(%rsp),%ecx
        movl  %ecx,nb313nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb313nf_innerk(%rsp)         ## number of innerloop atoms 
        jge   _nb_kernel313nf_x86_64_sse.nb313nf_unroll_loop
        jmp   _nb_kernel313nf_x86_64_sse.nb313nf_odd_inner
_nb_kernel313nf_x86_64_sse.nb313nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb313nf_innerjjnr(%rsp),%rdx      ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx             ## eax-edx=jnr1-4 

        addq $16,nb313nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movq nb313nf_charge(%rbp),%rsi  ## base of charge[] 

        movss (%rsi,%rax,4),%xmm3
        movss (%rsi,%rcx,4),%xmm4
        movss (%rsi,%rbx,4),%xmm6
        movss (%rsi,%rdx,4),%xmm7

        shufps $0,%xmm6,%xmm3
        shufps $0,%xmm7,%xmm4
        shufps $136,%xmm4,%xmm3 ## 10001000 ;# all charges in xmm3  
        movaps %xmm3,%xmm4              ## and in xmm4 
        mulps  nb313nf_iqM(%rsp),%xmm3
        mulps  nb313nf_iqH(%rsp),%xmm4

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movaps  %xmm3,nb313nf_qqM(%rsp)
        movaps  %xmm4,nb313nf_qqH(%rsp)

        movq nb313nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movl (%rsi,%rcx,4),%ecx
        movl (%rsi,%rdx,4),%edx
        movq nb313nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb313nf_ntia(%rsp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%rsi,%rax,4),%xmm6
        movlps (%rsi,%rcx,4),%xmm7
        movhps (%rsi,%rbx,4),%xmm6
        movhps (%rsi,%rdx,4),%xmm7