nb_kernel230_x86_64_sse.intel_syntax.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,982 行 · 第 1/4 页

;#
;# $Id: nb_kernel230_x86_64_sse.intel_syntax.s,v 1.1.2.2 2006/09/22 08:32:50 lindahl Exp $
;#
;# Gromacs 4.0                         Copyright (c) 1991-2003 
;# David van der Spoel, Erik Lindahl
;#
;# This program is free software; you can redistribute it and/or
;# modify it under the terms of the GNU General Public License
;# as published by the Free Software Foundation; either version 2
;# of the License, or (at your option) any later version.
;#
;# To help us fund GROMACS development, we humbly ask that you cite
;# the research papers on the package. Check out http://www.gromacs.org
;# 
;# And Hey:
;# Gnomes, ROck Monsters And Chili Sauce
;#

;# These files require GNU binutils 2.10 or later, since we
;# use intel syntax for portability, or a recent version 
;# of NASM that understands Extended 3DNow and SSE2 instructions.
;# (NASM is normally only used with MS Visual C++).
;# Since NASM and gnu as disagree on some definitions and use 
;# completely different preprocessing options I have to introduce a
;# trick: NASM uses ';' for comments, while gnu as uses '#' on x86.
;# Gnu as treats ';' as a line break, i.e. ignores it. This is the
;# reason why all comments need both symbols...
;# The source is written for GNU as, with intel syntax. When you use
;# NASM we redefine a couple of things. The false if-statement around 
;# the following code is seen by GNU as, but NASM doesn't see it, so 
;# the code inside is read by NASM but not gcc.

; .if 0    # block below only read by NASM
%define .section	section
%define .long		dd
%define .align		align
%define .globl		global
;# NASM only wants 'dword', not 'dword ptr'.
%define ptr
.equiv          .equiv                  2
   %1 equ %2
%endmacro
; .endif                   # End of NASM-specific block
; .intel_syntax noprefix   # Line only read by gnu as




.globl nb_kernel230_x86_64_sse
.globl _nb_kernel230_x86_64_sse
nb_kernel230_x86_64_sse:	
_nb_kernel230_x86_64_sse:	
;#	Room for return address and rbp (16 bytes)
.equiv          nb230_fshift,           16
.equiv          nb230_gid,              24
.equiv          nb230_pos,              32
.equiv          nb230_faction,          40
.equiv          nb230_charge,           48
.equiv          nb230_p_facel,          56
.equiv          nb230_argkrf,           64
.equiv          nb230_argcrf,           72
.equiv          nb230_Vc,               80
.equiv          nb230_type,             88
.equiv          nb230_p_ntype,          96
.equiv          nb230_vdwparam,         104
.equiv          nb230_Vvdw,             112
.equiv          nb230_p_tabscale,       120
.equiv          nb230_VFtab,            128
.equiv          nb230_invsqrta,         136
.equiv          nb230_dvda,             144
.equiv          nb230_p_gbtabscale,     152
.equiv          nb230_GBtab,            160
.equiv          nb230_p_nthreads,       168
.equiv          nb230_count,            176
.equiv          nb230_mtx,              184
.equiv          nb230_outeriter,        192
.equiv          nb230_inneriter,        200
.equiv          nb230_work,             208
	;# stack offsets for local variables  
	;# bottom of stack is cache-aligned for sse use 
.equiv          nb230_ix,               0
.equiv          nb230_iy,               16
.equiv          nb230_iz,               32
.equiv          nb230_iq,               48
.equiv          nb230_dx,               64
.equiv          nb230_dy,               80
.equiv          nb230_dz,               96
.equiv          nb230_c6,               112
.equiv          nb230_c12,              128
.equiv          nb230_tsc,              144
.equiv          nb230_qq,               160
.equiv          nb230_vctot,            176
.equiv          nb230_Vvdwtot,          192
.equiv          nb230_fix,              208
.equiv          nb230_fiy,              224
.equiv          nb230_fiz,              240
.equiv          nb230_half,             256
.equiv          nb230_three,            272
.equiv          nb230_two,              288
.equiv          nb230_krf,              304
.equiv          nb230_crf,              320
.equiv          nb230_nri,              336
.equiv          nb230_iinr,             344
.equiv          nb230_jindex,           352
.equiv          nb230_jjnr,             360
.equiv          nb230_shift,            368
.equiv          nb230_shiftvec,         376
.equiv          nb230_facel,            384
.equiv          nb230_innerjjnr,        392
.equiv          nb230_is3,              400
.equiv          nb230_ii3,              404
.equiv          nb230_ntia,             408
.equiv          nb230_innerk,           412
.equiv          nb230_n,                416
.equiv          nb230_nn1,              420
.equiv          nb230_ntype,            424
.equiv          nb230_nouter,           428
.equiv          nb230_ninner,           432


	push rbp
	mov  rbp, rsp
	push rbx

	
	emms

        push r12
        push r13
        push r14
        push r15

	sub rsp, 456		;# local variable stack space (n*16+8)

	;# zero 32-bit iteration counters
	mov eax, 0
	mov [rsp + nb230_nouter], eax
	mov [rsp + nb230_ninner], eax

	mov edi, [rdi]
	mov [rsp + nb230_nri], edi
	mov [rsp + nb230_iinr], rsi
	mov [rsp + nb230_jindex], rdx
	mov [rsp + nb230_jjnr], rcx
	mov [rsp + nb230_shift], r8
	mov [rsp + nb230_shiftvec], r9
	mov rdi, [rbp + nb230_p_ntype]
	mov edi, [rdi]
	mov [rsp + nb230_ntype], edi
	mov rsi, [rbp + nb230_p_facel]
	movss xmm0, [rsi]
	movss [rsp + nb230_facel], xmm0

	mov rax, [rbp + nb230_p_tabscale]
	movss xmm3, [rax]
	shufps xmm3, xmm3, 0
	movaps [rsp + nb230_tsc], xmm3

	mov rsi, [rbp + nb230_argkrf]
	mov rdi, [rbp + nb230_argcrf]
	movss xmm1, [rsi]
	movss xmm2, [rdi]
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0
	movaps [rsp + nb230_krf], xmm1
	movaps [rsp + nb230_crf], xmm2

	;# create constant floating-point factors on stack
	mov eax, 0x3f000000     ;# half in IEEE (hex)
	mov [rsp + nb230_half], eax
	movss xmm1, [rsp + nb230_half]
	shufps xmm1, xmm1, 0    ;# splat to all elements
	movaps xmm2, xmm1       
	addps  xmm2, xmm2	;# one
	movaps xmm3, xmm2
	addps  xmm2, xmm2	;# two
	addps  xmm3, xmm2	;# three
	movaps [rsp + nb230_half],  xmm1
	movaps [rsp + nb230_two],  xmm2
	movaps [rsp + nb230_three],  xmm3

.nb230_threadloop:
        mov   rsi, [rbp + nb230_count]          ;# pointer to sync counter
        mov   eax, [rsi]
.nb230_spinlock:
        mov   ebx, eax                          ;# ebx=*count=nn0
        add   ebx, 1                           ;# ebx=nn1=nn0+10
        lock
        cmpxchg [esi], ebx                      ;# write nn1 to *counter,
                                                ;# if it hasnt changed.
                                                ;# or reread *counter to eax.
        pause                                   ;# -> better p4 performance
        jnz .nb230_spinlock

        ;# if(nn1>nri) nn1=nri
        mov ecx, [rsp + nb230_nri]
        mov edx, ecx
        sub ecx, ebx
        cmovle ebx, edx                         ;# if(nn1>nri) nn1=nri
        ;# Cleared the spinlock if we got here.
        ;# eax contains nn0, ebx contains nn1.
        mov [rsp + nb230_n], eax
        mov [rsp + nb230_nn1], ebx
        sub ebx, eax                            ;# calc number of outer lists
	mov esi, eax				;# copy n to esi
        jg  .nb230_outerstart
        jmp .nb230_end

.nb230_outerstart:
	;# ebx contains number of outer iterations
	add ebx, [rsp + nb230_nouter]
	mov [rsp + nb230_nouter], ebx

.nb230_outer:
	mov   rax, [rsp + nb230_shift]      ;# eax = pointer into shift[] 
	mov   ebx, [rax + rsi*4]		;# ebx=shift[n] 
	
	lea   rbx, [rbx + rbx*2]    ;# rbx=3*is 
	mov   [rsp + nb230_is3],ebx    	;# store is3 

	mov   rax, [rsp + nb230_shiftvec]   ;# eax = base of shiftvec[] 

	movss xmm0, [rax + rbx*4]
	movss xmm1, [rax + rbx*4 + 4]
	movss xmm2, [rax + rbx*4 + 8] 

	mov   rcx, [rsp + nb230_iinr]       ;# ecx = pointer into iinr[] 	
	mov   ebx, [rcx + rsi*4]	    ;# ebx =ii 

	mov   rdx, [rbp + nb230_charge]
	movss xmm3, [rdx + rbx*4]	
	mulss xmm3, [rsp + nb230_facel]
	shufps xmm3, xmm3, 0

    	mov   rdx, [rbp + nb230_type] 
    	mov   edx, [rdx + rbx*4]
    	imul  edx, [rsp + nb230_ntype]
    	shl   edx, 1
    	mov   [rsp + nb230_ntia], edx
		
	lea   rbx, [rbx + rbx*2]	;# rbx = 3*ii=ii3 
	mov   rax, [rbp + nb230_pos]    ;# eax = base of pos[]  

	addss xmm0, [rax + rbx*4]
	addss xmm1, [rax + rbx*4 + 4]
	addss xmm2, [rax + rbx*4 + 8]

	movaps [rsp + nb230_iq], xmm3
	
	shufps xmm0, xmm0, 0
	shufps xmm1, xmm1, 0
	shufps xmm2, xmm2, 0

	movaps [rsp + nb230_ix], xmm0
	movaps [rsp + nb230_iy], xmm1
	movaps [rsp + nb230_iz], xmm2

	mov   [rsp + nb230_ii3], ebx
	
	;# clear vctot and i forces 
	xorps xmm4, xmm4
	movaps [rsp + nb230_vctot], xmm4
	movaps [rsp + nb230_Vvdwtot], xmm4
	movaps [rsp + nb230_fix], xmm4
	movaps [rsp + nb230_fiy], xmm4
	movaps [rsp + nb230_fiz], xmm4
	
	mov   rax, [rsp + nb230_jindex]
	mov   ecx, [rax + rsi*4]	     ;# jindex[n] 
	mov   edx, [rax + rsi*4 + 4]	     ;# jindex[n+1] 
	sub   edx, ecx               ;# number of innerloop atoms 

	mov   rsi, [rbp + nb230_pos]
	mov   rdi, [rbp + nb230_faction]	
	mov   rax, [rsp + nb230_jjnr]
	shl   ecx, 2
	add   rax, rcx
	mov   [rsp + nb230_innerjjnr], rax     ;# pointer to jjnr[nj0] 
	mov   ecx, edx
	sub   edx,  4
	add   ecx, [rsp + nb230_ninner]
	mov   [rsp + nb230_ninner], ecx
	add   edx, 0
	mov   [rsp + nb230_innerk], edx    ;# number of innerloop atoms 
	jge   .nb230_unroll_loop
	jmp   .nb230_finish_inner
.nb230_unroll_loop:	
	;# quad-unroll innerloop here 
	mov   rdx, [rsp + nb230_innerjjnr]     ;# pointer to jjnr[k] 
	mov   r12d, [rdx]	
	mov   r13d, [rdx + 4]              
	mov   r14d, [rdx + 8]            
	mov   r15d, [rdx + 12]         ;# eax-edx=jnr1-4 
	add qword ptr [rsp + nb230_innerjjnr],  16 ;# advance pointer (unrolled 4) 
    
	lea   rax, [r12 + r12*2]     ;# replace jnr with j3 
	lea   rbx, [r13 + r13*2]	
	lea   rcx, [r14 + r14*2]    
	lea   rdx, [r15 + r15*2]	

	mov rdi, [rbp + nb230_pos]
	;# load coordinates
	movlps xmm1, [rdi + rax*4]	;# x1 y1 - - 
	movlps xmm2, [rdi + rcx*4]	;# x3 y3 - - 
	movhps xmm1, [rdi + rbx*4]	;# x2 y2 - -
	movhps xmm2, [rdi + rdx*4]	;# x4 y4 - -

	movss xmm5, [rdi + rax*4 + 8]	;# z1 - - - 
	movss xmm6, [rdi + rcx*4 + 8]	;# z2 - - - 
	movss xmm7, [rdi + rbx*4 + 8]	;# z3 - - - 
	movss xmm8, [rdi + rdx*4 + 8]	;# z4 - - - 
    movlhps xmm5, xmm7 ;# jzOa  -  jzOb  -
    movlhps xmm6, xmm8 ;# jzOc  -  jzOd -

    movaps xmm4, xmm1
    unpcklps xmm1, xmm2  ;# jxa jxc jya jyc        
    unpckhps xmm4, xmm2  ;# jxb jxd jyb jyd
    movaps xmm2, xmm1
    unpcklps xmm1, xmm4 ;# x
    unpckhps xmm2, xmm4 ;# y
    shufps   xmm5, xmm6,  136  ;# 10001000 => jzH2a jzH2b jzH2c jzH2d

	mov rsi, [rbp + nb230_charge]

	;# calc dr  
	subps xmm1, [rsp + nb230_ix]
	subps xmm2, [rsp + nb230_iy]
	subps xmm5, [rsp + nb230_iz]

	movss xmm6, [rsi + r12*4]
	movss xmm3, [rsi + r13*4]
	movss xmm4, [rsi + r14*4]
	movss xmm0, [rsi + r15*4]

	;# store dr
    movaps [rsp + nb230_dx], xmm1
    movaps [rsp + nb230_dy], xmm2
    movaps [rsp + nb230_dz], xmm5
    
	;# square it 
	mulps xmm1,xmm1
	mulps xmm2,xmm2
	mulps xmm5,xmm5
	addps xmm1, xmm2
	addps xmm1, xmm5

	mov rsi, [rbp + nb230_type]

    unpcklps xmm6, xmm4  ;# jqa jqc - -
    unpcklps xmm3, xmm0  ;# jqb jqd - -
    unpcklps xmm6, xmm3  ;# jqa jqb jqc jqd
	mulps xmm6, [rsp + nb230_iq] 
    movaps [rsp + nb230_qq], xmm6

	;# rsq in xmm1
    movaps xmm0, [rsp + nb230_krf]
    mulps  xmm0, xmm1    ;# krsq
    
     ;# vdw parameters
	mov r12d, [rsi + r12*4]
	mov r13d, [rsi + r13*4]
	mov r14d, [rsi + r14*4]
	mov r15d, [rsi + r15*4]

   ;# calculate rinv=1/sqrt(rsq)
	rsqrtps xmm5, xmm1
	movaps xmm2, xmm5
	mulps xmm5, xmm5
	movaps xmm4, [rsp + nb230_three]
	mulps xmm5, xmm1	;# rsq*lu*lu 	
    subps xmm4, xmm5	;# 30-rsq*lu*lu 
	mulps xmm4, xmm2	
	mulps xmm4, [rsp + nb230_half]	
	movaps xmm2, xmm4
	mulps  xmm1, xmm4	
    
    ;# xmm2=rinv
    ;# xmm1=r

	shl r12d, 1	
	shl r13d, 1	
	shl r14d, 1	
	shl r15d, 1	
    mov edi, [rsp + nb230_ntia]

    mulps xmm1, [rsp + nb230_tsc] ;# rtab

    ;# truncate and convert to integers
    cvttps2dq xmm5, xmm1
    
	add r12d, edi
	add r13d, edi
	add r14d, edi
	add r15d, edi

    ;# convert back to float
    cvtdq2ps  xmm4, xmm5
    
    ;# multiply by 8
    pslld   xmm5, 3

    ;# calculate eps
    subps     xmm1, xmm4

    ;# move to integer registers
    movhlps xmm6, xmm5
    movd    r8d, xmm5
    movd    r10d, xmm6
    pshufd  xmm5, xmm5, 1
    pshufd  xmm6, xmm6, 1
    movd    r9d, xmm5
    movd    r11d, xmm6

    ;# xmm1=eps
    ;# xmm2=rinv
    
	mov rsi, [rbp + nb230_VFtab]
    ;# calculate LJ table
    movlps xmm5, [rsi + r8*4]
   	movlps xmm9, [rsi + r8*4 + 16]
    
	movlps xmm7,  [rsi + r10*4]
	movlps xmm11, [rsi + r10*4 + 16]

    movaps  xmm3, xmm2              ;# rinv
    subps   xmm3, xmm0
    subps   xmm3, xmm0              ;# rinv-2*krsq
    addps   xmm0, xmm2              ;# rinv+krsq
    subps   xmm0, [rsp + nb230_crf] ;# rinv+krsq-crf
    mulps   xmm0, [rsp + nb230_qq]  ;# vcoul=qq*(rinv+krsq-crf)
    mulps   xmm3, [rsp + nb230_qq]  ;# qq*(rinv-2*krsq)

    mulps   xmm3, xmm2              ;# rinv*qq*(rinv-2*krsq)
    
	movhps xmm5, [rsi + r9*4]
	movhps xmm9, [rsi + r9*4 + 16]

    addps   xmm0, [rsp + nb230_vctot]
    movaps  [rsp + nb230_vctot], xmm0
    
	movhps xmm7,  [rsi + r11*4]
	movhps xmm11, [rsi + r11*4 + 16]
    
    movaps xmm4, xmm5
    movaps xmm8, xmm9
	shufps xmm4, xmm7, 136  ;# 10001000
	shufps xmm8, xmm11, 136  ;# 10001000
	shufps xmm5, xmm7, 221  ;# 11011101
	shufps xmm9, xmm11, 221  ;# 11011101

	movlps xmm7,  [rsi + r8*4 + 8]
	movlps xmm11, [rsi + r8*4 + 24]
    
	movlps xmm13, [rsi + r10*4 + 8]
	movlps xmm14, [rsi + r10*4 + 24]

	movhps xmm7,  [rsi + r9*4 + 8]
	movhps xmm11, [rsi + r9*4 + 24]
    
	movhps xmm13, [rsi + r11*4 + 8]
	movhps xmm14, [rsi + r11*4 + 24]

    movaps xmm6, xmm7
    movaps xmm10, xmm11
    
	shufps xmm6, xmm13, 136  ;# 10001000
	shufps xmm10, xmm14, 136  ;# 10001000
	shufps xmm7, xmm13, 221  ;# 11011101
	shufps xmm11, xmm14, 221  ;# 11011101
    ;# dispersion table in xmm4-xmm7, repulsion table in xmm8-xmm11
	mov rsi, [rbp + nb230_vdwparam]
    
    mulps  xmm7, xmm1    ;# Heps
    mulps  xmm11, xmm1 
    mulps  xmm6, xmm1   ;# Geps
    mulps  xmm10, xmm1 
    mulps  xmm7, xmm1   ;# Heps2
    mulps  xmm11, xmm1 

    ;# load c6/c12
	movlps xmm13, [rsi + r12*4]
	movlps xmm14, [rsi + r14*4]
	movhps xmm13, [rsi + r13*4]
	movhps xmm14, [rsi + r15*4]

    addps  xmm5, xmm6  ;# F+Geps
    addps  xmm9, xmm10 
    addps  xmm5, xmm7   ;# F+Geps+Heps2 = Fp
    addps  xmm9, xmm11 
    addps  xmm7, xmm7    ;# 2*Heps2
    addps  xmm11, xmm11
    addps  xmm7, xmm6   ;# 2*Heps2+Geps
    addps  xmm11, xmm10

	movaps xmm12, xmm13
	shufps xmm12, xmm14, 136  ;# 10001000