nb_kernel312_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 2,232 行 · 第 1/5 页

        mulps  %xmm5,%xmm5
        movaps %xmm6,nb312_dxH2O(%rsp)
        movaps %xmm7,nb312_dyH2O(%rsp)
        movaps %xmm8,nb312_dzH2O(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

    movd %eax,%mm0 ## save j3 in mm0-mm3
    movd %ebx,%mm1
    movd %ecx,%mm2
    movd %edx,%mm3

        ## start doing invsqrt for jO atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb312_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb312_half(%rsp),%xmm4
        mulps   %xmm4,%xmm9 ## rinvOO 
        mulps   %xmm4,%xmm10 ## rinvH1O
    mulps   %xmm4,%xmm11 ## rinvH2O

        movaps  %xmm9,nb312_rinvOO(%rsp)
        movaps  %xmm10,nb312_rinvH1O(%rsp)
        movaps  %xmm11,nb312_rinvH2O(%rsp)

        ## O interactions 
    ## rsq in xmm0,xmm3,xmm6  
    ## rinv in xmm9, xmm10, xmm11

    movaps nb312_tsc(%rsp),%xmm1
    mulps  %xmm9,%xmm0 ## r
    mulps  %xmm10,%xmm3
    mulps  %xmm11,%xmm6
    mulps  %xmm1,%xmm0 ## rtab
    mulps  %xmm1,%xmm3
    mulps  %xmm1,%xmm6

    ## truncate and convert to integers
    cvttps2dq %xmm0,%xmm1
    cvttps2dq %xmm3,%xmm4
    cvttps2dq %xmm6,%xmm7

    ## convert back to float
    cvtdq2ps  %xmm1,%xmm2
    cvtdq2ps  %xmm4,%xmm5
    cvtdq2ps  %xmm7,%xmm8

    ## multiply by 4
    pslld   $2,%xmm1
    pslld   $2,%xmm4
    pslld   $2,%xmm7

    ## move to integer registers
    movhlps %xmm1,%xmm13
    movhlps %xmm4,%xmm14
    movhlps %xmm7,%xmm15
    movd    %xmm1,%eax
    movd    %xmm4,%r8d
    movd    %xmm7,%r12d
    movd    %xmm13,%ecx
    movd    %xmm14,%r10d
    movd    %xmm15,%r14d
    pshufd $1,%xmm1,%xmm1
    pshufd $1,%xmm4,%xmm4
    pshufd $1,%xmm7,%xmm7
    pshufd $1,%xmm13,%xmm13
    pshufd $1,%xmm14,%xmm14
    pshufd $1,%xmm15,%xmm15
    movd    %xmm1,%ebx
    movd    %xmm4,%r9d
    movd    %xmm7,%r13d
    movd    %xmm13,%edx
    movd    %xmm14,%r11d
    movd    %xmm15,%r15d

    movq nb312_VFtab(%rbp),%rsi

    ## calculate eps
    subps     %xmm2,%xmm0
    subps     %xmm5,%xmm3
    subps     %xmm8,%xmm6

    movaps    %xmm0,nb312_epsO(%rsp)
    movaps    %xmm3,nb312_epsH1(%rsp)
    movaps    %xmm6,nb312_epsH2(%rsp)

    ## Load LOTS of table data
        movlps (%rsi,%rax,4),%xmm1
        movlps (%rsi,%r8,4),%xmm5
        movlps (%rsi,%r12,4),%xmm9

        movlps (%rsi,%rcx,4),%xmm3
        movlps (%rsi,%r10,4),%xmm7
        movlps (%rsi,%r14,4),%xmm11

        movhps (%rsi,%rbx,4),%xmm1
        movhps (%rsi,%r9,4),%xmm5
        movhps (%rsi,%r13,4),%xmm9

        movhps (%rsi,%rdx,4),%xmm3
        movhps (%rsi,%r11,4),%xmm7
        movhps (%rsi,%r15,4),%xmm11

    movaps %xmm1,%xmm0
    movaps %xmm5,%xmm4
    movaps %xmm9,%xmm8
        shufps $136,%xmm3,%xmm0 ## 10001000
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $136,%xmm11,%xmm8 ## 10001000
        shufps $221,%xmm3,%xmm1 ## 11011101
        shufps $221,%xmm7,%xmm5 ## 11011101
        shufps $221,%xmm11,%xmm9 ## 11011101

        movlps 8(%rsi,%rax,4),%xmm3
        movlps 8(%rsi,%r8,4),%xmm7
        movlps 8(%rsi,%r12,4),%xmm11

        movlps 8(%rsi,%rcx,4),%xmm12
        movlps 8(%rsi,%r10,4),%xmm13
        movlps 8(%rsi,%r14,4),%xmm14

        movhps 8(%rsi,%rbx,4),%xmm3
        movhps 8(%rsi,%r9,4),%xmm7
        movhps 8(%rsi,%r13,4),%xmm11

        movhps 8(%rsi,%rdx,4),%xmm12
        movhps 8(%rsi,%r11,4),%xmm13
        movhps 8(%rsi,%r15,4),%xmm14

    movaps %xmm3,%xmm2
    movaps %xmm7,%xmm6
    movaps %xmm11,%xmm10

        shufps $136,%xmm12,%xmm2 ## 10001000
        shufps $136,%xmm13,%xmm6 ## 10001000
        shufps $136,%xmm14,%xmm10 ## 10001000
        shufps $221,%xmm12,%xmm3 ## 11011101
        shufps $221,%xmm13,%xmm7 ## 11011101
        shufps $221,%xmm14,%xmm11 ## 11011101
    ## table data ready in xmm0-xmm3 , xmm4-xmm7 , and xmm8-xmm11

    mulps  nb312_epsO(%rsp),%xmm3     ## Heps
    mulps  nb312_epsH1(%rsp),%xmm7
    mulps  nb312_epsH2(%rsp),%xmm11
    mulps  nb312_epsO(%rsp),%xmm2     ## Geps
    mulps  nb312_epsH1(%rsp),%xmm6
    mulps  nb312_epsH2(%rsp),%xmm10
    mulps  nb312_epsO(%rsp),%xmm3     ## Heps2
    mulps  nb312_epsH1(%rsp),%xmm7
    mulps  nb312_epsH2(%rsp),%xmm11

    addps  %xmm2,%xmm1  ## F+Geps
    addps  %xmm6,%xmm5
    addps  %xmm10,%xmm9
    addps  %xmm3,%xmm1  ## F+Geps+Heps2 = Fp
    addps  %xmm7,%xmm5
    addps  %xmm11,%xmm9
    addps  %xmm3,%xmm3   ## 2*Heps2
    addps  %xmm7,%xmm7
    addps  %xmm11,%xmm11
    addps  %xmm2,%xmm3   ## 2*Heps2+Geps
    addps  %xmm6,%xmm7
    addps  %xmm10,%xmm11
    addps  %xmm1,%xmm3  ## FF = Fp + 2*Heps2 + Geps
    addps  %xmm5,%xmm7
    addps  %xmm9,%xmm11
    mulps  nb312_epsO(%rsp),%xmm1     ## eps*Fp
    mulps  nb312_epsH1(%rsp),%xmm5
    mulps  nb312_epsH2(%rsp),%xmm9
    addps  %xmm0,%xmm1    ## VV
    addps  %xmm4,%xmm5
    addps  %xmm8,%xmm9
    mulps  nb312_qqOO(%rsp),%xmm1     ## VV*qq = vcoul
    mulps  nb312_qqOH(%rsp),%xmm5
    mulps  nb312_qqOH(%rsp),%xmm9
    mulps  nb312_qqOO(%rsp),%xmm3      ## FF*qq = fij
    mulps  nb312_qqOH(%rsp),%xmm7
    mulps  nb312_qqOH(%rsp),%xmm11

    ## calculate LJ
    movaps nb312_rinvOO(%rsp),%xmm12
    mulps  %xmm12,%xmm12 ## rinvsq
    movaps %xmm12,%xmm13 ## rinvsq
    mulps  %xmm12,%xmm12 ## rinv4
    mulps  %xmm13,%xmm12 ## rinv6
    movaps %xmm12,%xmm13 ## rinv6
    mulps  %xmm12,%xmm12 ## rinv12
        mulps  nb312_c6(%rsp),%xmm13
        mulps  nb312_c12(%rsp),%xmm12
    movaps %xmm12,%xmm14
    subps  %xmm13,%xmm14

        addps  nb312_Vvdwtot(%rsp),%xmm14
        mulps  nb312_six(%rsp),%xmm13
        mulps  nb312_twelve(%rsp),%xmm12
        movaps %xmm14,nb312_Vvdwtot(%rsp)
    subps  %xmm13,%xmm12 ## LJ fscal    
    mulps  nb312_rinvOO(%rsp),%xmm12
    movaps %xmm12,nb312_fstmp(%rsp)

    movd %mm0,%eax ## restore j3 from mm0-mm3
    movd %mm1,%ebx
    movd %mm2,%ecx
    movd %mm3,%edx

    ## accumulate vctot
    addps  nb312_vctot(%rsp),%xmm1
    addps  %xmm9,%xmm5
    addps  %xmm5,%xmm1
    movaps %xmm1,nb312_vctot(%rsp)

    movaps nb312_tsc(%rsp),%xmm10
    mulps  %xmm10,%xmm3 ## fscal
    mulps  %xmm10,%xmm7
    mulps  %xmm11,%xmm10

        ## move j O forces to local temp variables 
    movlps (%rdi,%rax,4),%xmm11 ## jxOa jyOa  -   -
    movlps (%rdi,%rcx,4),%xmm12 ## jxOc jyOc  -   -

    ## xmm11: jxOa jyOa jxOb jyOb 
    ## xmm12: jxOc jyOc jxOd jyOd
    ## xmm13: jzOa jzOb jzOc jzOd


    movaps nb312_fstmp(%rsp),%xmm0
    xorps  %xmm4,%xmm4
    xorps  %xmm8,%xmm8

    subps  %xmm3,%xmm0
    subps  %xmm7,%xmm4
    subps  %xmm10,%xmm8
    movhps (%rdi,%rbx,4),%xmm11 ## jxOa jyOa jxOb jyOb 
    movhps (%rdi,%rdx,4),%xmm12 ## jxOc jyOc jxOd jyOd 

    mulps  nb312_rinvOO(%rsp),%xmm0
    mulps  nb312_rinvH1O(%rsp),%xmm4
    mulps  nb312_rinvH2O(%rsp),%xmm8

    movss  8(%rdi,%rax,4),%xmm13    ## jzOa  -  -  -
    movss  8(%rdi,%rcx,4),%xmm14    ## jzOc  -  -  -

    movaps %xmm0,%xmm1
    movaps %xmm0,%xmm2
    movaps %xmm4,%xmm3
    movaps %xmm4,%xmm5
    movaps %xmm8,%xmm6
    movaps %xmm8,%xmm7

    movhps 8(%rdi,%rbx,4),%xmm13    ## jzOa  -  jzOb  -
    movhps 8(%rdi,%rdx,4),%xmm14    ## jzOc  -  jzOd -    
    shufps $136,%xmm14,%xmm13 ## 10001000 => jzOa jzOb jzOc jzOd

        mulps nb312_dxOO(%rsp),%xmm0
        mulps nb312_dyOO(%rsp),%xmm1
        mulps nb312_dzOO(%rsp),%xmm2
        mulps nb312_dxH1O(%rsp),%xmm3
        mulps nb312_dyH1O(%rsp),%xmm4
        mulps nb312_dzH1O(%rsp),%xmm5
        mulps nb312_dxH2O(%rsp),%xmm6
        mulps nb312_dyH2O(%rsp),%xmm7
        mulps nb312_dzH2O(%rsp),%xmm8

    movaps %xmm0,%xmm14
    movaps %xmm1,%xmm15
    addps %xmm2,%xmm13
    addps nb312_fixO(%rsp),%xmm0
    addps nb312_fiyO(%rsp),%xmm1
    addps nb312_fizO(%rsp),%xmm2

    addps %xmm3,%xmm14
    addps %xmm4,%xmm15
    addps %xmm5,%xmm13
    addps nb312_fixH1(%rsp),%xmm3
    addps nb312_fiyH1(%rsp),%xmm4
    addps nb312_fizH1(%rsp),%xmm5

    addps %xmm6,%xmm14
    addps %xmm7,%xmm15
    addps %xmm8,%xmm13
    addps nb312_fixH2(%rsp),%xmm6
    addps nb312_fiyH2(%rsp),%xmm7
    addps nb312_fizH2(%rsp),%xmm8

    movaps %xmm0,nb312_fixO(%rsp)
    movaps %xmm1,nb312_fiyO(%rsp)
    movaps %xmm2,nb312_fizO(%rsp)
    movaps %xmm3,nb312_fixH1(%rsp)
    movaps %xmm4,nb312_fiyH1(%rsp)
    movaps %xmm5,nb312_fizH1(%rsp)
    movaps %xmm6,nb312_fixH2(%rsp)
    movaps %xmm7,nb312_fiyH2(%rsp)
    movaps %xmm8,nb312_fizH2(%rsp)

    ## xmm11 = fOx
    ## xmm12 = fOy
    ## xmm13 = fOz
    movaps %xmm14,%xmm0
    unpcklps %xmm15,%xmm14
    unpckhps %xmm15,%xmm0

    addps  %xmm14,%xmm11
    addps  %xmm0,%xmm12

    movhlps  %xmm13,%xmm14 ## fOzc fOzd

    pshufd $1,%xmm13,%xmm3
    pshufd $3,%xmm13,%xmm4

    movlps %xmm11,(%rdi,%rax,4)
    movhps %xmm11,(%rdi,%rbx,4)
    movlps %xmm12,(%rdi,%rcx,4)
    movhps %xmm12,(%rdi,%rdx,4)
    movss  %xmm13,8(%rdi,%rax,4)
    movss  %xmm14,8(%rdi,%rcx,4)
    movss  %xmm3,8(%rdi,%rbx,4)
    movss  %xmm4,8(%rdi,%rdx,4)

        ## move j H1 coordinates to local temp variables 
        movq  nb312_pos(%rbp),%rsi
    movlps 12(%rsi,%rax,4),%xmm0    ## jxH1a jyH1a  -   -
    movlps 12(%rsi,%rcx,4),%xmm1    ## jxH1c jyH1c  -   -
    movhps 12(%rsi,%rbx,4),%xmm0    ## jxH1a jyH1a jxH1b jyH1b 
    movhps 12(%rsi,%rdx,4),%xmm1    ## jxH1c jyH1c jxH1d jyH1d 

    movss  20(%rsi,%rax,4),%xmm2    ## jzH1a  -  -  -
    movss  20(%rsi,%rcx,4),%xmm3    ## jzH1c  -  -  -
    movhps 20(%rsi,%rbx,4),%xmm2    ## jzH1a  -  jzH1b  -
    movhps 20(%rsi,%rdx,4),%xmm3    ## jzH1c  -  jzH1d -

    movaps %xmm0,%xmm4
    unpcklps %xmm1,%xmm0 ## jxH1a jxH1c jyH1a jyH1c        
    unpckhps %xmm1,%xmm4 ## jxH1b jxH1d jyH1b jyH1d
    movaps %xmm0,%xmm1
    unpcklps %xmm4,%xmm0 ## x
    unpckhps %xmm4,%xmm1 ## y

    shufps  $136,%xmm3,%xmm2  ## 10001000 => jzH1a jzH1b jzH1c jzH1d

    ## xmm0 = H1x
    ## xmm1 = H1y
    ## xmm2 = H1z

    movaps %xmm0,%xmm3
    movaps %xmm1,%xmm4
    movaps %xmm2,%xmm5
    movaps %xmm0,%xmm6
    movaps %xmm1,%xmm7
    movaps %xmm2,%xmm8

    subps nb312_ixO(%rsp),%xmm0
    subps nb312_iyO(%rsp),%xmm1
    subps nb312_izO(%rsp),%xmm2
    subps nb312_ixH1(%rsp),%xmm3
    subps nb312_iyH1(%rsp),%xmm4
    subps nb312_izH1(%rsp),%xmm5
    subps nb312_ixH2(%rsp),%xmm6
    subps nb312_iyH2(%rsp),%xmm7
    subps nb312_izH2(%rsp),%xmm8

        movaps %xmm0,nb312_dxOH1(%rsp)
        movaps %xmm1,nb312_dyOH1(%rsp)
        movaps %xmm2,nb312_dzOH1(%rsp)
        mulps  %xmm0,%xmm0
        mulps  %xmm1,%xmm1
        mulps  %xmm2,%xmm2
        movaps %xmm3,nb312_dxH1H1(%rsp)
        movaps %xmm4,nb312_dyH1H1(%rsp)
        movaps %xmm5,nb312_dzH1H1(%rsp)
        mulps  %xmm3,%xmm3
        mulps  %xmm4,%xmm4
        mulps  %xmm5,%xmm5
        movaps %xmm6,nb312_dxH2H1(%rsp)
        movaps %xmm7,nb312_dyH2H1(%rsp)
        movaps %xmm8,nb312_dzH2H1(%rsp)
        mulps  %xmm6,%xmm6
        mulps  %xmm7,%xmm7
        mulps  %xmm8,%xmm8
        addps  %xmm1,%xmm0
        addps  %xmm2,%xmm0
        addps  %xmm4,%xmm3
        addps  %xmm5,%xmm3
    addps  %xmm7,%xmm6
    addps  %xmm8,%xmm6

        ## start doing invsqrt for jH1 atoms
        rsqrtps %xmm0,%xmm1
        rsqrtps %xmm3,%xmm4
    rsqrtps %xmm6,%xmm7

        movaps  %xmm1,%xmm2
        movaps  %xmm4,%xmm5
    movaps  %xmm7,%xmm8

        mulps   %xmm1,%xmm1 ## lu*lu
        mulps   %xmm4,%xmm4 ## lu*lu
    mulps   %xmm7,%xmm7 ## lu*lu

        movaps  nb312_three(%rsp),%xmm9
        movaps  %xmm9,%xmm10
    movaps  %xmm9,%xmm11

        mulps   %xmm0,%xmm1 ## rsq*lu*lu
        mulps   %xmm3,%xmm4 ## rsq*lu*lu 
    mulps   %xmm6,%xmm7 ## rsq*lu*lu

        subps   %xmm1,%xmm9
        subps   %xmm4,%xmm10
    subps   %xmm7,%xmm11 ## 3-rsq*lu*lu

        mulps   %xmm2,%xmm9
        mulps   %xmm5,%xmm10
    mulps   %xmm8,%xmm11 ## lu*(3-rsq*lu*lu)

        movaps  nb312_half(%rsp),%xmm4