nb_kernel104_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,085 行 · 第 1/5 页

        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  12(%rdi,%rcx,4),%xmm3
        movss  16(%rdi,%rcx,4),%xmm4
        movss  20(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,12(%rdi,%rcx,4)
        movss  %xmm4,16(%rdi,%rcx,4)
        movss  %xmm5,20(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        movaps %xmm0,%xmm6
        movss %xmm2,%xmm7
        movlhps %xmm1,%xmm6
        shufps $8,%xmm6,%xmm6 ## 00001000       

        ## accumulate H2i forces in xmm0, xmm1, xmm2 
        movaps nb104_fixH2(%rsp),%xmm0
        movaps nb104_fiyH2(%rsp),%xmm1
        movaps nb104_fizH2(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  24(%rdi,%rcx,4),%xmm3
        movss  28(%rdi,%rcx,4),%xmm4
        movss  32(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,24(%rdi,%rcx,4)
        movss  %xmm4,28(%rdi,%rcx,4)
        movss  %xmm5,32(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## accumulate M i forces in xmm0, xmm1, xmm2 
        movaps nb104_fixM(%rsp),%xmm0
        movaps nb104_fiyM(%rsp),%xmm1
        movaps nb104_fizM(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  36(%rdi,%rcx,4),%xmm3
        movss  40(%rdi,%rcx,4),%xmm4
        movss  44(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,36(%rdi,%rcx,4)
        movss  %xmm4,40(%rdi,%rcx,4)
        movss  %xmm5,44(%rdi,%rcx,4)

        ## accumulate force in xmm6/xmm7 for fshift 
        addss %xmm2,%xmm7
        movlhps %xmm1,%xmm0
        shufps $8,%xmm0,%xmm0 ## 00001000       
        addps   %xmm0,%xmm6

        ## increment fshift force  
        movlps  (%rsi,%rdx,4),%xmm3
        movss  8(%rsi,%rdx,4),%xmm4
        subps  %xmm6,%xmm3
        subss  %xmm7,%xmm4
        movlps  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb104_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb104_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total potential energy and update it 
        movaps nb104_vctot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb104_Vc(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb104_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel104_x86_64_sse.nb104_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb104_n(%rsp)
        jmp _nb_kernel104_x86_64_sse.nb104_outer
_nb_kernel104_x86_64_sse.nb104_outerend: 
        ## check if more outer neighborlists remain
        movl  nb104_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel104_x86_64_sse.nb104_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel104_x86_64_sse.nb104_threadloop
_nb_kernel104_x86_64_sse.nb104_end: 


        movl nb104_nouter(%rsp),%eax
        movl nb104_ninner(%rsp),%ebx
        movq nb104_outeriter(%rbp),%rcx
        movq nb104_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $1512,%rsp
        emms


        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret







.globl nb_kernel104nf_x86_64_sse
.globl _nb_kernel104nf_x86_64_sse
nb_kernel104nf_x86_64_sse:      
_nb_kernel104nf_x86_64_sse:     
.set nb104nf_fshift, 16
.set nb104nf_gid, 24
.set nb104nf_pos, 32
.set nb104nf_faction, 40
.set nb104nf_charge, 48
.set nb104nf_p_facel, 56
.set nb104nf_argkrf, 64
.set nb104nf_argcrf, 72
.set nb104nf_Vc, 80
.set nb104nf_type, 88
.set nb104nf_p_ntype, 96
.set nb104nf_vdwparam, 104
.set nb104nf_Vvdw, 112
.set nb104nf_p_tabscale, 120
.set nb104nf_VFtab, 128
.set nb104nf_invsqrta, 136
.set nb104nf_dvda, 144
.set nb104nf_p_gbtabscale, 152
.set nb104nf_GBtab, 160
.set nb104nf_p_nthreads, 168
.set nb104nf_count, 176
.set nb104nf_mtx, 184
.set nb104nf_outeriter, 192
.set nb104nf_inneriter, 200
.set nb104nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use         
.set nb104nf_ixH1, 0
.set nb104nf_iyH1, 16
.set nb104nf_izH1, 32
.set nb104nf_ixH2, 48
.set nb104nf_iyH2, 64
.set nb104nf_izH2, 80
.set nb104nf_ixM, 96
.set nb104nf_iyM, 112
.set nb104nf_izM, 128
.set nb104nf_jxH1, 144
.set nb104nf_jyH1, 160
.set nb104nf_jzH1, 176
.set nb104nf_jxH2, 192
.set nb104nf_jyH2, 208
.set nb104nf_jzH2, 224
.set nb104nf_jxM, 240
.set nb104nf_jyM, 256
.set nb104nf_jzM, 272
.set nb104nf_dxMM, 288
.set nb104nf_dyMM, 304
.set nb104nf_dzMM, 320
.set nb104nf_qqHH, 336
.set nb104nf_qqMH, 352
.set nb104nf_qqMM, 368
.set nb104nf_vctot, 384
.set nb104nf_half, 400
.set nb104nf_three, 416
.set nb104nf_rsqH1H1, 432
.set nb104nf_rsqH1H2, 448
.set nb104nf_rsqH1M, 464
.set nb104nf_rsqH2H1, 480
.set nb104nf_rsqH2H2, 496
.set nb104nf_rsqH2M, 512
.set nb104nf_rsqMH1, 528
.set nb104nf_rsqMH2, 544
.set nb104nf_rsqMM, 560
.set nb104nf_rinvH1H1, 576
.set nb104nf_rinvH1H2, 592
.set nb104nf_rinvH1M, 608
.set nb104nf_rinvH2H1, 624
.set nb104nf_rinvH2H2, 640
.set nb104nf_rinvH2M, 656
.set nb104nf_rinvMH1, 672
.set nb104nf_rinvMH2, 688
.set nb104nf_rinvMM, 704
.set nb104nf_is3, 720
.set nb104nf_ii3, 724
.set nb104nf_nri, 728
.set nb104nf_iinr, 736
.set nb104nf_jindex, 744
.set nb104nf_jjnr, 752
.set nb104nf_shift, 760
.set nb104nf_shiftvec, 768
.set nb104nf_facel, 776
.set nb104nf_innerjjnr, 784
.set nb104nf_innerk, 792
.set nb104nf_n, 800
.set nb104nf_nn1, 804
.set nb104nf_nouter, 808
.set nb104nf_ninner, 812

        push %rbp
        movq %rsp,%rbp
        push %rbx


        emms
        subq $824,%rsp
        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb104nf_nouter(%rsp)
        movl %eax,nb104nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb104nf_nri(%rsp)
        movq %rsi,nb104nf_iinr(%rsp)
        movq %rdx,nb104nf_jindex(%rsp)
        movq %rcx,nb104nf_jjnr(%rsp)
        movq %r8,nb104nf_shift(%rsp)
        movq %r9,nb104nf_shiftvec(%rsp)
        movq nb104nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss %xmm0,nb104nf_facel(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb104nf_half(%rsp)
        movss nb104nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb104nf_half(%rsp)
        movaps %xmm3,nb104nf_three(%rsp)

        ## assume we have at least one i particle - start directly 
        movq  nb104nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx),%ebx               ## ebx =ii 

        movq  nb104nf_charge(%rbp),%rdx
        movss 4(%rdx,%rbx,4),%xmm3
        movss %xmm3,%xmm4
        movss 12(%rdx,%rbx,4),%xmm5
        movq nb104nf_p_facel(%rbp),%rsi
        movss (%rsi),%xmm0
        movss nb104nf_facel(%rsp),%xmm6
        mulss  %xmm3,%xmm3
        mulss  %xmm5,%xmm4
        mulss  %xmm5,%xmm5
        mulss  %xmm6,%xmm3
        mulss  %xmm6,%xmm4
        mulss  %xmm6,%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb104nf_qqHH(%rsp)
        movaps %xmm4,nb104nf_qqMH(%rsp)
        movaps %xmm5,nb104nf_qqMM(%rsp)

_nb_kernel104nf_x86_64_sse.nb104nf_threadloop: 
        movq  nb104nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel104nf_x86_64_sse.nb104nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel104nf_x86_64_sse.nb104nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb104nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb104nf_n(%rsp)
        movl %ebx,nb104nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel104nf_x86_64_sse.nb104nf_outerstart
        jmp _nb_kernel104nf_x86_64_sse.nb104nf_end

_nb_kernel104nf_x86_64_sse.nb104nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb104nf_nouter(%rsp),%ebx
        movl %ebx,nb104nf_nouter(%rsp)

_nb_kernel104nf_x86_64_sse.nb104nf_outer: 
        movq  nb104nf_shift(%rsp),%rax          ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## rbx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx        ## rbx=3*is 
        movl  %ebx,nb104nf_is3(%rsp)            ## store is3 

        movq  nb104nf_shiftvec(%rsp),%rax     ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb104nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        lea  (%rbx,%rbx,2),%rbx        ## rbx = 3*ii=ii3 
        movq  nb104nf_pos(%rbp),%rax    ## rax = base of pos[]  
        movl  %ebx,nb104nf_ii3(%rsp)

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5
        addss 12(%rax,%rbx,4),%xmm3
        addss 16(%rax,%rbx,4),%xmm4
        addss 20(%rax,%rbx,4),%xmm5
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm3,nb104nf_ixH1(%rsp)
        movaps %xmm4,nb104nf_iyH1(%rsp)
        movaps %xmm5,nb104nf_izH1(%rsp)

        movss %xmm0,%xmm3
        movss %xmm1,%xmm4
        movss %xmm2,%xmm5
        addss 24(%rax,%rbx,4),%xmm0
        addss 28(%rax,%rbx,4),%xmm1
        addss 32(%rax,%rbx,4),%xmm2
        addss 36(%rax,%rbx,4),%xmm3
        addss 40(%rax,%rbx,4),%xmm4
        addss 44(%rax,%rbx,4),%xmm5

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2
        shufps $0,%xmm3,%xmm3
        shufps $0,%xmm4,%xmm4
        shufps $0,%xmm5,%xmm5
        movaps %xmm0,nb104nf_ixH2(%rsp)
        movaps %xmm1,nb104nf_iyH2(%rsp)
        movaps %xmm2,nb104nf_izH2(%rsp)
        movaps %xmm3,nb104nf_ixM(%rsp)
        movaps %xmm4,nb104nf_iyM(%rsp)