nb_kernel030_x86_64_sse.s

来自「最著名最快的分子模拟软件」· S 代码 · 共 1,724 行 · 第 1/4 页

    mulss  nb030_dy(%rsp),%xmm10
    mulss  nb030_dz(%rsp),%xmm11

    ## accumulate i forces
    addss %xmm9,%xmm12
    addss %xmm10,%xmm13
    addss %xmm11,%xmm14
    movss %xmm12,nb030_fix(%rsp)
    movss %xmm13,nb030_fiy(%rsp)
    movss %xmm14,nb030_fiz(%rsp)

        movq nb030_faction(%rbp),%rsi
    ## add to j forces
    addss  (%rsi,%rax,4),%xmm9
    addss  4(%rsi,%rax,4),%xmm10
    addss  8(%rsi,%rax,4),%xmm11
    movss  %xmm9,(%rsi,%rax,4)
    movss  %xmm10,4(%rsi,%rax,4)
    movss  %xmm11,8(%rsi,%rax,4)

_nb_kernel030_x86_64_sse.nb030_updateouterdata: 
        movl  nb030_ii3(%rsp),%ecx
        movq  nb030_faction(%rbp),%rdi
        movq  nb030_fshift(%rbp),%rsi
        movl  nb030_is3(%rsp),%edx

        ## accumulate i forces in xmm0, xmm1, xmm2 
        movaps nb030_fix(%rsp),%xmm0
        movaps nb030_fiy(%rsp),%xmm1
        movaps nb030_fiz(%rsp),%xmm2

        movhlps %xmm0,%xmm3
        movhlps %xmm1,%xmm4
        movhlps %xmm2,%xmm5
        addps  %xmm3,%xmm0
        addps  %xmm4,%xmm1
        addps  %xmm5,%xmm2 ## sum is in 1/2 in xmm0-xmm2 

        movaps %xmm0,%xmm3
        movaps %xmm1,%xmm4
        movaps %xmm2,%xmm5

        shufps $1,%xmm3,%xmm3
        shufps $1,%xmm4,%xmm4
        shufps $1,%xmm5,%xmm5
        addss  %xmm3,%xmm0
        addss  %xmm4,%xmm1
        addss  %xmm5,%xmm2      ## xmm0-xmm2 has single force in pos0 

        ## increment i force 
        movss  (%rdi,%rcx,4),%xmm3
        movss  4(%rdi,%rcx,4),%xmm4
        movss  8(%rdi,%rcx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rdi,%rcx,4)
        movss  %xmm4,4(%rdi,%rcx,4)
        movss  %xmm5,8(%rdi,%rcx,4)

        ## increment fshift force  
        movss  (%rsi,%rdx,4),%xmm3
        movss  4(%rsi,%rdx,4),%xmm4
        movss  8(%rsi,%rdx,4),%xmm5
        subss  %xmm0,%xmm3
        subss  %xmm1,%xmm4
        subss  %xmm2,%xmm5
        movss  %xmm3,(%rsi,%rdx,4)
        movss  %xmm4,4(%rsi,%rdx,4)
        movss  %xmm5,8(%rsi,%rdx,4)

        ## get n from stack
        movl nb030_n(%rsp),%esi
        ## get group index for i particle 
        movq  nb030_gid(%rbp),%rdx              ## base of gid[]
        movl  (%rdx,%rsi,4),%edx                ## ggid=gid[n]

        ## accumulate total lj energy and update it 
        movaps nb030_Vvdwtot(%rsp),%xmm7
        ## accumulate 
        movhlps %xmm7,%xmm6
        addps  %xmm6,%xmm7      ## pos 0-1 in xmm7 have the sum now 
        movaps %xmm7,%xmm6
        shufps $1,%xmm6,%xmm6
        addss  %xmm6,%xmm7

        ## add earlier value from mem 
        movq  nb030_Vvdw(%rbp),%rax
        addss (%rax,%rdx,4),%xmm7
        ## move back to mem 
        movss %xmm7,(%rax,%rdx,4)

        ## finish if last 
        movl nb030_nn1(%rsp),%ecx
        ## esi already loaded with n
        incl %esi
        subl %esi,%ecx
        jz _nb_kernel030_x86_64_sse.nb030_outerend

        ## not last, iterate outer loop once more!  
        movl %esi,nb030_n(%rsp)
        jmp _nb_kernel030_x86_64_sse.nb030_outer
_nb_kernel030_x86_64_sse.nb030_outerend: 
        ## check if more outer neighborlists remain
        movl  nb030_nri(%rsp),%ecx
        ## esi already loaded with n above
        subl  %esi,%ecx
        jz _nb_kernel030_x86_64_sse.nb030_end
        ## non-zero, do one more workunit
        jmp   _nb_kernel030_x86_64_sse.nb030_threadloop
_nb_kernel030_x86_64_sse.nb030_end: 

        movl nb030_nouter(%rsp),%eax
        movl nb030_ninner(%rsp),%ebx
        movq nb030_outeriter(%rbp),%rcx
        movq nb030_inneriter(%rbp),%rdx
        movl %eax,(%rcx)
        movl %ebx,(%rdx)

        addq $376,%rsp
        emms

        pop %r15
        pop %r14
        pop %r13
        pop %r12

        pop %rbx
        pop    %rbp
        ret





.globl nb_kernel030nf_x86_64_sse
.globl _nb_kernel030nf_x86_64_sse
nb_kernel030nf_x86_64_sse:      
_nb_kernel030nf_x86_64_sse:     
##      Room for return address and rbp (16 bytes)
.set nb030nf_fshift, 16
.set nb030nf_gid, 24
.set nb030nf_pos, 32
.set nb030nf_faction, 40
.set nb030nf_charge, 48
.set nb030nf_p_facel, 56
.set nb030nf_argkrf, 64
.set nb030nf_argcrf, 72
.set nb030nf_Vc, 80
.set nb030nf_type, 88
.set nb030nf_p_ntype, 96
.set nb030nf_vdwparam, 104
.set nb030nf_Vvdw, 112
.set nb030nf_p_tabscale, 120
.set nb030nf_VFtab, 128
.set nb030nf_invsqrta, 136
.set nb030nf_dvda, 144
.set nb030nf_p_gbtabscale, 152
.set nb030nf_GBtab, 160
.set nb030nf_p_nthreads, 168
.set nb030nf_count, 176
.set nb030nf_mtx, 184
.set nb030nf_outeriter, 192
.set nb030nf_inneriter, 200
.set nb030nf_work, 208
        ## stack offsets for local variables  
        ## bottom of stack is cache-aligned for sse use 
.set nb030nf_ix, 0
.set nb030nf_iy, 16
.set nb030nf_iz, 32
.set nb030nf_tsc, 48
.set nb030nf_c6, 64
.set nb030nf_c12, 80
.set nb030nf_Vvdwtot, 96
.set nb030nf_half, 112
.set nb030nf_three, 128
.set nb030nf_is3, 144
.set nb030nf_ii3, 148
.set nb030nf_innerjjnr, 152
.set nb030nf_nri, 160
.set nb030nf_iinr, 168
.set nb030nf_jindex, 176
.set nb030nf_jjnr, 184
.set nb030nf_shift, 192
.set nb030nf_shiftvec, 200
.set nb030nf_ntia, 208
.set nb030nf_innerk, 212
.set nb030nf_n, 216
.set nb030nf_nn1, 220
.set nb030nf_ntype, 224
.set nb030nf_nouter, 228
.set nb030nf_ninner, 232

        push %rbp
        movq %rsp,%rbp
        push %rbx

        subq $248,%rsp          # # local variable stack space (n*16+8)
        emms

        ## zero 32-bit iteration counters
        movl $0,%eax
        movl %eax,nb030nf_nouter(%rsp)
        movl %eax,nb030nf_ninner(%rsp)

        movl (%rdi),%edi
        movl %edi,nb030nf_nri(%rsp)
        movq %rsi,nb030nf_iinr(%rsp)
        movq %rdx,nb030nf_jindex(%rsp)
        movq %rcx,nb030nf_jjnr(%rsp)
        movq %r8,nb030nf_shift(%rsp)
        movq %r9,nb030nf_shiftvec(%rsp)
        movq nb030nf_p_ntype(%rbp),%rdi
        movl (%rdi),%edi
        movl %edi,nb030nf_ntype(%rsp)

        movq nb030nf_p_tabscale(%rbp),%rax
        movss (%rax),%xmm3
        shufps $0,%xmm3,%xmm3
        movaps %xmm3,nb030nf_tsc(%rsp)

        ## create constant floating-point factors on stack
        movl $0x3f000000,%eax   ## half in IEEE (hex)
        movl %eax,nb030nf_half(%rsp)
        movss nb030nf_half(%rsp),%xmm1
        shufps $0,%xmm1,%xmm1  ## splat to all elements
        movaps %xmm1,%xmm2
        addps  %xmm2,%xmm2      ## one
        movaps %xmm2,%xmm3
        addps  %xmm2,%xmm2      ## two
        addps  %xmm2,%xmm3      ## three
        movaps %xmm1,nb030nf_half(%rsp)
        movaps %xmm3,nb030nf_three(%rsp)

_nb_kernel030nf_x86_64_sse.nb030nf_threadloop: 
        movq  nb030nf_count(%rbp),%rsi            ## pointer to sync counter
        movl  (%rsi),%eax
_nb_kernel030nf_x86_64_sse.nb030nf_spinlock: 
        movl  %eax,%ebx                         ## ebx=*count=nn0
        addl  $1,%ebx                          ## ebx=nn1=nn0+10
        lock 
        cmpxchgl %ebx,(%rsi)                    ## write nn1 to *counter,
                                                ## if it hasnt changed.
                                                ## or reread *counter to eax.
        pause                                   ## -> better p4 performance
        jnz _nb_kernel030nf_x86_64_sse.nb030nf_spinlock

        ## if(nn1>nri) nn1=nri
        movl nb030nf_nri(%rsp),%ecx
        movl %ecx,%edx
        subl %ebx,%ecx
        cmovlel %edx,%ebx                       ## if(nn1>nri) nn1=nri
        ## Cleared the spinlock if we got here.
        ## eax contains nn0, ebx contains nn1.
        movl %eax,nb030nf_n(%rsp)
        movl %ebx,nb030nf_nn1(%rsp)
        subl %eax,%ebx                          ## calc number of outer lists
        movl %eax,%esi                          ## copy n to esi
        jg  _nb_kernel030nf_x86_64_sse.nb030nf_outerstart
        jmp _nb_kernel030nf_x86_64_sse.nb030nf_end

_nb_kernel030nf_x86_64_sse.nb030nf_outerstart: 
        ## ebx contains number of outer iterations
        addl nb030nf_nouter(%rsp),%ebx
        movl %ebx,nb030nf_nouter(%rsp)

_nb_kernel030nf_x86_64_sse.nb030nf_outer: 
        movq  nb030nf_shift(%rsp),%rax          ## rax = pointer into shift[] 
        movl  (%rax,%rsi,4),%ebx                ## ebx=shift[n] 

        lea  (%rbx,%rbx,2),%rbx    ## rbx=3*is 
        movl  %ebx,nb030nf_is3(%rsp)            ## store is3 

        movq  nb030nf_shiftvec(%rsp),%rax       ## rax = base of shiftvec[] 

        movss (%rax,%rbx,4),%xmm0
        movss 4(%rax,%rbx,4),%xmm1
        movss 8(%rax,%rbx,4),%xmm2

        movq  nb030nf_iinr(%rsp),%rcx           ## rcx = pointer into iinr[]    
        movl  (%rcx,%rsi,4),%ebx                ## ebx =ii 

        movq  nb030nf_type(%rbp),%rdx
        movl  (%rdx,%rbx,4),%edx
        imull nb030nf_ntype(%rsp),%edx
        shll  %edx
        movl  %edx,nb030nf_ntia(%rsp)

        lea  (%rbx,%rbx,2),%rbx                ## rbx = 3*ii=ii3 
        movq  nb030nf_pos(%rbp),%rax            ## rax = base of pos[]  

        addss (%rax,%rbx,4),%xmm0
        addss 4(%rax,%rbx,4),%xmm1
        addss 8(%rax,%rbx,4),%xmm2

        shufps $0,%xmm0,%xmm0
        shufps $0,%xmm1,%xmm1
        shufps $0,%xmm2,%xmm2

        movaps %xmm0,nb030nf_ix(%rsp)
        movaps %xmm1,nb030nf_iy(%rsp)
        movaps %xmm2,nb030nf_iz(%rsp)

        movl  %ebx,nb030nf_ii3(%rsp)

        ## clear tot potential and i forces 
        xorps %xmm4,%xmm4
        movaps %xmm4,nb030nf_Vvdwtot(%rsp)

        movq  nb030nf_jindex(%rsp),%rax
        movl  (%rax,%rsi,4),%ecx                ## jindex[n] 
        movl  4(%rax,%rsi,4),%edx               ## jindex[n+1] 
        subl  %ecx,%edx                         ## number of innerloop atoms 

        movq  nb030nf_pos(%rbp),%rsi
        movq  nb030nf_jjnr(%rsp),%rax
        shll  $2,%ecx
        addq  %rcx,%rax
        movq  %rax,nb030nf_innerjjnr(%rsp)      ## pointer to jjnr[nj0] 
        movl  %edx,%ecx
        subl  $4,%edx
        addl  nb030nf_ninner(%rsp),%ecx
        movl  %ecx,nb030nf_ninner(%rsp)
        addl  $0,%edx
        movl  %edx,nb030nf_innerk(%rsp)         ## number of innerloop atoms 
        jge   _nb_kernel030nf_x86_64_sse.nb030nf_unroll_loop
        jmp   _nb_kernel030nf_x86_64_sse.nb030nf_finish_inner
_nb_kernel030nf_x86_64_sse.nb030nf_unroll_loop: 
        ## quad-unroll innerloop here 
        movq  nb030nf_innerjjnr(%rsp),%rdx       ## pointer to jjnr[k] 
        movl  (%rdx),%eax
        movl  4(%rdx),%ebx
        movl  8(%rdx),%ecx
        movl  12(%rdx),%edx           ## eax-edx=jnr1-4 
        addq $16,nb030nf_innerjjnr(%rsp)             ## advance pointer (unrolled 4) 

        movd  %eax,%mm0         ## use mmx registers as temp storage 
        movd  %ebx,%mm1
        movd  %ecx,%mm2
        movd  %edx,%mm3

        movq nb030nf_type(%rbp),%rsi
        movl (%rsi,%rax,4),%eax
        movl (%rsi,%rbx,4),%ebx
        movl (%rsi,%rcx,4),%ecx
        movl (%rsi,%rdx,4),%edx
        movq nb030nf_vdwparam(%rbp),%rsi
        shll %eax
        shll %ebx
        shll %ecx
        shll %edx
        movl nb030nf_ntia(%rsp),%edi
        addl %edi,%eax
        addl %edi,%ebx
        addl %edi,%ecx
        addl %edi,%edx

        movlps (%rsi,%rax,4),%xmm6
        movlps (%rsi,%rcx,4),%xmm7
        movhps (%rsi,%rbx,4),%xmm6
        movhps (%rsi,%rdx,4),%xmm7

        movaps %xmm6,%xmm4
        shufps $136,%xmm7,%xmm4 ## 10001000
        shufps $221,%xmm7,%xmm6 ## 11011101

        movd  %mm0,%eax
        movd  %mm1,%ebx
        movd  %mm2,%ecx
        movd  %mm3,%edx

        movaps %xmm4,nb030nf_c6(%rsp)
        movaps %xmm6,nb030nf_c12(%rsp)

        movq nb030nf_pos(%rbp),%rsi        ## base of pos[] 

        lea  (%rax,%rax,2),%rax     ## replace jnr with j3 
        lea  (%rbx,%rbx,2),%rbx

        lea  (%rcx,%rcx,2),%rcx     ## replace jnr with j3 
        lea  (%rdx,%rdx,2),%rdx

        ## move four coordinates to xmm0-xmm2   

        movlps (%rsi,%rax,4),%xmm4
        movlps (%rsi,%rcx,4),%xmm5
        movss 8(%rsi,%rax,4),%xmm2
        movss 8(%rsi,%rcx,4),%xmm6

        movhps (%rsi,%rbx,4),%xmm4
        movhps (%rsi,%rdx,4),%xmm5

        movss 8(%rsi,%rbx,4),%xmm0
        movss 8(%rsi,%rdx,4),%xmm1

        shufps $0,%xmm0,%xmm2
        shufps $0,%xmm1,%xmm6

        movaps %xmm4,%xmm0
        movaps %xmm4,%xmm1

        shufps $136,%xmm6,%xmm2 ## 10001000

        shufps $136,%xmm5,%xmm0 ## 10001000
        shufps $221,%xmm5,%xmm1 ## 11011101             

        ## move nb030nf_ix-iz to xmm4-xmm6 
        movaps nb030nf_ix(%rsp),%xmm4
        movaps nb030nf_iy(%rsp),%xmm5
        movaps nb030nf_iz(%rsp),%xmm6

        ## calc dr 
        subps %xmm0,%xmm4
        subps %xmm1,%xmm5
        subps %xmm2,%xmm6

        ## square it 
        mulps %xmm4,%xmm4
        mulps %xmm5,%xmm5
        mulps %xmm6,%xmm6
        addps %xmm5,%xmm4
        addps %xmm6,%xmm4
        ## rsq in xmm4 

        rsqrtps %xmm4,%xmm5
        ## lookup seed in xmm5 
        movaps %xmm5,%xmm2
        mulps %xmm5,%xmm5
        movaps nb030nf_three(%rsp),%xmm1
        mulps %xmm4,%xmm5       ## rsq*lu*lu                    
        movaps nb030nf_half(%rsp),%xmm0